From 209edf0433e442631a6dac2f8520ed52a83db63d Mon Sep 17 00:00:00 2001
From: Grim <69561145+LinkIsGrim@users.noreply.github.com>
Date: Wed, 18 Oct 2023 14:51:00 -0400
Subject: [PATCH] Arsenal - Add `FUNC(getVirtualItems)` (#9512)

add API
---
 addons/arsenal/XEH_PREP.hpp                   |  1 +
 .../arsenal/functions/fnc_getVirtualItems.sqf | 39 +++++++++++++++++++
 2 files changed, 40 insertions(+)
 create mode 100644 addons/arsenal/functions/fnc_getVirtualItems.sqf

diff --git a/addons/arsenal/XEH_PREP.hpp b/addons/arsenal/XEH_PREP.hpp
index 3b063d8ebe..3864a810d8 100644
--- a/addons/arsenal/XEH_PREP.hpp
+++ b/addons/arsenal/XEH_PREP.hpp
@@ -39,6 +39,7 @@ PREP(fillLeftPanel);
 PREP(fillLoadoutsList);
 PREP(fillRightPanel);
 PREP(fillSort);
+PREP(getVirtualItems);
 PREP(handleActions);
 PREP(handleLoadoutsSearchbar);
 PREP(handleMouse);
diff --git a/addons/arsenal/functions/fnc_getVirtualItems.sqf b/addons/arsenal/functions/fnc_getVirtualItems.sqf
new file mode 100644
index 0000000000..0666b34087
--- /dev/null
+++ b/addons/arsenal/functions/fnc_getVirtualItems.sqf
@@ -0,0 +1,39 @@
+#include "..\script_component.hpp"
+#include "..\defines.hpp"
+/*
+ * Author: johnb43, Grim
+ * Gets list of virtual items available to the object.
+ *
+ * Arguments:
+ * 0: Target <OBJECT>
+ *
+ * Return Value:
+ * Virtual Items <HASHMAP>
+ *
+ * Example:
+ * cursorObject call ace_arsenal_fnc_getVirtualItems
+ *
+ * Public: Yes
+*/
+params [["_object", objNull, [objNull]]];
+
+private _virtualItems = _object getVariable QGVAR(virtualItems);
+if (isNil "_virtualItems") exitWith {createHashMap};
+
+private _virtualItemsFlat = +_virtualItems;
+private _weapons = _virtualItemsFlat deleteAt IDX_VIRT_WEAPONS;
+private _attachments = _virtualItemsFlat deleteAt IDX_VIRT_ATTACHMENTS;
+
+for "_index" from IDX_VIRT_ITEMS_ALL to IDX_VIRT_MISC_ITEMS do {
+    _virtualItemsFlat merge [_virtualItemsFlat deleteAt _index, true];
+};
+
+for "_index" from IDX_VIRT_PRIMARY_WEAPONS to IDX_VIRT_HANDGUN_WEAPONS do {
+    _virtualItemsFlat merge [_weapons deleteAt _index, true];
+};
+
+for "_index" from IDX_VIRT_OPTICS_ATTACHMENTS to IDX_VIRT_BIPOD_ATTACHMENTS do {
+    _virtualItemsFlat merge [_attachments deleteAt _index, true];
+};
+
+_virtualItemsFlat // return