From 97bc371f5c55373d809d1a5144d9b462874d7392 Mon Sep 17 00:00:00 2001
From: PabstMirror <pabstmirror@gmail.com>
Date: Sun, 9 Jun 2024 18:20:39 -0500
Subject: [PATCH] Common - Add `addPlayerEH` for adding EHs to ace_player
 (#10056)

* Common - Add `addPlayerEH` for adding EHs to ace_player

* Update fnc_addPlayerEH.sqf

* convert ui to use new func
---
 addons/common/XEH_PREP.hpp                    |  1 +
 addons/common/functions/fnc_addPlayerEH.sqf   | 61 +++++++++++++++++++
 addons/ui/XEH_PREP.hpp                        |  1 -
 addons/ui/XEH_clientInit.sqf                  |  2 +-
 .../ui/functions/fnc_handlePlayerChanged.sqf  | 32 ----------
 5 files changed, 63 insertions(+), 34 deletions(-)
 create mode 100644 addons/common/functions/fnc_addPlayerEH.sqf
 delete mode 100644 addons/ui/functions/fnc_handlePlayerChanged.sqf

diff --git a/addons/common/XEH_PREP.hpp b/addons/common/XEH_PREP.hpp
index 68fdaaf77d..5a2893eeaf 100644
--- a/addons/common/XEH_PREP.hpp
+++ b/addons/common/XEH_PREP.hpp
@@ -265,6 +265,7 @@ PREP(_handleRequestAllSyncedEvents);
 PREP(addActionEventHandler);
 PREP(addActionMenuEventHandler);
 PREP(addMapMarkerCreatedEventHandler);
+PREP(addPlayerEH);
 
 PREP(removeActionEventHandler);
 PREP(removeActionMenuEventHandler);
diff --git a/addons/common/functions/fnc_addPlayerEH.sqf b/addons/common/functions/fnc_addPlayerEH.sqf
new file mode 100644
index 0000000000..81d030fb62
--- /dev/null
+++ b/addons/common/functions/fnc_addPlayerEH.sqf
@@ -0,0 +1,61 @@
+#include "..\script_component.hpp"
+/*
+ * Author: PabstMirror
+ * Adds event handler just to ACE_player
+ *
+ * Arguments:
+ * 0: Key <STRING>
+ * 1: Event Type <STRING>
+ * 2: Event Code <CODE>
+ * 3: Ignore Virtual Units (spectators, virtual zeus, uav RC) <BOOL> (default: false)
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * ["example", "FiredNear", {systemChat str _this}] call ace_common_fnc_addPlayerEH
+ *
+ * Public: Yes
+*/
+params [["_key", "", [""]], ["_type", "", [""]], ["_code", {}, [{}]], ["_ignoreVirtual", false, [false]]];
+TRACE_3("addPlayerEH",_key,_type,_ignoreVirtual);
+
+if (isNil QGVAR(playerEventsHash)) then { // first-run init
+    GVAR(playerEventsHash) = createHashMap;
+    ["unit", {
+        params ["_newPlayer", "_oldPlayer"];
+        // uav check only applies to direct controlling UAVs from zeus, no effect on normal UAV operation
+        private _isVirutal = (unitIsUAV _newPlayer) || {getNumber (configOf _newPlayer >> "isPlayableLogic") == 1};
+
+        TRACE_4("",_newPlayer,_oldPlayer,_isVirutal,count GVAR(playerEventsHash));
+        {
+            _y params ["_type", "_code", "_ignoreVirtual"];
+
+            private _oldEH = _oldPlayer getVariable [_x, -1];
+            if (_oldEH != -1) then { 
+                _oldPlayer removeEventHandler [_type, _oldEH]; 
+                _oldPlayer setVariable [_x, nil];
+            };
+
+            _oldEH = _newPlayer getVariable [_x, -1];
+            if (_oldEH != -1) then { continue }; // if respawned then var and EH already exists
+            if (_ignoreVirtual && _isVirutal) then { continue };
+
+            private _newEH = _newPlayer addEventHandler [_type, _code];
+            _newPlayer setVariable [_x, _newEH];
+        } forEach GVAR(playerEventsHash);
+    }, false] call CBA_fnc_addPlayerEventHandler;
+};
+
+
+_key = format [QGVAR(playerEvents_%1), toLower _key];
+if (_key in GVAR(playerEventsHash)) exitWith { ERROR_1("bad key %1",_this); };
+
+GVAR(playerEventsHash) set [_key, [_type, _code, _ignoreVirtual]];
+
+if (isNull ACE_player) exitWith {};
+if (_ignoreVirtual && {(unitIsUAV ACE_player) || {getNumber (configOf ACE_player >> "isPlayableLogic") == 1}}) exitWith {};
+
+// Add event now
+private _newEH = ACE_player addEventHandler [_type, _code];
+ACE_player setVariable [_key, _newEH];
diff --git a/addons/ui/XEH_PREP.hpp b/addons/ui/XEH_PREP.hpp
index f7edabcc3f..436e59361c 100644
--- a/addons/ui/XEH_PREP.hpp
+++ b/addons/ui/XEH_PREP.hpp
@@ -1,5 +1,4 @@
 PREP(compileConfigUI);
-PREP(handlePlayerChanged);
 PREP(handleSpeedIndicator);
 PREP(moduleInit);
 PREP(onAnimChanged);
diff --git a/addons/ui/XEH_clientInit.sqf b/addons/ui/XEH_clientInit.sqf
index 1ef328b176..d7f1df73fb 100644
--- a/addons/ui/XEH_clientInit.sqf
+++ b/addons/ui/XEH_clientInit.sqf
@@ -48,4 +48,4 @@ GVAR(elementsSet) = call CBA_fnc_createNamespace;
     }] call CBA_fnc_addEventHandler;
 }] call CBA_fnc_addEventHandler;
 
-["unit", LINKFUNC(handlePlayerChanged), true] call CBA_fnc_addPlayerEventHandler;
+[QUOTE(ADDON), "AnimChanged", LINKFUNC(onAnimChanged)] call EFUNC(common,addPlayerEH);
diff --git a/addons/ui/functions/fnc_handlePlayerChanged.sqf b/addons/ui/functions/fnc_handlePlayerChanged.sqf
deleted file mode 100644
index 94f317a18c..0000000000
--- a/addons/ui/functions/fnc_handlePlayerChanged.sqf
+++ /dev/null
@@ -1,32 +0,0 @@
-#include "..\script_component.hpp"
-/*
- * Author: veteran29
- * Handles switching units.
- *
- * Arguments:
- * 0: New Unit <OBJECT>
- * 1: Old Unit <OBJECT>
- *
- * Return Value:
- * None
- *
- * Example:
- * [newbob, oldbob] call ace_ui_fnc_handlePlayerChanged
- *
- * Public: No
- */
-params ["_newUnit", "_oldUnit"];
-TRACE_2("unit changed",_newUnit,_oldUnit);
-
-if (!isNull _oldUnit) then {
-    _oldUnit removeEventHandler ["AnimChanged", _oldUnit getVariable [QGVAR(animHandler), -1]];
-    _oldUnit setVariable [QGVAR(animHandler), nil];
-    TRACE_1("remove old",_oldUnit getVariable QGVAR(animHandler));
-};
-
-// Don't add a new EH if the unit respawned
-if (_newUnit getVariable [QGVAR(animHandler), -1] == -1) then {
-    private _animHandler = _newUnit addEventHandler ["AnimChanged", LINKFUNC(onAnimChanged)];
-    TRACE_1("add new",_animHandler);
-    _newUnit setVariable [QGVAR(animHandler), _animHandler];
-};