From 94e8bee3483911619de7bd92984f2e13f310d992 Mon Sep 17 00:00:00 2001
From: esteldunedain <nicolas.d.badano@gmail.com>
Date: Sun, 28 Feb 2016 23:08:25 -0300
Subject: [PATCH] Move the pfh from setDead to a waitAndExecute loop:
 reviveStepLoop

---
 addons/medical/XEH_PREP.hpp                   |  1 +
 .../medical/functions/fnc_reviveStateLoop.sqf | 56 +++++++++++++++++++
 addons/medical/functions/fnc_setDead.sqf      | 37 +-----------
 3 files changed, 59 insertions(+), 35 deletions(-)
 create mode 100644 addons/medical/functions/fnc_reviveStateLoop.sqf

diff --git a/addons/medical/XEH_PREP.hpp b/addons/medical/XEH_PREP.hpp
index 906f4e18f7..b9ad6ba546 100644
--- a/addons/medical/XEH_PREP.hpp
+++ b/addons/medical/XEH_PREP.hpp
@@ -64,6 +64,7 @@ PREP(onWoundUpdateRequest);
 PREP(onPropagateWound);
 PREP(parseConfigForInjuries);
 PREP(playInjuredSound);
+PREP(reviveStateLoop);
 PREP(selectionNameToNumber);
 PREP(serverRemoveBody);
 PREP(setCardiacArrest);
diff --git a/addons/medical/functions/fnc_reviveStateLoop.sqf b/addons/medical/functions/fnc_reviveStateLoop.sqf
new file mode 100644
index 0000000000..3e55f7b7ce
--- /dev/null
+++ b/addons/medical/functions/fnc_reviveStateLoop.sqf
@@ -0,0 +1,56 @@
+/*
+ * Author: Glowbal, esteldunedain
+ * Loop that handles a unit in the revive state.
+ *
+ * Arguments:
+ * 0: Unit <OBJECT>
+ *
+ * ReturnValue:
+ * None
+ *
+ * Public: No
+ */
+
+#include "script_component.hpp"
+
+params ["_unit"]
+
+// If locality changed finish the local loop
+// @todo: reinitiate the loop elsewhere
+if (!local _unit) exitWith {};
+
+private _startTime = _unit getVariable [QGVAR(reviveStartTime), 0];
+
+// Remove heartbeat
+if (GVAR(level) >= 2) then {
+    if (_unit getVariable [QGVAR(heartRate), 60] > 0) then {
+        _unit setVariable [QGVAR(heartRate), 0];
+    };
+};
+
+// If we are in revive state in a blown up vehicle, try to unload so that people can access the body
+if ((alive _unit) && {(vehicle _unit) != _unit} && {!alive (vehicle _unit)}) then {
+    TRACE_2("Unloading", _unit, vehicle _unit);
+    [_unit] call EFUNC(common,unloadPerson);
+};
+
+// If the timer run out, let the unit die and exit the loop
+if (GVAR(maxReviveTime) > 0 && {ACE_time - _startTime > GVAR(maxReviveTime)}) exitwith {
+    _unit setVariable [QGVAR(inReviveState), nil, true];
+    _unit setVariable [QGVAR(reviveStartTime), nil];
+    [_unit, true] call FUNC(setDead);
+};
+
+// If the unit was taken out from revive state, exit the loop
+if !(_unit getVariable [QGVAR(inReviveState), false]) exitwith {
+    // Revived without dieing, so in case we have lifes, remove one.
+    if (GVAR(amountOfReviveLives) > 0) then {
+        _lifesLeft = _unit getVariable[QGVAR(amountOfReviveLives), GVAR(amountOfReviveLives)];
+        _unit setVariable [QGVAR(amountOfReviveLives), _lifesLeft - 1, true];
+    };
+
+    _unit setVariable [QGVAR(reviveStartTime), nil];
+};
+
+// Schedule the loop to be executed again 1 sec later
+[DFUNC(reviveStateLoop), [_unit], 1] call EFUNC(common,waitAndExecute);
diff --git a/addons/medical/functions/fnc_setDead.sqf b/addons/medical/functions/fnc_setDead.sqf
index 913431ccac..061a28c081 100644
--- a/addons/medical/functions/fnc_setDead.sqf
+++ b/addons/medical/functions/fnc_setDead.sqf
@@ -41,41 +41,8 @@ if (((_reviveVal == 1 && {[_unit] call EFUNC(common,isPlayer)} || _reviveVal ==
     _unit setVariable [QGVAR(reviveStartTime), ACE_time];
     [_unit, true] call FUNC(setUnconscious);
 
-    [{
-        private "_startTime";
-        params ["_args", "_idPFH"];
-        _args params ["_unit"];
-        _startTime = _unit getVariable [QGVAR(reviveStartTime), 0];
-
-        //If we are in reivie state in a blown up vehicle, try to unload so that people can access the body
-        if ((alive _unit) && {(vehicle _unit) != _unit} && {!alive (vehicle _unit)}) then {
-            TRACE_2("Unloading", _unit, vehicle _unit);
-            [_unit] call EFUNC(common,unloadPerson);
-        };
-
-        if (GVAR(maxReviveTime) > 0 && {ACE_time - _startTime > GVAR(maxReviveTime)}) exitwith {
-            [_idPFH] call CBA_fnc_removePerFrameHandler;
-            _unit setVariable [QGVAR(inReviveState), nil, true];
-            _unit setVariable [QGVAR(reviveStartTime), nil];
-            [_unit, true] call FUNC(setDead);
-        };
-
-        if !(_unit getVariable [QGVAR(inReviveState), false]) exitwith {
-            // revived without dieing, so in case we have lifes, remove one.
-            if (GVAR(amountOfReviveLives) > 0) then {
-                _lifesLeft = _unit getVariable[QGVAR(amountOfReviveLives), GVAR(amountOfReviveLives)];
-                _unit setVariable [QGVAR(amountOfReviveLives), _lifesLeft - 1, true];
-            };
-
-            _unit setVariable [QGVAR(reviveStartTime), nil];
-            [_idPFH] call CBA_fnc_removePerFrameHandler;
-        };
-        if (GVAR(level) >= 2) then {
-            if (_unit getVariable [QGVAR(heartRate), 60] > 0) then {
-                _unit setVariable [QGVAR(heartRate), 0];
-            };
-        };
-    }, 1, [_unit] ] call CBA_fnc_addPerFrameHandler;
+    // Run the loop that tracks the revive state
+    [_unit ] call FUNC(reviveStateLoop);
     false;
 };