AGM - Night Vision First Pass

addons/nightvision/CfgEventHandlers.hpp

@@ -0,0 +1,19 @@
+class Extended_PreInit_EventHandlers {
+  class ADDON {
+    init = QUOTE(call COMPILE_FILE(XEH_preInit) );
+  };
+};
+
+class Extended_PostInit_EventHandlers {
+  class ADDON {
+    clientInit = QUOTE(call COMPILE_FILE(XEH_postInitClient) );
+  };
+};
+
+class Extended_FiredBIS_EventHandlers {
+  class AllVehicles {
+    class ADDON {
+      clientFiredBIS = QUOTE( _this call FUNC(blending) );
+    };
+  };
+};

addons/nightvision/CfgVehicles.hpp

@@ -0,0 +1,22 @@
+class CfgVehicles {
+  class All {
+    ACE_NightVision_grain = 0.75;
+    ACE_NightVision_blur = 0.055;
+  };
+
+  #define MACRO_ADDITEM(ITEM,COUNT) class _xx_##ITEM { \
+    name = #ITEM; \
+    count = COUNT; \
+  };
+
+  class Box_NATO_Support_F;
+  class ACE_Box_Misc: Box_NATO_Support_F {
+    class TransportItems {
+      MACRO_ADDITEM(ACE_NVG_Gen1,6)
+      MACRO_ADDITEM(ACE_NVG_Gen2,6)
+    //MACRO_ADDITEM(ACE_NVG_Gen3,6)
+      MACRO_ADDITEM(ACE_NVG_Gen4,6)
+      MACRO_ADDITEM(ACE_NVG_Wide,6)
+    };
+  };
+};

addons/nightvision/CfgWeapons.hpp

@@ -0,0 +1,56 @@
+class CfgWeapons {
+  class Binocular;
+  class NVGoggles: Binocular {
+    displayName = "$STR_ACE_NightVision_NVG_Gen3_brown";
+    ACE_NightVision_grain = 0.75;
+    ACE_NightVision_blur = 0.055;
+    ACE_NightVision_radBlur = 0.001;
+  };
+  class NVGoggles_OPFOR: NVGoggles {
+    displayName = "$STR_ACE_NightVision_NVG_Gen3_black";
+  };
+  class NVGoggles_INDEP: NVGoggles {
+    displayName = "$STR_ACE_NightVision_NVG_Gen3_green";
+  };
+
+  class ACE_NVG_Gen1: NVGoggles_OPFOR {
+    author = "$STR_ACE_Common_ACETeam";
+    modelOptics = "\A3\weapons_f\reticle\optics_night";
+    displayName = "$STR_ACE_NightVision_NVG_Gen1";
+    ACE_NightVision_grain = 2.25;
+    ACE_NightVision_blur = 0.22;
+    ACE_NightVision_radBlur = 0.004;
+  };
+  class ACE_NVG_Gen2: NVGoggles_INDEP {
+    author = "$STR_ACE_Common_ACETeam";
+    modelOptics = "\A3\weapons_f\reticle\optics_night";
+    displayName = "$STR_ACE_NightVision_NVG_Gen2";
+    ACE_NightVision_grain = 1.5;
+    ACE_NightVision_blur = 0.11;
+    ACE_NightVision_radBlur = 0.002;
+  };
+  /*class ACE_NVG_Gen3: NVGoggles {
+    author = "$STR_ACE_Common_ACETeam";
+    modelOptics = "\A3\weapons_f\reticle\optics_night";
+    displayName = "$STR_ACE_NightVision_NVG_Gen3";
+    ACE_NightVision_grain = 0.75;
+    ACE_NightVision_blur = 0.055;
+    ACE_NightVision_radBlur = 0.001;
+  };*/
+  class ACE_NVG_Gen4: NVGoggles {
+    author = "$STR_ACE_Common_ACETeam";
+    modelOptics = "\A3\weapons_f\reticle\optics_night";
+    displayName = "$STR_ACE_NightVision_NVG_Gen4";
+    ACE_NightVision_grain = 0.0;
+    ACE_NightVision_blur = 0.0;
+    ACE_NightVision_radBlur = 0.0;
+  };
+  class ACE_NVG_Wide: NVGoggles {
+    author = "$STR_ACE_Common_ACETeam";
+    modelOptics = PATHOF(ACE_nvg_wide_optics.p3d);
+    displayName = "$STR_ACE_NightVision_NVG_FullScreen";
+    ACE_NightVision_grain = 0.75;
+    ACE_NightVision_blur = 0.055;
+    ACE_NightVision_radBlur = 0.001;
+  };
+};

