- Added isFeatureCameraActive to ace_common

- ace_goggles_fnc_externalCamera now checks for cameras made by a BI feature

addons/common/XEH_preInit.sqf

@@ -107,6 +107,7 @@ PREP(isAutoWind);
 PREP(isAwake);
 PREP(isEngineer);
 PREP(isEOD);
+PREP(isFeatureCameraActive);
 PREP(isInBuilding);
 PREP(isModLoaded);
 PREP(isPlayer);

addons/common/functions/fnc_isFeatureCameraActive.sqf

@@ -0,0 +1,31 @@
+/*
+ * Author: Sniperwolf572
+ *
+ * Checks if one of the following BI feature cameras are active:
+ *
+ * - Classic camera (BIS_fnc_cameraOld)
+ * - Splendid camera (BIS_fnc_camera)
+ * - Arsenal camera (BIS_fnc_arsenal)
+ * - Animation viewer (BIS_fnc_animViewer)
+ * - Establishing shot (BIS_fnc_establishingShot)
+ *
+ * Arguments:
+ * None
+ *
+ * Return value:
+ * Is BI feature camera active (bool)
+ *
+ * Example:
+ * call ace_common_fnc_isFeatureCameraActive;
+ *
+ */
+
+#include "script_component.hpp"
+
+(
+	!isNull (missionNamespace getVariable ["BIS_DEBUG_CAM", objNull]) || // Classic camera
+    {!isNull (missionNamespace getVariable ["BIS_fnc_camera_cam", objNull])} || // Splendid camera
+    {!isNull (uiNamespace getVariable ["BIS_fnc_arsenal_cam", objNull])} || // Arsenal camera
+    {!isNull (uiNamespace getVariable ["BIS_fnc_animViewer_cam", objNull])} || // Animation viewer camera
+    {!isNull (missionNamespace getVariable ["BIS_fnc_establishingShot_fakeUAV", objNull])} // Establishing shot camera   
+)

addons/goggles/functions/fnc_externalCamera.sqf

@@ -16,4 +16,5 @@
 #include "script_component.hpp"
 
 if (GVAR(showInThirdPerson)) exitWith { false };
-(cameraView == "EXTERNAL" || cameraView == "GROUP")
+
+(cameraView in ["EXTERNAL", "GROUP"] || {call EFUNC(common,isFeatureCameraActive)})