addons/nightvision/XEH_postInitClient.sqf

@@ -0,0 +1,31 @@
+// by commy2
+#include "script_component.hpp"
+
+if (!hasInterface) exitWith {};
+
+GVAR(ppEffectBlur) = ppEffectCreate ["dynamicBlur", 1234];  
+GVAR(ppEffectBlur) ppEffectForceInNVG true;
+GVAR(ppEffectBlur) ppEffectAdjust [0]; 
+GVAR(ppEffectBlur) ppEffectCommit 0;  
+
+GVAR(ppEffectRadialBlur) = ppEffectCreate ["radialBlur", 1238];
+GVAR(ppEffectRadialBlur) ppEffectForceInNVG true;
+GVAR(ppEffectRadialBlur) ppEffectAdjust [0, 0, 0, 0];
+GVAR(ppEffectRadialBlur) ppEffectCommit 0;
+
+GVAR(ppEffectFilmGrain) = ppEffectCreate ["FilmGrain", 1235];
+GVAR(ppEffectFilmGrain) ppEffectAdjust [0.25, 2.5, 2.5, 2.5*0.3, 2.5*0.3, false];
+GVAR(ppEffectFilmGrain) ppEffectCommit 0;
+
+GVAR(ppEffectNVGBrightness) = ppEffectCreate ["ColorCorrections", 1236];
+GVAR(ppEffectNVGBrightness) ppEffectForceInNVG true;
+GVAR(ppEffectNVGBrightness) ppEffectAdjust [1, 1, 0, [0, 0, 0, 0], [0, 0, 0, 1], [0, 0, 0, 1]];
+GVAR(ppEffectNVGBrightness) ppEffectCommit 0;
+
+GVAR(ppEffectMuzzleFlash) = ppEffectCreate ["ColorCorrections", 1237];
+GVAR(ppEffectMuzzleFlash) ppEffectEnable true;
+GVAR(ppEffectMuzzleFlash) ppEffectForceInNVG true;
+GVAR(ppEffectMuzzleFlash) ppEffectAdjust [1, 1, 0, [0, 0, 0, 0], [0, 0, 0, 1], [0, 0, 0, 1]];
+GVAR(ppEffectMuzzleFlash) ppEffectCommit 0;
+
+0 spawn COMPILE_FILE(nightVision); //ToDo

addons/nightvision/XEH_preInit.sqf

@@ -0,0 +1,5 @@
+#include "script_component.hpp"
+
+PREP(blending);
+PREP(decreaseNVGBrightness);
+PREP(increaseNVGBrightness);

addons/nightvision/config.cpp

@@ -0,0 +1,39 @@
+#include "script_component.hpp"
+
+class CfgPatches {
+  class ADDON {
+    units[] = {};
+    weapons[] = {"ACE_NVG_Gen1", "ACE_NVG_Gen2", /*"ACE_NVG_Gen3",*/ "ACE_NVG_Gen4", "ACE_NVG_Wide"};
+    requiredVersion = 0.60;
+    requiredAddons[] = {"ace_common"};
+    author[] = {"commy2", "KoffeinFlummi", "PabstMirror"};
+    authorUrl = "https://github.com/commy2/";
+    VERSION_CONFIG;
+  };
+};
+
+#include "CfgEventHandlers.hpp"
+#include "CfgVehicles.hpp"
+
+class ACE_Core_Default_Keys {
+  class increaseNVGBrightness {
+    displayName = "$STR_ACE_NightVision_IncreaseNVGBrightness";
+    condition = QUOTE( currentVisionMode _player == 1 );
+    statement = QUOTE( [_player, _vehicle] call FUNC(increaseNVGBrightness) );
+    key = 201;
+    shift = 0;
+    control = 0;
+    alt = 1;
+    allowHolding = 1;
+  };
+  class decreaseNVGBrightness {
+    displayName = "$STR_ACE_NightVision_DecreaseNVGBrightness";
+    condition = QUOTE( currentVisionMode _player == 1 );
+    statement = QUOTE( [_player, _vehicle] call FUNC(decreaseNVGBrightness) );
+    key = 209;
+    shift = 0;
+    control = 0;
+    alt = 1;
+    allowHolding = 1;
+  };
+};

addons/nightvision/functions/fnc_blending.sqf

@@ -0,0 +1,71 @@
+// by commy2
+#include "script_component.hpp"
+
+private ["_vehicle", "_weapon", "_ammo", "_magazine", "_player"];
+
+_vehicle = _this select 0;
+_weapon = _this select 1;
+_ammo = _this select 4;
+_magazine = _this select 5;
+
+// if (_this select 0 == vehicle ACE_player && {currentVisionMode (_this select 0) == 1}) then {_this call AGM_NightVision_fnc_blending};
+if ((_vehicle != (vehicle ACE_player)) || {(currentVisionMode _vehicle) != 1}) exitWith {};
+
+_player = ACE_player;
+
+if (_player != _vehicle && {!(_weapon in (_vehicle weaponsTurret ([_player] call EFUNC(common,getTurretIndex))))}) exitWith {};
+
+private ["_silencer", "_visibleFireCoef", "_visibleFireTimeCoef", "_visibleFire", "_visibleFireTime", "_nvgBrightnessCoef", "_fnc_isTracer", "_darkness"];
+
+_silencer = switch (_weapon) do {
+  case (primaryWeapon _player) : {primaryWeaponItems _player select 0};
+  case (secondaryWeapon _player) : {secondaryWeaponItems _player select 0};
+  case (handgunWeapon _player) : {handgunItems _player select 0};
+  default {""};
+};
+
+_visibleFireCoef = 1;
+_visibleFireTimeCoef = 1;
+if (_silencer != "") then {
+  _visibleFireCoef = getNumber (configFile >> "CfgWeapons" >> _silencer >> "ItemInfo" >> "AmmoCoef" >> "visibleFire");
+  _visibleFireTimeCoef = getNumber (configFile >> "CfgWeapons" >> _silencer >> "ItemInfo" >> "AmmoCoef" >> "visibleFireTime");
+};
+
+_visibleFire = getNumber (configFile >> "CfgAmmo" >> _ammo >> "visibleFire");
+_visibleFireTime = getNumber (configFile >> "CfgAmmo" >> _ammo >> "visibleFireTime");
+
+_nvgBrightnessCoef = 1 + (_player getVariable [QUOTE( GVAR(NVGBrightness) ), 0]) / 4;
+
+_fnc_isTracer = {
+  private ["_indexShot", "_lastRoundsTracer", "_tracersEvery"];
+
+  if (getNumber (configFile >> "CfgAmmo" >> _ammo >> "nvgOnly") > 0) exitWith {false};
+
+  _indexShot = (_player ammo _weapon) + 1;
+
+  _lastRoundsTracer = getNumber (configFile >> "CfgMagazines" >> _magazine >> "lastRoundsTracer");
+  if (_indexShot <= _lastRoundsTracer) exitWith {true};
+
+  _tracersEvery = getNumber (configFile >> "CfgMagazines" >> _magazine >> "tracersEvery");
+  if (_tracersEvery == 0) exitWith {false};
+
+  (_indexShot - _lastRoundsTracer) % _tracersEvery == 0
+};
+
+if (call _fnc_isTracer) then {
+  _visibleFire = _visibleFire + 2;
+  _visibleFireTime = _visibleFireTime + 2;
+};
+
+_darkness = 1 - (call EFUNC(common,ambientBrightness));
+
+_visibleFire = _darkness * _visibleFireCoef * _visibleFire * _nvgBrightnessCoef / 10 min 1;
+_visibleFireTime = _darkness * _visibleFireTimeCoef * _visibleFireTime * _nvgBrightnessCoef / 10 min 0.5;
+
+["NightVision", [_visibleFire, _visibleFireTime], {format ["visibleFire: %1 - visibleFireTime: %2", _this select 0, _this select 1]}] call AGM_Debug_fnc_log;
+
+GVAR(ppEffectMuzzleFlash) ppEffectAdjust [1, 1, _visibleFire, [0, 0, 0, 0], [0, 0, 0, 1], [0, 0, 0, 1]];
+GVAR(ppEffectMuzzleFlash) ppEffectCommit 0;
+
+GVAR(ppEffectMuzzleFlash) ppEffectAdjust [1, 1, 0, [0, 0, 0, 0], [0, 0, 0, 1], [0, 0, 0, 1]];
+GVAR(ppEffectMuzzleFlash) ppEffectCommit _visibleFireTime;

addons/nightvision/functions/fnc_decreaseNVGBrightness.sqf

@@ -0,0 +1,21 @@
+// by commy2
+#include "script_component.hpp"
+
+private ["_player", "_vehicle", "_brightness"];
+
+_player = _this select 0;
+_vehicle = _this select 1;
+
+_brightness = _player getVariable [QUOTE( GVAR(NVGBrightness) ), 0];
+
+if (_brightness > -1) then {
+  _brightness = round (10 * _brightness - 1) / 10;
+
+  _player setVariable [QUOTE( GVAR(NVGBrightness) ), _brightness, false];
+
+  GVAR(ppEffectNVGBrightness) ppEffectAdjust [1, 1, _brightness / 4, [0, 0, 0, 0], [0, 0, 0, 1], [0, 0, 0, 1]];
+  GVAR(ppEffectNVGBrightness) ppEffectCommit 0;
+
+  [format [localize "STR_ACE_NightVision_NVGBrightness", format ["%1%", _brightness * 100]]] call EFUNC(common,displayTextStructured);
+  playSound "ACE_Sound_Click";
+};

addons/nightvision/functions/fnc_increaseNVGBrightness.sqf

@@ -0,0 +1,21 @@
+// by commy2
+#include "script_component.hpp"
+
+private ["_player", "_vehicle", "_brightness"];
+
+_player = _this select 0;
+_vehicle = _this select 1;
+
+_brightness = _player getVariable [QUOTE( GVAR(NVGBrightness) ), 0];
+
+if (_brightness < 1) then {
+  _brightness = round (10 * _brightness + 1) / 10;
+
+  _player setVariable [QUOTE( GVAR(NVGBrightness) ), _brightness, false];
+
+  GVAR(ppEffectNVGBrightness) ppEffectAdjust [1, 1, _brightness / 4, [0, 0, 0, 0], [0, 0, 0, 1], [0, 0, 0, 1]];
+  GVAR(ppEffectNVGBrightness) ppEffectCommit 0;
+
+  [format [localize "STR_ACE_NightVision_NVGBrightness", format ["%1%", _brightness * 100]]] call EFUNC(common,displayTextStructured);
+  playSound "ACE_Sound_Click";
+};

addons/nightvision/functions/script_component.hpp

@@ -0,0 +1,12 @@
+#define COMPONENT nightvision
+#include "\z\ace\addons\main\script_mod.hpp"
+
+#ifdef DEBUG_ENABLED_BLANK
+    #define DEBUG_MODE_FULL
+#endif
+
+#ifdef DEBUG_SETTINGS_BLANK
+    #define DEBUG_SETTINGS DEBUG_SETTINGS_BLANK
+#endif
+
+#include "\z\ace\addons\main\script_macros.hpp"

addons/nightvision/nightVision.sqf

@@ -0,0 +1,103 @@
+//by commy2
+#include "script_component.hpp"
+
+xxx =5;
+
+private ["_currentVehicle", "_currentTurret", "_currentHMD", "_grainSetting", "_blurSetting"];
+
+_currentView = "";
+_currentVehicle = objNull;
+_currentTurret = [-1];
+_currentHMD = "";
+
+while {true} do {
+  GVAR(ppEffectFilmGrain) ppEffectEnable false;
+  GVAR(ppEffectBlur) ppEffectEnable false;
+  GVAR(ppEffectRadialBlur) ppEffectEnable false;
+  GVAR(ppEffectNVGBrightness) ppEffectEnable false;
+
+  waitUntil {currentVisionMode ACE_player == 1};
+
+  GVAR(ppEffectFilmGrain) ppEffectEnable true;
+  GVAR(ppEffectBlur) ppEffectEnable true;
+  GVAR(ppEffectRadialBlur) ppEffectEnable true;
+  GVAR(ppEffectNVGBrightness) ppEffectEnable true;
+
+  waitUntil {
+    // any updates?
+    if (hmd ACE_player != _currentHMD || {cameraView != _currentView} || {vehicle ACE_player != _currentVehicle} || {!(_currentTurret isEqualTo []) && {ACE_player != _currentVehicle turretUnit _currentTurret}}) then {
+      _currentHMD = hmd ACE_player;
+      _currentView = cameraView;
+      _currentVehicle = vehicle ACE_player;
+      _currentTurret = [ACE_player] call EFUNC(common,getTurretIndex);
+
+      private ["_config", "_fnc_isUsingHMD"];
+      _config = configFile >> "CfgVehicles" >> typeOf _currentVehicle;
+
+      _fnc_isUsingHMD = {
+        if (_currentView != "GUNNER") exitWith {true};  // asume hmd usage outside of gunner view
+
+        if (ACE_player == (driver _currentVehicle)) exitWith {
+          !("NVG" in getArray (_config >> "ViewOptics" >> "visionMode"));
+        };
+
+        private "_turretConfig";
+        _turretConfig = [_config, _currentTurret] call EFUNC(core,getTurretConfigPath);
+        _turretConfig = _turretConfig >> "OpticsIn";
+
+        private "_result";
+        _result = true;
+        for "_index" from 0 to (count _turretConfig - 1) do {
+          if ("NVG" in getArray (_turretConfig select _index >> "visionMode")) exitWith {_result = false};
+          true
+        };
+
+        _result
+      };
+
+      // on foot or in vehicle using hmd
+      if ((_currentVehicle == ACE_player) || _fnc_isUsingHMD) then {
+        _grainSetting = getNumber (configFile >> "CfgWeapons" >> _currentHMD >> "AGM_NightVision_grain");
+        _blurSetting = getNumber (configFile >> "CfgWeapons" >> _currentHMD >> "AGM_NightVision_blur");
+        _radBlurSetting = getNumber (configFile >> "CfgWeapons" >> _currentHMD >> "AGM_NightVision_radBlur");
+
+        GVAR(ppEffectFilmGrain) ppEffectAdjust [0.25, 2.5, 2.5, _grainSetting, _grainSetting, false];
+        GVAR(ppEffectFilmGrain) ppEffectCommit 0;
+        GVAR(ppEffectBlur) ppEffectAdjust [_blurSetting];
+        GVAR(ppEffectBlur) ppEffectCommit 0;
+        GVAR(ppEffectRadialBlur) ppEffectAdjust [_radBlurSetting, _radBlurSetting, 0.2, 0.2];
+        GVAR(ppEffectRadialBlur) ppEffectCommit 0;
+
+      // in vehicle and not using hmd
+      } else {
+        _grainSetting = _currentVehicle getVariable ["AGM_NightVision_grain", getNumber (_config >> "AGM_NightVision_grain")];
+        _blurSetting = _currentVehicle getVariable ["AGM_NightVision_blur", getNumber (_config >> "AGM_NightVision_blur")];
+        _radBlurSetting = _currentVehicle getVariable ["AGM_NightVision_radBlur", getNumber (_config >> "AGM_NightVision_radBlur")];
+
+        GVAR(ppEffectFilmGrain) ppEffectAdjust [0.25, 2.5, 2.5, _grainSetting, _grainSetting, false];
+        GVAR(ppEffectFilmGrain) ppEffectCommit 0;
+        GVAR(ppEffectBlur) ppEffectAdjust [_blurSetting];
+        GVAR(ppEffectBlur) ppEffectCommit 0;
+        GVAR(ppEffectRadialBlur) ppEffectAdjust [_radBlurSetting, _radBlurSetting, 0.2, 0.2];
+        GVAR(ppEffectRadialBlur) ppEffectCommit 0;
+      };
+    };
+
+    // Detect if curator interface is open and disable effects
+    if (!isNull findDisplay 312) then {
+      GVAR(ppEffectFilmGrain) ppEffectEnable false;
+      GVAR(ppEffectBlur) ppEffectEnable false;
+      GVAR(ppEffectRadialBlur) ppEffectEnable false;
+      GVAR(ppEffectNVGBrightness) ppEffectEnable false;
+
+      waitUntil {isNull findDisplay 312};
+
+      GVAR(ppEffectFilmGrain) ppEffectEnable true;
+      GVAR(ppEffectBlur) ppEffectEnable true;
+      GVAR(ppEffectRadialBlur) ppEffectEnable true;
+      GVAR(ppEffectNVGBrightness) ppEffectEnable true;
+    };
+
+    currentVisionMode ACE_player != 1
+  };
+};

addons/nightvision/script_component.hpp

@@ -0,0 +1,12 @@
+#define COMPONENT nightvision
+#include "\z\ace\addons\main\script_mod.hpp"
+
+#ifdef DEBUG_ENABLED_BLANK
+    #define DEBUG_MODE_FULL
+#endif
+
+#ifdef DEBUG_SETTINGS_BLANK
+    #define DEBUG_SETTINGS DEBUG_SETTINGS_BLANK
+#endif
+
+#include "\z\ace\addons\main\script_macros.hpp"

addons/nightvision/stringtable.xml

@@ -0,0 +1,127 @@
+<?xml version="1.0" encoding="utf-8"?>
+<!-- Edited with tabler - 2014-12-17 -->
+<Project name="ACE">
+  <Package name="NightVision">
+    <Key ID="STR_ACE_NightVision_NVG_Gen1">
+      <English>NV Goggles (Gen1)</English>
+      <Czech>Noktovizor (Gen1)</Czech>
+      <French>JVN (Gen1)</French>
+      <German>NS-Brille (Gen1)</German>
+      <Italian>Occhiali notturni (Gen1)</Italian>
+      <Polish>Gogle noktowizyjne (Gen1)</Polish>
+      <Portuguese>Óculos de visão noturna (Gen1)</Portuguese>
+      <Russian>ПНВ (Gen1)</Russian>
+      <Spanish>Sistema de visión nocturna (Gen1)</Spanish>
+    </Key>
+    <Key ID="STR_ACE_NightVision_NVG_Gen2">
+      <English>NV Goggles (Gen2)</English>
+      <Czech>Noktovizor (Gen2)</Czech>
+      <French>JVN (Gen2)</French>
+      <German>NS-Brille (Gen2)</German>
+      <Italian>Occhiali notturni (Gen2)</Italian>
+      <Polish>Gogle noktowizyjne (Gen2)</Polish>
+      <Portuguese>Óculos de visão noturna (Gen2)</Portuguese>
+      <Russian>ПНВ (Gen2)</Russian>
+      <Spanish>Sistema de visión nocturna (Gen2)</Spanish>
+    </Key>
+    <Key ID="STR_ACE_NightVision_NVG_Gen3">
+      <English>NV Goggles (Gen3)</English>
+      <Czech>Noktovizor (Gen3)</Czech>
+      <French>JVN (Gen3)</French>
+      <German>NS-Brille (Gen3)</German>
+      <Italian>Occhiali notturni (Gen3)</Italian>
+      <Polish>Gogle noktowizyjne (Gen3)</Polish>
+      <Portuguese>Óculos de visão noturna (Gen3)</Portuguese>
+      <Russian>ПНВ (Gen3)</Russian>
+      <Spanish>Sistema de visión nocturna (Gen3)</Spanish>
+    </Key>
+    <Key ID="STR_ACE_NightVision_NVG_Gen3_brown">
+      <English>NV Goggles (Gen3, Brown)</English>
+      <Czech>Noktovizor (Gen3, hnědý)</Czech>
+      <French>JVN (Gen3, marron)</French>
+      <German>NS-Brille (Gen3, Braun)</German>
+      <Italian>Occhiali notturni (Gen3, marroni)</Italian>
+      <Polish>Gogle noktowizyjne (Gen3, brązowe)</Polish>
+      <Portuguese>Óculos de visão noturna (Gen3, marrons)</Portuguese>
+      <Russian>ПНВ (Gen3, коричневый)</Russian>
+      <Spanish>Sistema de visión nocturna (Gen3, marrón)</Spanish>
+    </Key>
+    <Key ID="STR_ACE_NightVision_NVG_Gen3_green">
+      <English>NV Goggles (Gen3, Green)</English>
+      <Czech>Noktovizor (Gen3, zelený)</Czech>
+      <French>JVN (Gen3, vertes)</French>
+      <German>NS-Brille (Gen3, Grün)</German>
+      <Italian>Occhiali notturni (Gen3, verdi)</Italian>
+      <Polish>Gogle noktowizyjne (Gen3, zielone)</Polish>
+      <Portuguese>Óculos de visão noturna (Gen3, verdes)</Portuguese>
+      <Russian>ПНВ (Gen3, зеленый)</Russian>
+      <Spanish>Sistema de visión nocturna (Gen3, verde)</Spanish>
+    </Key>
+    <Key ID="STR_ACE_NightVision_NVG_Gen3_black">
+      <English>NV Goggles (Gen3, Black)</English>
+      <Czech>Noktovizor (Gen3, černý)</Czech>
+      <French>JVN (Gen3, noires)</French>
+      <German>NS-Brille (Gen3, Schwarz)</German>
+      <Italian>Occhiali notturni (Gen3, neri)</Italian>
+      <Polish>Gogle noktowizyjne (Gen3, czarne)</Polish>
+      <Portuguese>Óculos de visão noturna (Gen3, pretos)</Portuguese>
+      <Russian>ПНВ (Gen3, черный)</Russian>
+      <Spanish>Sistema de visión nocturna (Gen3, negro)</Spanish>
+    </Key>
+    <Key ID="STR_ACE_NightVision_NVG_Gen4">
+      <English>NV Goggles (Gen4)</English>
+      <Czech>Noktovizor (Gen4)</Czech>
+      <French>JVN (Gen4)</French>
+      <German>NS-Brille (Gen4)</German>
+      <Italian>Occhiali notturni (Gen4)</Italian>
+      <Polish>Gogle noktowizyjne (Gen4)</Polish>
+      <Portuguese>Óculos de visão noturna (Gen4)</Portuguese>
+      <Russian>ПНВ (Gen4)</Russian>
+      <Spanish>Sistema de visión nocturna (Gen4)</Spanish>
+    </Key>
+    <Key ID="STR_ACE_NightVision_NVG_FullScreen">
+      <English>NV Goggles (Wide)</English>
+      <German>NS-Brille (Weitwinkel)</German>
+      <Spanish>Sistema de visión nocturna (Panorámicas)</Spanish>
+      <Polish>Gogle noktowizyjne (panoramiczne)</Polish>
+      <Czech>Noktovizor (Široký)</Czech>
+      <Russian>ПНВ (Широкий)</Russian>
+    </Key>
+    <Key ID="STR_ACE_NightVision_NVGBrightness">
+      <English>Brightness: %1</English>
+      <German>Helligkeit: %1</German>
+      <Spanish>Brillo: %1</Spanish>
+      <Polish>Czułość: %1</Polish>
+      <Czech>Zvýšení: %1</Czech>
+      <French>Luminosité : %1</French>
+      <Russian>Контраст: </Russian>
+      <Hungarian>Fényerő: %1</Hungarian>
+      <Portuguese>Luminosidade: %1</Portuguese>
+      <Italian>Luminosità: %1</Italian>
+    </Key>
+    <Key ID="STR_ACE_NightVision_IncreaseNVGBrightness">
+      <English>Increase NVG Brightness</English>
+      <German>Nachtsichtgerätshelligkeit erhöhen</German>
+      <Spanish>Aumentar el brillo de las NVG</Spanish>
+      <Polish>Zwiększ czułość noktowizji</Polish>
+      <Czech>Zvýšení jasu noktovizoru</Czech>
+      <French>Augmenter la luminosité des JVN</French>
+      <Russian>Увеличить яркость ПНВ</Russian>
+      <Hungarian>Fényerő növelése</Hungarian>
+      <Portuguese>Aumentar Luminosidade do EVN</Portuguese>
+      <Italian>Aumenta la luminosità dell'NVG</Italian>
+    </Key>
+    <Key ID="STR_ACE_NightVision_DecreaseNVGBrightness">
+      <English>Decrease NVG Brightness</English>
+      <German>Nachtsichtgerätshelligkeit verringern</German>
+      <Spanish>Disminuir el brillo de las NVG</Spanish>
+      <Polish>Zmniejsz czułość noktowizji</Polish>
+      <Czech>Snížení jasu noktovizoru</Czech>
+      <French>Baisser la luminosité des JVN</French>
+      <Russian>Уменьшить яркость ПНВ</Russian>
+      <Hungarian>Fényerő csökkentése</Hungarian>
+      <Portuguese>Diminuir Luminosidade do EVN</Portuguese>
+      <Italian>Riduci la luminosità dell'NVG</Italian>
+    </Key>
+  </Package>
+</Project>