Merge branch 'master' of https://github.com/acemod/ACE3

2024-08-30 18:23:18 +00:00 · 2015-04-15 06:45:42 +03:00 · 2015-04-15 06:45:42 +03:00 · df8a958c42
commit df8a958c42
parent 21c9272293 7ad9238bbf
480 changed files with 15976 additions and 8766 deletions
--- a/AUTHORS.txt
+++ b/AUTHORS.txt
@ -56,6 +56,7 @@ Kllrt <kllrtik@gmail.com>
 Legolasindar "Viper" <legolasindar@gmail.com>
 licht-im-Norden87 <lichtimnorden87@gmail.com>
 MarcBook
+meat <p.humberdroz@gmail.com>
 Michail Nikolaev
 nic547 <nic547@outlook.com>
 oscarmolinadev
@ -74,3 +75,5 @@ Aleksey EpMAK Yermakov <epmak777@gmail.com>
 ruPaladin <happyworm24@rambler.ru>
 BlackPixxel
 Asgar Serran <piechottaf@web.de>
+Kavinsky <nmunozfernandez@gmail.com>
+
--- a/ace_advanced_ballistics.dll
+++ b/ace_advanced_ballistics.dll
--- a/ace_breakLine.dll
+++ b/ace_breakLine.dll
--- a/ace_fcs.dll
+++ b/ace_fcs.dll
--- a/addons/advanced_ballistics/ACE_Settings.hpp
+++ b/addons/advanced_ballistics/ACE_Settings.hpp
@ -0,0 +1,64 @@
+class ACE_Settings {
+    class GVAR(enabled) {
+        displayName = "Advanced Ballistics";
+        description = "Enables advanced ballistics";
+        typeName = "BOOL";
+        value = 0;
+    };
+    class GVAR(alwaysSimulateForSnipers) {
+        displayName = "Always Enabled For Snipers";
+        description = "Always enables advanced ballistics when high power optics are used";
+        typeName = "BOOL";
+        value = 1;
+    };
+    class GVAR(disabledInFullAutoMode) {
+        displayName = "Disabled In FullAuto Mode";
+        description = "Disables the advanced ballistics during full auto fire";
+        typeName = "BOOL";
+        value = 0;
+    };
+    class GVAR(onlyActiveForLocalPlayers) {
+        displayName = "Disabled For Non Local Players";
+        description = "Disables the advanced ballistics for bullets coming from other players (enable this if you encounter frame drops during heavy firefights in multiplayer)";
+        typeName = "BOOL";
+        value = 1;
+    };
+    /* // TODO: We currently do not have firedEHs on vehicles
+    class GVAR(vehicleGunnerEnabled) {
+        displayName = "Enabled For Vehicle Gunners";
+        description = "Enables advanced ballistics for vehicle gunners";
+        typeName = "BOOL";
+        value = 0;
+    };
+    */
+    class GVAR(ammoTemperatureEnabled) {
+        displayName = "Enable Ammo Temperature Simulation";
+        description = "Muzzle velocity varies with ammo temperature";
+        typeName = "BOOL";
+        value = 1;
+    };
+    class GVAR(barrelLengthInfluenceEnabled) {
+        displayName = "Enable Barrel Length Simulation";
+        description = "Muzzle velocity varies with barrel length";
+        typeName = "BOOL";
+        value = 1;
+    };
+    class GVAR(bulletTraceEnabled) {
+        displayName = "Enable Bullet Trace Effect";
+        description = "Enables a bullet trace effect to high caliber bullets (only visible when looking through high power optics)";
+        typeName = "BOOL";
+        value = 1;
+    };
+    class GVAR(simulationInterval) {
+        displayName = "Simulation Interval";
+        description = "Defines the interval between every calculation step";
+        typeName = "SCALAR";
+        value = 0.0;
+    };
+    class GVAR(simulationRadius) {
+        displayName = "Simulation Radius";
+        description = "Defines the radius (in meters) in which advanced ballistics are applied";
+        typeName = "SCALAR";
+        value = 3000;
+    };
+};
--- a/addons/advanced_ballistics/CfgEventHandlers.hpp
+++ b/addons/advanced_ballistics/CfgEventHandlers.hpp
@ -0,0 +1,19 @@
+class Extended_PreInit_EventHandlers {
+    class ADDON {
+        init = QUOTE( call COMPILE_FILE(XEH_preInit) );
+    };
+};
+
+class Extended_PostInit_EventHandlers {
+    class ADDON {
+        init = QUOTE( call COMPILE_FILE(XEH_postInit) );
+    };
+};
+
+class Extended_FiredBIS_EventHandlers {
+    class CAManBase {
+        class ADDON {
+            firedBIS = QUOTE(_this call FUNC(handleFired));
+        };
+    };
+};
--- a/addons/advanced_ballistics/CfgVehicles.hpp
+++ b/addons/advanced_ballistics/CfgVehicles.hpp
@ -0,0 +1,78 @@
+class CfgVehicles {
+    class ACE_Module;
+    class GVAR(ModuleSettings): ACE_Module {
+        scope = 2;
+        displayName = "Advanced Ballistics";
+        icon = QUOTE(PATHTOF(UI\Icon_Module_Wind_ca.paa));
+        category = "ACE";
+        function = QUOTE(DFUNC(initModuleSettings));
+        functionPriority = 1;
+        isGlobal = 1;
+        isTriggerActivated = 0;
+        author = "Ruthberg";
+        class Arguments {
+            class enabled {
+                displayName = "Advanced Ballistics";
+                description = "Enables advanced ballistics";
+                typeName = "BOOL";
+                defaultValue = 0;
+            };
+            class alwaysSimulateForSnipers {
+                displayName = "Always Enabled For Snipers";
+                description = "Always enables advanced ballistics when high power optics are used";
+                typeName = "BOOL";
+                defaultValue = 1;
+            };
+            class disabledInFullAutoMode {
+                displayName = "Disabled In FullAuto Mode";
+                description = "Disables the advanced ballistics during full auto fire";
+                typeName = "BOOL";
+                defaultValue = 0;
+            };
+            class onlyActiveForLocalPlayers {
+                displayName = "Disabled For Non Local Players";
+                description = "Disables the advanced ballistics for bullets coming from other players (enable this if you encounter frame drops during heavy firefights in multiplayer)";
+                typeName = "BOOL";
+                defaultValue = 1;
+            };
+            /* // TODO: We currently do not have firedEHs on vehicles
+            class vehicleGunnerEnabled {
+                displayName = "Enabled For Vehicle Gunners";
+                description = "Enables advanced ballistics for vehicle gunners";
+                typeName = "BOOL";
+                defaultValue = 0;
+            };
+            */
+            class ammoTemperatureEnabled {
+                displayName = "Enable Ammo Temperature Simulation";
+                description = "Muzzle velocity varies with ammo temperature";
+                typeName = "BOOL";
+                defaultValue = 1;
+            };
+            class barrelLengthInfluenceEnabled {
+                displayName = "Enable Barrel Length Simulation";
+                description = "Muzzle velocity varies with barrel length";
+                typeName = "BOOL";
+                defaultValue = 1;
+            };
+            class bulletTraceEnabled {
+                displayName = "Enable Bullet Trace Effect";
+                description = "Enables a bullet trace effect to high caliber bullets (only visible when looking through high power optics)";
+                typeName = "BOOL";
+                defaultValue = 1;
+            };
+            class simulationInterval {
+                displayName = "Simulation Interval";
+                description = "Defines the interval between every calculation step";
+                typeName = "NUMBER";
+                defaultValue = 0.0;
+            };
+            class simulationRadius {
+                displayName = "Simulation Radius";
+                description = "Defines the radius (in meters) in which advanced ballistics are applied";
+                typeName = "NUMBER";
+                defaultValue = 3000;
+            };
+        };
+    };
+};
--- a/addons/advanced_ballistics/README.md
+++ b/addons/advanced_ballistics/README.md
@ -0,0 +1,10 @@
+ace_advanced_ballistics
+===============
+
+The Advanced Ballistics module introduces advanced external- and internal ballistics to the game.
+
+## Maintainers
+
+The people responsible for merging changes to this component or answering potential questions.
+
+- [Ruthberg] (http://github.com/Ulteq)
--- a/addons/advanced_ballistics/RscTitles.hpp
+++ b/addons/advanced_ballistics/RscTitles.hpp
@ -0,0 +1,63 @@
+class RscTitles
+{
+    class RscTurretDial
+    {
+        idd=-1;
+        onLoad="with uiNameSpace do { RscTurretDial = _this select 0 };";
+        movingEnable=0;
+        duration=5;
+        fadeIn="false";
+        fadeOut="false";
+        class controls
+        {
+            class RscTurretDial
+            {
+                idc=132949;
+                type=0;
+                style=128;
+                font="TahomaB";
+                colorBackground[]={0,0,0,0.8};
+                colorText[]={1,1,1,1};
+                x="SafeZoneX + 0.0025";
+                y="SafeZoneY + 0.0025";
+                w=0.10;
+                h=0.05;
+                sizeEx=0.03;
+                text="";
+            };
+        };
+    };
+
+    class RscProtractor
+    {
+        idd=-1;
+        onLoad="with uiNameSpace do { RscProtractor = _this select 0 };";
+        movingEnable=0;
+        duration=60;
+        fadeIn="false";
+        fadeOut="false";
+        class controls
+        {
+            class RscProtractorBase
+            {
+                idc=132950;
+                type=0;
+                style=48;
+                font="TahomaB";
+                colorBackground[]={0,0,0,0};
+                colorText[]={1,1,1,1};
+                x="SafeZoneX + 0.001";
+                y="SafeZoneY + 0.001";
+                w=0.2;
+                h=0.2*4/3;
+                size=0.034;
+                sizeEx=0.027;
+                text="";
+            };
+            class RscProtractorMarker : RscProtractorBase
+            {
+                idc=132951;
+            };
+        };
+    };
+};
--- a/addons/advanced_ballistics/UI/Icon_Module_Wind_ca.paa
+++ b/addons/advanced_ballistics/UI/Icon_Module_Wind_ca.paa
--- a/addons/advanced_ballistics/UI/protractor.paa
+++ b/addons/advanced_ballistics/UI/protractor.paa
--- a/addons/advanced_ballistics/UI/protractor_marker.paa
+++ b/addons/advanced_ballistics/UI/protractor_marker.paa
--- a/addons/advanced_ballistics/XEH_postInit.sqf
+++ b/addons/advanced_ballistics/XEH_postInit.sqf
@ -0,0 +1,45 @@
+#include "script_component.hpp"
+
+#include "initKeybinds.sqf"
+
+GVAR(currentbulletID) = -1;
+
+GVAR(bulletDatabase) = [];
+GVAR(bulletDatabaseStartTime) = [];
+GVAR(bulletDatabaseSpeed) = [];
+GVAR(bulletDatabaseFrames) = [];
+GVAR(bulletDatabaseLastFrame) = [];
+GVAR(bulletDatabaseHDeflect) = [];
+GVAR(bulletDatabaseSpinDrift) = [];
+GVAR(bulletDatabaseOccupiedIndices) = [];
+GVAR(bulletDatabaseFreeIndices) = [];
+
+GVAR(WindInfo) = false;
+GVAR(WindInfoStart) = time;
+
+GVAR(Protractor) = false;
+GVAR(ProtractorStart) = time;
+
+// Those are only used in the pure sqf version (extension free PFH)
+GVAR(SimulationPrecision) = 2;
+GVAR(WindEnabled) = true;
+GVAR(SpinDriftEnabled) = true;
+GVAR(CoriolisEnabled) = true;
+GVAR(EoetvoesEnabled) = true;
+GVAR(AdvancedAirDragEnabled) = true;
+GVAR(TransonicRegionEnabled) = true;
+GVAR(AtmosphericDensitySimulationEnabled) = true;
+
+GVAR(currentGrid) = 0;
+GVAR(INIT_MESSAGE_ENABLED) = false;
+
+GVAR(extensionAvailable) = "ace_advanced_ballistics" callExtension "version" == "1.0";
+if (!GVAR(extensionAvailable)) exitWith {
+    if ("ace_advanced_ballistics" callExtension "version" == "") then {
+        diag_log text "[ACE] ERROR: ace_advanced_ballistics.dll is missing";
+    } else {
+        diag_log text "[ACE] ERROR: ace_advanced_ballistics.dll is incompatible";
+    };
+};
+
+[] call FUNC(initializeTerrainExtension);
--- a/addons/advanced_ballistics/XEH_preInit.sqf
+++ b/addons/advanced_ballistics/XEH_preInit.sqf
@ -0,0 +1,18 @@
+#include "script_component.hpp"
+
+ADDON = false;
+
+PREP(calculateAirDensity);
+PREP(calculateAmmoTemperatureVelocityShift);
+PREP(calculateAtmosphericCorrection);
+PREP(calculateBarrelLengthVelocityShift);
+PREP(calculateRetardation);
+PREP(calculateRoughnessLength);
+PREP(calculateStabilityFactor);
+PREP(calculateWindSpeed);
+PREP(displayProtractor);
+PREP(handleFired);
+PREP(initializeTerrainExtension);
+PREP(initModuleSettings);
+
+ADDON = true;
--- a/addons/advanced_ballistics/config.cpp
+++ b/addons/advanced_ballistics/config.cpp
@ -0,0 +1,18 @@
+#include "script_component.hpp"
+
+class CfgPatches {
+    class ADDON {
+        units[] = {};
+        weapons[] = {};
+        requiredVersion = REQUIRED_VERSION;
+        requiredAddons[] = {"ace_ballistics", "ace_weather", "ace_modules"};
+        author[] = {"Ruthberg"};
+        authorUrl = "https://github.com/ulteq";
+        VERSION_CONFIG;
+    };
+};
+
+#include "CfgEventHandlers.hpp"
+#include "CfgVehicles.hpp"
+#include "RscTitles.hpp"
+#include "ACE_Settings.hpp"
--- a/addons/advanced_ballistics/functions/fnc_calculateAirDensity.sqf
+++ b/addons/advanced_ballistics/functions/fnc_calculateAirDensity.sqf
@ -0,0 +1,36 @@
+/*
+ * Author: Ruthberg
+ *
+ * Displays a wind info (colored arrow) in the top left corner of the screen
+ *
+ * Arguments:
+ * 0: temperature - degrees celcius <NUMBER>
+ * 1: pressure - hPa <NUMBER>
+ * 2: relativeHumidity - value between 0.0 and 1.0 <NUMBER>
+ *
+ * Return Value:
+ * 0: density of air - kg * m^(-3) <NUMBER>
+ *
+ * Return value:
+ * None
+ */
+#include "script_component.hpp"
+
+private ["_temperature", "_pressure", "_relativeHumidity"];
+_temperature      = _this select 0; // in C
+_pressure         = _this select 1; // in hPa
+_relativeHumidity = _this select 2; // as ratio 0-1
+
+_pressure = _pressure * 100;
+
+if (_relativeHumidity > 0) then {
+    private ["_pSat", "_vaporPressure", "_partialPressure"];
+    // Saturation vapor pressure calculated according to: http://wahiduddin.net/calc/density_algorithms.htm
+    _pSat = 6.1078 * 10 ^ ((7.5 * _temperature) / (_temperature + 237.3));
+    _vaporPressure = _relativeHumidity * _pSat;
+    _partialPressure = _pressure - _vaporPressure;
+
+    (_partialPressure * DRY_AIR_MOLAR_MASS + _vaporPressure * WATER_VAPOR_MOLAR_MASS) / (UNIVERSAL_GAS_CONSTANT * KELVIN(_temperature))
+} else {
+    _pressure / (SPECIFIC_GAS_CONSTANT_DRY_AIR * KELVIN(_temperature))
+};
--- a/addons/advanced_ballistics/functions/fnc_calculateAmmoTemperatureVelocityShift.sqf
+++ b/addons/advanced_ballistics/functions/fnc_calculateAmmoTemperatureVelocityShift.sqf
@ -0,0 +1,42 @@
+/*
+ * Author: Ruthberg
+ *
+ * Calculates the ammo temperature induced muzzle velocity shift
+ *
+ * Arguments:
+ * 0: ammo - classname <string>
+ * 1: temperature - degrees celcius <NUMBER>
+ *
+ * Return Value:
+ * 0: muzzle velocity shift - m/s <NUMBER>
+ *
+ * Return value:
+ * None
+ */
+#include "script_component.hpp"
+
+private ["_ammo", "_temperature", "_muzzleVelocityTable", "_muzzleVelocityShift", "_temperatureIndexA", "_temperatureIndexB", "_temperatureRatio"];
+_ammo           = _this select 0;
+_temperature    = _this select 1;
+
+_muzzleVelocityTable = [];
+
+if (isArray(configFile >> "cfgAmmo" >> _ammo >> "ACE_ammoTempMuzzleVelocityShifts")) then {
+    _muzzleVelocityTable = getArray(configFile >> "cfgAmmo" >> _ammo >> "ACE_ammoTempMuzzleVelocityShifts");
+};
+
+if (count _muzzleVelocityTable != 11) exitWith { 0 };
+
+_temperatureIndexA = floor((_temperature + 15) / 5);
+_temperatureIndexA = 0 max _temperatureIndexA;
+_temperatureIndexA = _temperatureIndexA min 10;
+
+_temperatureIndexB = ceil((_temperature + 15) / 5);
+_temperatureIndexB = 0 max _temperatureIndexB;
+_temperatureIndexB = _temperatureIndexB min 10;
+
+_temperatureRatio = ((_temperature + 15) / 5) - floor((_temperature + 15) / 5);
+
+_muzzleVelocityShift = (_muzzleVelocityTable select _temperatureIndexA) * (1 - _temperatureRatio) + (_muzzleVelocityTable select _temperatureIndexB) * _temperatureRatio;
+
+_muzzleVelocityShift
--- a/addons/advanced_ballistics/functions/fnc_calculateAtmosphericCorrection.sqf
+++ b/addons/advanced_ballistics/functions/fnc_calculateAtmosphericCorrection.sqf
@ -0,0 +1,33 @@
+/*
+ * Author: Ruthberg
+ *
+ * Calculates the atmospherically corrected ballistic coefficient
+ *
+ * Arguments:
+ * 0: ballistic coefficient - G1-G7 <NUMBER>
+ * 1: temperature - degrees celcius <NUMBER>
+ * 2: pressure - hPa <NUMBER>
+ * 3: relativeHumidity - value between 0.0 and 1.0 <NUMBER>
+ * 4: atmosphereModel - ICAO or ASM <STRING>
+ *
+ * Return Value:
+ * corrected ballistic coefficient <NUMBER>
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+private ["_ballisticCoefficient", "_temperature", "_pressure", "_relativeHumidity", "_atmosphereModel", "_airDensity"];
+_ballisticCoefficient = _this select 0;
+_temperature          = _this select 1; // in C
+_pressure             = _this select 2; // in hPa
+_relativeHumidity     = _this select 3; // as ratio 0-1
+_atmosphereModel      = _this select 4; // "ICAO" or "ASM"
+
+_airDensity = [_temperature, _pressure, _relativeHumidity] call FUNC(calculateAirDensity);
+
+if (_atmosphereModel == "ICAO") then {
+    (STD_AIR_DENSITY_ICAO / _airDensity) * _ballisticCoefficient
+} else {
+    (STD_AIR_DENSITY_ASM / _airDensity) * _ballisticCoefficient
+};
--- a/addons/advanced_ballistics/functions/fnc_calculateBarrelLengthVelocityShift.sqf
+++ b/addons/advanced_ballistics/functions/fnc_calculateBarrelLengthVelocityShift.sqf
@ -0,0 +1,66 @@
+/*
+ * Author: Ruthberg
+ *
+ * Calculates the muzzle velocity shift caused by different barrel lengths
+ *
+ * Arguments:
+ * 0: ammo - classname <string>
+ * 0: weapon - classname <string>
+ * 1: muzzle velocity - m/s <NUMBER>
+ *
+ * Return Value:
+ * 0: muzzle velocity shift - m/s <NUMBER>
+ *
+ * Return value:
+ * None
+ */
+#include "script_component.hpp"
+
+private ["_ammo", "_weapon", "_barrelLength", "_muzzleVelocityTable", "_barrelLengthTable", "_muzzleVelocity", "_lowerIndex", "_upperIndex", "_barrelLengthRatio", "_muzzleVelocityNew"];
+_ammo           = _this select 0;
+_weapon         = _this select 1;
+_muzzleVelocity = _this select 2;
+
+_barrelLength = getNumber(configFile >> "cfgWeapons" >> _weapon >> "ACE_barrelLength");
+
+if (_barrelLength == 0) exitWith { 0 };
+
+_muzzleVelocityTable = [];
+_barrelLengthTable = [];
+
+if (isArray(configFile >> "cfgAmmo" >> _ammo >> "ACE_muzzleVelocities")) then {
+    _muzzleVelocityTable = getArray(configFile >> "cfgAmmo" >> _ammo >> "ACE_muzzleVelocities");
+};
+if (isArray(configFile >> "cfgAmmo" >> _ammo >> "ACE_barrelLengths")) then {
+    _barrelLengthTable = getArray(configFile >> "cfgAmmo" >> _ammo >> "ACE_barrelLengths");
+};
+
+if (count _muzzleVelocityTable != count _barrelLengthTable) exitWith { 0 };
+if (count _muzzleVelocityTable == 0 || count _barrelLengthTable == 0) exitWith { 0 };
+if (count _muzzleVelocityTable == 1) exitWith { (_muzzleVelocityTable select 0) - _muzzleVelocity };
+
+_lowerIndex = 0;
+_upperIndex = (count _barrelLengthTable) - 1;
+
+if (_barrelLength <= (_barrelLengthTable select _lowerIndex)) exitWith { (_muzzleVelocityTable select _lowerIndex) - _muzzleVelocity };
+if (_barrelLength >= (_barrelLengthTable select _upperIndex)) exitWith { (_muzzleVelocityTable select _upperIndex) - _muzzleVelocity };
+
+for "_i" from 0 to (count _barrelLengthTable) - 1 do {
+    if (_barrelLength >= _barrelLengthTable select _i) then {
+        _lowerIndex = _i;
+    };
+};
+for "_i" from (count _barrelLengthTable) - 1 to 0 step -1 do {
+    if (_barrelLength <= _barrelLengthTable select _i) then {
+        _upperIndex = _i;
+    };
+};
+
+_barrelLengthRatio = 0;
+if ((_barrelLengthTable select _upperIndex) - (_barrelLengthTable select _lowerIndex) > 0) then {
+    _barrelLengthRatio = ((_barrelLengthTable select _upperIndex) - _barrelLength) / ((_barrelLengthTable select _upperIndex) - (_barrelLengthTable select _lowerIndex));
+};
+
+_muzzleVelocityNew = (_muzzleVelocityTable select _lowerIndex) + ((_muzzleVelocityTable select _upperIndex) - (_muzzleVelocityTable select _lowerIndex)) * (1 - _barrelLengthRatio);
+
+_muzzleVelocityNew - _muzzleVelocity
--- a/addons/advanced_ballistics/functions/fnc_calculateRetardation.sqf
+++ b/addons/advanced_ballistics/functions/fnc_calculateRetardation.sqf
@ -0,0 +1,145 @@
+/*
+ * Author: Ruthberg
+ *
+ * Calculates the retardation of the bullet
+ *
+ * Arguments:
+ * 0: drag model - 1-7 <integer>
+ * 1: drag coefficient - bc <NUMBER>
+ * 2: velocity - m/s <NUMBER>
+ *
+ * Return Value:
+ * 0: retardation - m/(s^2) <NUMBER>
+ *
+ * Return value:
+ * None
+ */
+#include "script_component.hpp"
+
+// Source: GNU Exterior Ballistics
+
+private ["_dragModel", "_dragCoefficient", "_velocity", "_A", "_M", "_result"];
+_dragModel       = _this select 0;
+_dragCoefficient = _this select 1;
+_velocity        = (_this select 2) * 3.2808399;
+
+_A = -1;
+_M = -1;
+_result = 0;
+
+switch _dragModel do {
+    case 1:
+    {
+        switch true do {
+            case (_velocity > 4230) : { _A = 0.0001477404177730177; _M = 1.9565; };
+            case (_velocity > 3680) : { _A = 0.0001920339268755614; _M = 1.925 ; };
+            case (_velocity > 3450) : { _A = 0.0002894751026819746; _M = 1.875 ; };
+            case (_velocity > 3295) : { _A = 0.0004349905111115636; _M = 1.825 ; };
+            case (_velocity > 3130) : { _A = 0.0006520421871892662; _M = 1.775 ; };
+            case (_velocity > 2960) : { _A = 0.0009748073694078696; _M = 1.725 ; };
+            case (_velocity > 2830) : { _A = 0.001453721560187286; _M = 1.675 ; };
+            case (_velocity > 2680) : { _A = 0.002162887202930376; _M = 1.625 ; };
+            case (_velocity > 2460) : { _A = 0.003209559783129881; _M = 1.575 ; };
+            case (_velocity > 2225) : { _A = 0.003904368218691249; _M = 1.55  ; };
+            case (_velocity > 2015) : { _A = 0.003222942271262336; _M = 1.575 ; };
+            case (_velocity > 1890) : { _A = 0.002203329542297809; _M = 1.625 ; };
+            case (_velocity > 1810) : { _A = 0.001511001028891904; _M = 1.675 ; };
+            case (_velocity > 1730) : { _A = 0.0008609957592468259; _M = 1.75  ; };
+            case (_velocity > 1595) : { _A = 0.0004086146797305117; _M = 1.85  ; };
+            case (_velocity > 1520) : { _A = 0.0001954473210037398; _M = 1.95  ; };
+            case (_velocity > 1420) : { _A = 0.00005431896266462351; _M = 2.125 ; };
+            case (_velocity > 1360) : { _A = 0.000008847742581674416; _M = 2.375 ; };
+            case (_velocity > 1315) : { _A = 0.000001456922328720298; _M = 2.625 ; };
+            case (_velocity > 1280) : { _A = 0.0000002419485191895565; _M = 2.875 ; };
+            case (_velocity > 1220) : { _A = 0.00000001657956321067612; _M = 3.25  ; };
+            case (_velocity > 1185) : { _A = 0.0000000004745469537157371; _M = 3.75  ; };
+            case (_velocity > 1150) : { _A = 0.00000000001379746590025088; _M = 4.25  ; };
+            case (_velocity > 1100) : { _A = 0.0000000000004070157961147882; _M = 4.75  ; };
+            case (_velocity > 1060) : { _A = 0.00000000000002938236954847331; _M = 5.125 ; };
+            case (_velocity > 1025) : { _A = 0.00000000000001228597370774746; _M = 5.25  ; };
+            case (_velocity >  980) : { _A = 0.00000000000002916938264100495; _M = 5.125 ; };
+            case (_velocity >  945) : { _A = 0.0000000000003855099424807451; _M = 4.75  ; };
+            case (_velocity >  905) : { _A = 0.00000000001185097045689854; _M = 4.25  ; };
+            case (_velocity >  860) : { _A = 0.0000000003566129470974951; _M = 3.75  ; };
+            case (_velocity >  810) : { _A = 0.00000001045513263966272; _M = 3.25  ; };
+            case (_velocity >  780) : { _A = 0.0000001291159200846216; _M = 2.875 ; };
+            case (_velocity >  750) : { _A = 0.0000006824429329105383; _M = 2.625 ; };
+            case (_velocity >  700) : { _A = 0.000003569169672385163; _M = 2.375 ; };
+            case (_velocity >  640) : { _A = 0.00001839015095899579; _M = 2.125 ; };
+            case (_velocity >  600) : { _A = 0.00005711174688734240; _M = 1.950 ; };
+            case (_velocity >  550) : { _A = 0.00009226557091973427; _M = 1.875 ; };
+            case (_velocity >  250) : { _A = 0.00009337991957131389; _M = 1.875 ; };
+            case (_velocity >  100) : { _A = 0.00007225247327590413; _M = 1.925 ; };
+            case (_velocity >   65) : { _A = 0.00005792684957074546; _M = 1.975 ; };
+            case (_velocity >    0) : { _A = 0.00005206214107320588; _M = 2.000 ; };
+        };
+    };
+    case 2:
+    {
+        switch true do {
+            case (_velocity > 1674) : { _A = 0.0079470052136733; _M = 1.36999902851493; };
+            case (_velocity > 1172) : { _A = 0.00100419763721974; _M = 1.65392237010294; };
+            case (_velocity > 1060) : { _A = 0.0000000000000000000000715571228255369;  _M = 7.91913562392361; };
+            case (_velocity >  949) : { _A = 0.000000000139589807205091; _M = 3.81439537623717; };
+            case (_velocity >  670) : { _A = 0.000234364342818625; _M = 1.71869536324748; };
+            case (_velocity >  335) : { _A = 0.000177962438921838; _M = 1.76877550388679; };
+            case (_velocity >    0) : { _A = 0.0000518033561289704; _M = 1.98160270524632; };
+        };
+    };
+    case 5:
+    {
+        switch true do {
+            case (_velocity > 1730) : { _A = 0.00724854775171929; _M = 1.41538574492812; };
+            case (_velocity > 1228) : { _A = 0.0000350563361516117; _M = 2.13077307854948; };
+            case (_velocity > 1116) : { _A = 0.000000000000184029481181151; _M = 4.81927320350395; };
+            case (_velocity > 1004) : { _A = 0.000000000000000000000134713064017409; _M = 7.8100555281422 ; };
+            case (_velocity >  837) : { _A = 0.000000103965974081168; _M = 2.84204791809926; };
+            case (_velocity >  335) : { _A = 0.0001093015938698234; _M = 1.81096361579504; };
+            case (_velocity >    0) : { _A = 0.0000351963178524273; _M = 2.00477856801111; };
+        };
+    };
+    case 6:
+    {
+        switch true do {
+            case (_velocity > 3236) : { _A = 0.0455384883480781; _M = 1.15997674041274; };
+            case (_velocity > 2065) : { _A = 0.07167261849653769; _M = 1.10704436538885; };
+            case (_velocity > 1311) : { _A = 0.00166676386084348; _M = 1.60085100195952; };
+            case (_velocity > 1144) : { _A = 0.000000101482730119215; _M = 2.9569674731838 ; };
+            case (_velocity > 1004) : { _A = 0.00000000000000000431542773103552; _M = 6.34106317069757; };
+            case (_velocity >  670) : { _A = 0.0000204835650496866; _M = 2.11688446325998; };
+            case (_velocity >    0) : { _A = 0.0000750912466084823; _M = 1.92031057847052; };
+        };
+    };
+    case 7:
+    {
+        switch true do {
+            case (_velocity > 4200) : { _A = 0.00000000129081656775919; _M = 3.24121295355962; };
+            case (_velocity > 3000) : { _A = 0.0171422231434847; _M = 1.27907168025204; };
+            case (_velocity > 1470) : { _A = 0.00233355948302505; _M = 1.52693913274526; };
+            case (_velocity > 1260) : { _A = 0.000797592111627665; _M = 1.67688974440324; };
+            case (_velocity > 1110) : { _A = 0.00000000000571086414289273; _M = 4.3212826264889 ; };
+            case (_velocity >  960) : { _A = 0.0000000000000000302865108244904; _M = 5.99074203776707; };
+            case (_velocity >  670) : { _A = 0.00000752285155782535; _M = 2.1738019851075 ; };
+            case (_velocity >  540) : { _A = 0.0000131766281225189; _M = 2.08774690257991; };
+            case (_velocity >    0) : { _A = 0.0000134504843776525; _M = 2.08702306738884; };
+        };
+    };
+    case 8:
+    {
+        switch true do {
+            case (_velocity > 3571) : { _A = 0.0112263766252305; _M = 1.33207346655961; };
+            case (_velocity > 1841) : { _A = 0.0167252613732636; _M = 1.28662041261785; };
+            case (_velocity > 1120) : { _A = 0.00220172456619625; _M = 1.55636358091189; };
+            case (_velocity > 1088) : { _A = 0.00000000000000020538037167098; _M = 5.80410776994789; };
+            case (_velocity >  976) : { _A = 0.00000000000592182174254121; _M = 4.29275576134191; };
+            case (_velocity >    0) : { _A = 0.000043917343795117; _M = 1.99978116283334; };
+        };
+    };
+};
+
+if (_A != -1 && _M != -1 && _velocity > 0 && _velocity < 10000) then {
+    _result = _A * (_velocity ^ _M) / _dragCoefficient;
+    _result = _result / 3.2808399;
+};
+
+_result
--- a/addons/advanced_ballistics/functions/fnc_calculateRoughnessLength.sqf
+++ b/addons/advanced_ballistics/functions/fnc_calculateRoughnessLength.sqf
@ -0,0 +1,34 @@
+/*
+ * Author: Ruthberg
+ *
+ * Calculates the terrain roughness length at a given world position
+ *
+ * Arguments:
+ * 0: _this - world position <posASL>
+ *
+ * Return Value:
+ * 0: roughness length <NUMBER>
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+private ["_roughness_lengths", "_windSource", "_nearBuildings", "_isWater"];
+
+// Source: http://es.ucsc.edu/~jnoble/wind/extrap/index.html
+_roughness_lengths = [0.0002, 0.0005, 0.0024, 0.03, 0.055, 0.1, 0.2, 0.4, 0.8, 1.6];
+
+_windSource = _this vectorDiff ((vectorNormalized ACE_wind) vectorMultiply 25);
+
+_nearBuildings = count (_windSource nearObjects ["Building", 50]);
+_isWater = surfaceIsWater _windSource;
+
+if (_nearBuildings == 0 && _isWater) exitWith {
+    0.0005
+};
+
+if (_nearBuildings >= 10) exitWith {
+    1.6
+};
+
+_roughness_lengths select (2 + (_nearBuildings min 6))
--- a/addons/advanced_ballistics/functions/fnc_calculateStabilityFactor.sqf
+++ b/addons/advanced_ballistics/functions/fnc_calculateStabilityFactor.sqf
@ -0,0 +1,45 @@
+/*
+ * Author: Ruthberg
+ *
+ * Calculates the stability factor of a bullet
+ *
+ * Arguments:
+ * 0: caliber - inches <NUMBER>
+ * 1: bullet length - inches <NUMBER>
+ * 2: bullet mass - grains <NUMBER>
+ * 3: barrel twist - inches <NUMBER>
+ * 4: muzzle velocity shift - m/s <NUMBER>
+ * 5: temperature - degrees celcius <NUMBER>
+ * 6: barometric Pressure - hPA <NUMBER>
+ *
+ * Return Value:
+ * 0: stability factor <NUMBER>
+ *
+ * Public: No
+ */
+ 
+private ["_caliber", "_bulletLength", "_bulletMass", "_barrelTwist", "_muzzleVelocity", "_temperature", "_barometricPressure", "_l", "_t", "_stabilityFactor"];
+_caliber            = _this select 0;
+_bulletLength       = _this select 1;
+_bulletMass         = _this select 2;
+_barrelTwist        = _this select 3;
+_muzzleVelocity     = _this select 4;
+_temperature        = _this select 5;
+_barometricPressure = _this select 6;
+
+// Source: http://www.jbmballistics.com/ballistics/bibliography/articles/miller_stability_1.pdf
+_t = _barrelTwist / _caliber;
+_l = _bulletLength / _caliber;
+
+_stabilityFactor = 30 * _bulletMass / (_t^2 * _caliber^3 * _l * (1 + _l^2));
+
+_muzzleVelocity = _muzzleVelocity * 3.2808399;
+if (_muzzleVelocity > 1120) then {
+    _stabilityFactor = _stabilityFactor * (_muzzleVelocity / 2800) ^ (1/3);
+} else {
+    _stabilityFactor = _stabilityFactor * (_muzzleVelocity / 1120) ^ (1/3);
+};
+
+_stabilityFactor = _stabilityFactor * (_temperature + 273) / (15 + 273) * 1013.25 / _barometricPressure;
+
+_stabilityFactor
--- a/addons/advanced_ballistics/functions/fnc_calculateWindSpeed.sqf
+++ b/addons/advanced_ballistics/functions/fnc_calculateWindSpeed.sqf
@ -0,0 +1,78 @@
+/*
+ * Author: Ruthberg
+ *
+ * Calculates the true wind speed at a given world position
+ *
+ * Arguments:
+ * 0: _this - world position <posASL>
+ *
+ * Return Value:
+ * 0: wind speed - m/s <NUMBER>
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+private ["_windSpeed", "_windDir", "_height", "_newWindSpeed", "_windSource", "_roughnessLength"];
+
+fnc_polar2vect = {
+    private ["_mag2D"];
+    _mag2D = (_this select 0) * cos((_this select 2));
+    [_mag2D * sin((_this select 1)), _mag2D * cos((_this select 1)), (_this select 0) * sin((_this select 2))];
+};
+
+_windSpeed = vectorMagnitude ACE_wind;
+_windDir = (ACE_wind select 0) atan2 (ACE_wind select 1);
+
+// Wind gradient
+if (_windSpeed > 0.05) then {
+    _height = (ASLToATL _this) select 2;
+    _height = 0 max _height min 20;
+    if (_height < 20) then {
+        _roughnessLength = _this call FUNC(calculateRoughnessLength);
+        _windSpeed = _windSpeed * ln(_height / _roughnessLength) / ln(20 / _roughnessLength);
+    };
+};
+
+// Terrain effect on wind
+if (_windSpeed > 0.05) then {
+    _newWindSpeed = 0;
+    {
+        _windSource = [100, _windDir + 180, _x] call fnc_polar2vect;
+        if (!(terrainIntersectASL [_this, _this vectorAdd _windSource])) exitWith {
+            _newWindSpeed = cos(_x * 9) * _windSpeed;
+        };
+        _windSource = [100, _windDir + 180 + _x, 0] call fnc_polar2vect;
+        if (!(terrainIntersectASL [_this, _this vectorAdd _windSource])) exitWith {
+            _newWindSpeed = cos(_x * 9) * _windSpeed;
+        };
+        _windSource = [100, _windDir + 180 - _x, 0] call fnc_polar2vect;
+        if (!(terrainIntersectASL [_this, _this vectorAdd _windSource])) exitWith {
+            _newWindSpeed = cos(_x * 9) * _windSpeed;
+        };
+    } forEach [0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10];
+    _windSpeed = _newWindSpeed;
+};
+
+// Obstacle effect on wind
+if (_windSpeed > 0.05) then {
+    _newWindSpeed = 0;
+    {
+        _windSource = [20, _windDir + 180, _x] call fnc_polar2vect;
+        if (!(lineIntersects [_this, _this vectorAdd _windSource])) exitWith {
+            _newWindSpeed = cos(_x * 2) * _windSpeed;
+        };
+        _windSource = [20, _windDir + 180 + _x, 0] call fnc_polar2vect;
+        if (!(lineIntersects [_this, _this vectorAdd _windSource])) exitWith {
+            _newWindSpeed = cos(_x * 2) * _windSpeed;
+        };
+        _windSource = [20, _windDir + 180 - _x, 0] call fnc_polar2vect;
+        if (!(lineIntersects [_this, _this vectorAdd _windSource])) exitWith {
+            _newWindSpeed = cos(_x * 2) * _windSpeed;
+        };
+    } forEach [0, 5, 10, 15, 20, 25, 30, 35, 40, 45];
+    _windSpeed = _newWindSpeed;
+};
+_windSpeed = 0 max _windSpeed;
+
+_windSpeed
--- a/addons/advanced_ballistics/functions/fnc_displayProtractor.sqf
+++ b/addons/advanced_ballistics/functions/fnc_displayProtractor.sqf
@ -0,0 +1,61 @@
+/*
+ * Author: Ruthberg
+ *
+ * Displays a protractor in the top left corner of the screen
+ *
+ * Argument:
+ * None
+ *
+ * Return value:
+ * None
+ */
+#include "script_component.hpp"
+
+#define __dsp (uiNamespace getVariable "RscProtractor")
+#define __ctrl1 (__dsp displayCtrl 132950)
+#define __ctrl2 (__dsp displayCtrl 132951)
+
+private ["_inclinationAngle", "_refPosition"];
+
+if (GVAR(Protractor)) exitWith {
+    GVAR(Protractor) = false;
+    1 cutText ["", "PLAIN"];
+    true
+};
+if (weaponLowered ACE_player) exitWith { true };
+if (vehicle ACE_player != ACE_player) exitWith { true };
+if (currentWeapon ACE_player != primaryWeapon ACE_player) exitWith { true };
+
+2 cutText ["", "PLAIN"];
+EGVAR(weather,WindInfo) = false;
+0 cutText ["", "PLAIN"];
+GVAR(Protractor) = true;
+
+[{
+    if !(GVAR(Protractor) && !(weaponLowered ACE_player) && currentWeapon ACE_player == primaryWeapon ACE_player) exitWith {
+        GVAR(Protractor) = false;
+        1 cutText ["", "PLAIN"];
+        [_this select 1] call cba_fnc_removePerFrameHandler;
+    };
+    
+    _refPosition = [SafeZoneX + 0.001, SafeZoneY + 0.001, 0.2, 0.2 * 4/3];
+    
+    _inclinationAngle = asin((ACE_player weaponDirection currentWeapon ACE_player) select 2);
+    _inclinationAngle = -58 max _inclinationAngle min 58;
+    
+    1 cutRsc ["RscProtractor", "PLAIN", 1, false];
+    
+    __ctrl1 ctrlSetScale 0.75;
+    __ctrl1 ctrlCommit 0;
+    __ctrl1 ctrlSetText QUOTE(PATHTOF(UI\protractor.paa));
+    __ctrl1 ctrlSetTextColor [1, 1, 1, 1];
+    
+    __ctrl2 ctrlSetScale 0.75;
+    __ctrl2 ctrlSetPosition [(_refPosition select 0), (_refPosition select 1) - 0.0012 * _inclinationAngle, (_refPosition select 2), (_refPosition select 3)];
+    __ctrl2 ctrlCommit 0;
+    __ctrl2 ctrlSetText QUOTE(PATHTOF(UI\protractor_marker.paa));
+    __ctrl2 ctrlSetTextColor [1, 1, 1, 1];
+    
+}, 0.1, []] call CBA_fnc_addPerFrameHandler;
+
+true
--- a/addons/advanced_ballistics/functions/fnc_handleFired.sqf
+++ b/addons/advanced_ballistics/functions/fnc_handleFired.sqf
@ -0,0 +1,382 @@
+/*
+ * Author: Glowbal, Ruthberg
+ *
+ * Handles advanced ballistics for (BulletBase) projectiles
+ *
+ * Arguments:
+ * 0: unit - Object the event handler is assigned to <OBJECT>
+ * 1: weapon - Fired weapon <STRING>
+ * 2: muzzle - Muzzle that was used <STRING>
+ * 3: mode - Current mode of the fired weapon <STRING>
+ * 4: ammo - Ammo used <STRING>
+ * 5: magazine - magazine name which was used <STRING>
+ * 6: projectile - Object of the projectile that was shot <OBJECT>
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+private ["_unit", "_weapon", "_mode", "_ammo", "_magazine", "_caliber", "_bullet", "_abort", "_index", "_opticsName", "_opticType", "_bulletTraceVisible", "_temperature", "_barometricPressure", "_atmosphereModel", "_bulletMass", "_bulletLength", "_bulletTranslation", "_airFriction", "_dragModel", "_velocityBoundaryData", "_muzzleVelocity", "_muzzleVelocityCoef", "_muzzleVelocityShift", "_bulletVelocity", "_bulletSpeed", "_bulletLength", "_bulletWeight", "_barrelTwist", "_twistDirection", "_stabilityFactor", "_transonicStabilityCoef", "_ACE_Elevation", "_ACE_Windage", "_ID"];
+_unit     = _this select 0;
+_weapon   = _this select 1;
+_mode     = _this select 3;
+_ammo     = _this select 4;
+_magazine = _this select 5;
+_bullet   = _this select 6;
+
+_abort = false;
+if (!hasInterface) exitWith {};
+if (!alive _bullet) exitWith {};
+if (!GVAR(enabled)) exitWith {};
+if (!([_unit] call EFUNC(common,isPlayer))) exitWith {};
+if (underwater _unit) exitWith {};
+if (!(_ammo isKindOf "BulletBase")) exitWith {};
+if (_unit distance ACE_player > GVAR(simulationRadius)) exitWith {};
+if (GVAR(onlyActiveForLocalPlayers) && _unit != ACE_player) then { _abort = true; };
+//if (!GVAR(vehicleGunnerEnabled) && !(_unit isKindOf "Man")) then { _abort = true; }; // TODO: We currently do not have firedEHs on vehicles
+if (GVAR(disabledInFullAutoMode) && getNumber(configFile >> "cfgWeapons" >> _weapon >> _mode >> "autoFire") == 1) then { _abort = true; };
+
+if (_abort && alwaysSimulateForSnipers) then {
+    // The shooter is non local
+    if (currentWeapon _unit == primaryWeapon _unit && count primaryWeaponItems _unit > 2) then {
+        _opticsName = (primaryWeaponItems _unit) select 2;
+        _opticType = getNumber(configFile >> "cfgWeapons" >> _opticsName >> "ItemInfo" >> "opticType");
+        _abort = _opticType != 2; // We only abort if the non local shooter is not a sniper
+    };
+};
+if (_abort || !(GVAR(extensionAvailable))) exitWith {
+    [_bullet, getNumber(configFile >> "cfgAmmo" >> _ammo >> "airFriction")] call EFUNC(winddeflection,updateTrajectoryPFH);
+};
+
+_airFriction = getNumber(configFile >> "cfgAmmo" >> _ammo >> "airFriction");
+_muzzleVelocity = getNumber(configFile >> "cfgMagazines" >> _magazine >> "initSpeed");
+_muzzleVelocityCoef = getNumber(configFile >> "cfgWeapons" >> _weapon >> "initSpeed");
+if (_muzzleVelocityCoef > 0) then {
+    _muzzleVelocity = _muzzleVelocityCoef;
+};
+if (_muzzleVelocityCoef < 0) then {
+    _muzzleVelocity = _muzzleVelocity * (-1 * _muzzleVelocityCoef);
+};
+
+_muzzleAccessory = "";
+switch (currentWeapon _unit) do {
+    case primaryWeapon _unit: { _muzzleAccessory = (primaryWeaponItems _unit) select 0; };
+    case handgunWeapon _unit: { _muzzleAccessory = (handgunItems _unit) select 0; };
+};
+
+if (_muzzleAccessory != "" && isNumber(configFile >> "cfgWeapons" >> _muzzleAccessory >> "ItemInfo" >> "MagazineCoef" >> "initSpeed")) then {
+    _initSpeedCoef = getNumber(configFile >> "cfgWeapons" >> _muzzleAccessory >> "ItemInfo" >> "MagazineCoef" >> "initSpeed");
+    _muzzleVelocity = _muzzleVelocity * _initSpeedCoef;
+};
+
+if (GVAR(barrelLengthInfluenceEnabled)) then {
+    _muzzleVelocityShift = [_ammo, _weapon, _muzzleVelocity] call FUNC(calculateBarrelLengthVelocityShift);
+    if (_muzzleVelocityShift != 0) then {
+        _bulletVelocity = velocity _bullet;
+        _bulletSpeed = vectorMagnitude _bulletVelocity;
+        _bulletVelocity = _bulletVelocity vectorAdd ((vectorNormalized _bulletVelocity) vectorMultiply (_muzzleVelocityShift * (_bulletSpeed / _muzzleVelocity)));
+        _bullet setVelocity _bulletVelocity;
+        _muzzleVelocity = _muzzleVelocity + _muzzleVelocityShift;
+    };
+};
+
+if (GVAR(ammoTemperatureEnabled)) then {
+    _temperature = GET_TEMPERATURE_AT_HEIGHT((getPosASL _unit) select 2);
+    _muzzleVelocityShift = [_ammo, _temperature] call FUNC(calculateAmmoTemperatureVelocityShift);
+    if (_muzzleVelocityShift != 0) then {
+        _bulletVelocity = velocity _bullet;
+        _bulletSpeed = vectorMagnitude _bulletVelocity;
+        _bulletVelocity = _bulletVelocity vectorAdd ((vectorNormalized _bulletVelocity) vectorMultiply (_muzzleVelocityShift * (_bulletSpeed / _muzzleVelocity)));
+        _bullet setVelocity _bulletVelocity;
+        _muzzleVelocity = _muzzleVelocity + _muzzleVelocityShift;
+    };
+};
+
+// TODO: Make _bulletTraceVisible global and toggle it with events
+_bulletTraceVisible = false;
+if (GVAR(bulletTraceEnabled) && currentWeapon ACE_player == primaryWeapon ACE_player && count primaryWeaponItems ACE_player > 2) then {
+    _opticsName = (primaryWeaponItems ACE_player) select 2;
+    _opticType = getNumber(configFile >> "cfgWeapons" >> _opticsName >> "ItemInfo" >> "opticType");
+    _bulletTraceVisible = (_opticType == 2 || currentWeapon ACE_player in ["ACE_Vector", "Binocular", "Rangefinder", "Laserdesignator"]) && cameraView == "GUNNER";
+};
+
+_caliber = getNumber(configFile >> "cfgAmmo" >> _ammo >> "ACE_caliber");
+_bulletLength = getNumber(configFile >> "cfgAmmo" >> _ammo >> "ACE_bulletLength");
+_bulletMass = getNumber(configFile >> "cfgAmmo" >> _ammo >> "ACE_bulletMass");
+_barrelTwist = getNumber(configFile >> "cfgWeapons" >> _weapon >> "ACE_barrelTwist");
+_stabilityFactor = 1.5;
+
+if (_caliber > 0 && _bulletLength > 0 && _bulletMass > 0 && _barrelTwist > 0) then {
+    _temperature = GET_TEMPERATURE_AT_HEIGHT((getPosASL _unit) select 2);
+    _barometricPressure = 1013.25 * exp(-(EGVAR(weather,Altitude) + ((getPosASL _bullet) select 2)) / 7990) - 10 * overcast;
+    _stabilityFactor = [_caliber, _bulletLength, _bulletMass, _barrelTwist, _muzzleVelocity, _temperature, _barometricPressure] call FUNC(calculateStabilityFactor);
+};
+
+_twistDirection = 1;
+if (isNumber(configFile >> "cfgWeapons" >> _weapon >> "ACE_twistDirection")) then {
+    _twistDirection = getNumber(configFile >> "cfgWeapons" >> _weapon >> "ACE_twistDirection");
+    if (_twistDirection != -1 && _twistDirection != 0 &&  _twistDirection != 1) then {
+        _twistDirection = 1;
+    };
+};
+
+_transonicStabilityCoef = 0.5;
+if (isNumber(configFile >> "cfgAmmo" >> _ammo >> "ACE_transonicStabilityCoef")) then {
+    _transonicStabilityCoef = getNumber(configFile >> "cfgAmmo" >> _ammo >> "ACE_transonicStabilityCoef");
+};
+
+_dragModel = 1;
+_ballisticCoefficients = [];
+_velocityBoundaries = [];
+_atmosphereModel = "ICAO";
+if (GVAR(AdvancedAirDragEnabled)) then {
+    if (isNumber(configFile >> "cfgAmmo" >> _ammo >> "ACE_dragModel")) then {
+        _dragModel = getNumber(configFile >> "cfgAmmo" >> _ammo >> "ACE_dragModel");
+        if (!(_dragModel in [1, 2, 5, 6, 7, 8])) then {
+            _dragModel = 1;
+        };
+    };
+    if (isArray(configFile >> "cfgAmmo" >> _ammo >> "ACE_ballisticCoefficients")) then {
+        _ballisticCoefficients = getArray(configFile >> "cfgAmmo" >> _ammo >> "ACE_ballisticCoefficients");
+    };
+    if (isArray(configFile >> "cfgAmmo" >> _ammo >> "ACE_velocityBoundaries")) then {
+        _velocityBoundaries = getArray(configFile >> "cfgAmmo" >> _ammo >> "ACE_velocityBoundaries");
+    };
+    if (isText(configFile >> "cfgAmmo" >> _ammo >> "ACE_standardAtmosphere")) then {
+        _atmosphereModel = getText(configFile >> "cfgAmmo" >> _ammo >> "ACE_standardAtmosphere");
+    };
+};
+
+#ifdef USE_ADVANCEDBALLISTICS_DLL
+    GVAR(currentbulletID) = (GVAR(currentbulletID) + 1) % 10000;
+
+    "ace_advanced_ballistics" callExtension format["new:%1:%2:%3:%4:%5:%6:%7:%8:%9:%10:%11:%12:%13:%14:%15:%16:%17:%18", GVAR(currentbulletID), _airFriction, _ballisticCoefficients, _velocityBoundaries, _atmosphereModel, _dragModel, _stabilityFactor, _twistDirection, _muzzleVelocity, _transonicStabilityCoef, getPosASL _bullet, EGVAR(weather,Latitude), EGVAR(weather,currentTemperature), EGVAR(weather,Altitude), EGVAR(weather,currentHumidity), overcast, floor(time), time - floor(time)];
+
+    [{
+        private ["_index", "_bullet", "_caliber", "_bulletTraceVisible", "_bulletVelocity", "_bulletPosition"];
+        EXPLODE_4_PVT(_this select 0,_bullet,_caliber,_bulletTraceVisible,_index);
+
+        if (!alive _bullet) exitWith {
+            [_this select 1] call cba_fnc_removePerFrameHandler;
+        };
+
+        _bulletVelocity = velocity _bullet;
+        _bulletPosition = getPosASL _bullet;
+
+        if (_bulletTraceVisible && vectorMagnitude _bulletVelocity > 600) then {
+            drop ["\A3\data_f\ParticleEffects\Universal\Refract","","Billboard",1,0.1,getPos _bullet,[0,0,0],0,1.275,1,0,[0.4*_caliber,0.2*_caliber],[[0,0,0,0.6],[0,0,0,0.4]],[1,0],0,0,"","",""];
+        };
+
+        call compile ("ace_advanced_ballistics" callExtension format["simulate:%1:%2:%3:%4:%5:%6:%7", _index, _bulletVelocity, _bulletPosition, ACE_wind, ASLToATL(_bulletPosition) select 2, floor(time), time - floor(time)]);
+
+    }, GVAR(simulationInterval), [_bullet, _caliber, _bulletTraceVisible, GVAR(currentbulletID)]] call CBA_fnc_addPerFrameHandler;
+#else
+    _index = count GVAR(bulletDatabase);
+    if (count GVAR(bulletDatabaseFreeIndices) > 0) then {
+        _index = GVAR(bulletDatabaseFreeIndices) select 0;
+        GVAR(bulletDatabaseFreeIndices) = GVAR(bulletDatabaseFreeIndices) - [_index];
+    };
+
+    GVAR(bulletDatabase)          set[_index, [_bullet, _caliber, _airFriction, _muzzleVelocity, _stabilityFactor, _transonicStabilityCoef, _twistDirection, _unit, _bulletTraceVisible, _ballisticCoefficients, _velocityBoundaries, _atmosphereModel, _dragModel, _index]];
+    GVAR(bulletDatabaseStartTime) set[_index, time];
+    GVAR(bulletDatabaseSpeed)     set[_index, 0];
+    GVAR(bulletDatabaseFrames)    set[_index, 1];
+    GVAR(bulletDatabaseLastFrame) set[_index, time];
+    GVAR(bulletDatabaseHDeflect)  set[_index, 0];
+    GVAR(bulletDatabaseSpinDrift) set[_index, 0];
+
+    if ((GVAR(bulletDatabaseOccupiedIndices) pushBack _index) == 0) then {
+        [{
+            private ["_bulletDatabaseEntry", "_bullet", "_caliber", "_muzzleVelocity", "_frames", "_speed", "_airFriction", "_airFrictionRef", "_dragModel", "_atmosphereModel", "_ballisticCoefficient", "_ballisticCoefficients", "_velocityBoundaries", "_airDensity", "_stabilityFactor", "_transonicStabilityCoef", "_twistDirection", "_unit", "_bulletTraceVisible", "_index", "_temperature", "_humidity", "_deltaT", "_TOF", "_bulletPosition", "_bulletVelocity", "_bulletSpeed", "_trueVelocity", "_trueSpeed", "_bulletSpeedAvg", "_wind", "_drag", "_dragRef", "_vect", "_accel", "_accelRef", "_centripetalAccel", "_pressure", "_pressureDeviation", "_windSourceObstacle", "_windSourceTerrain", "_height", "_roughnessLength"];
+
+            {
+                _bulletDatabaseEntry = (GVAR(bulletDatabase) select _x);
+                if (!alive (_bulletDatabaseEntry select 0)) then {
+                    _index  = _bulletDatabaseEntry select 13;
+                    GVAR(bulletDatabaseOccupiedIndices) = GVAR(bulletDatabaseOccupiedIndices) - [_index];
+                    GVAR(bulletDatabaseFreeIndices) pushBack _index;
+                };
+                true
+            } count GVAR(bulletDatabaseOccupiedIndices);
+
+            if (count GVAR(bulletDatabaseOccupiedIndices) == 0) exitWith {
+                GVAR(bulletDatabase)          = [];
+                GVAR(bulletDatabaseStartTime) = [];
+                GVAR(bulletDatabaseSpeed)     = [];
+                GVAR(bulletDatabaseFrames)    = [];
+                GVAR(bulletDatabaseLastFrame) = [];
+                GVAR(bulletDatabaseHDeflect)  = [];
+                GVAR(bulletDatabaseSpinDrift) = [];
+                GVAR(bulletDatabaseOccupiedIndices) = [];
+                GVAR(bulletDatabaseFreeIndices) = [];
+                [_this select 1] call cba_fnc_removePerFrameHandler;
+            };
+
+            {
+                _bulletDatabaseEntry    = GVAR(bulletDatabase) select _x;
+                _bullet                 = _bulletDatabaseEntry select 0;
+                _caliber                = _bulletDatabaseEntry select 1;
+                _airFriction            = _bulletDatabaseEntry select 2;
+                _muzzleVelocity         = _bulletDatabaseEntry select 3;
+                _stabilityFactor        = _bulletDatabaseEntry select 4;
+                _transonicStabilityCoef = _bulletDatabaseEntry select 5;
+                _twistDirection         = _bulletDatabaseEntry select 6;
+                _unit                   = _bulletDatabaseEntry select 7;
+                _bulletTraceVisible     = _bulletDatabaseEntry select 8;
+                _ballisticCoefficients  = _bulletDatabaseEntry select 9;
+                _velocityBoundaries     = _bulletDatabaseEntry select 10;
+                _atmosphereModel        = _bulletDatabaseEntry select 11;
+                _dragModel              = _bulletDatabaseEntry select 12;
+                _index                  = _bulletDatabaseEntry select 13;
+
+                _TOF = time - (GVAR(bulletDatabaseStartTime) select _index);
+
+                _bulletVelocity = velocity _bullet;
+                _bulletPosition = getPosASL _bullet;
+
+                _bulletSpeed = vectorMagnitude _bulletVelocity;
+                _bulletDir = (_bulletVelocity select 0) atan2 (_bulletVelocity select 1);
+
+                _speed = (GVAR(bulletDatabaseSpeed) select _index);
+                GVAR(bulletDatabaseSpeed) set[_index, _speed + _bulletSpeed];
+
+                _frames = (GVAR(bulletDatabaseFrames) select _index);
+                GVAR(bulletDatabaseFrames) set[_index, _frames + 1];
+
+                _bulletSpeedAvg = (_speed / _frames);
+
+                if ((GVAR(SimulationPrecision) < 2) || {_frames % GVAR(SimulationPrecision) == _index % GVAR(SimulationPrecision)}) then {
+                    _deltaT = time - (GVAR(bulletDatabaseLastFrame) select _index);
+                    GVAR(bulletDatabaseLastFrame) set[_index, time];
+
+                    _trueVelocity = _bulletVelocity;
+                    _trueSpeed = _bulletSpeed;
+                    _wind = [0, 0, 0];
+                    if (GVAR(WindEnabled) && (vectorMagnitude ACE_wind) > 0) then {
+                        _windSourceObstacle = _bulletPosition vectorDiff ((vectorNormalized ACE_wind) vectorMultiply 10);
+                        _windSourceTerrain = _bulletPosition vectorDiff ((vectorNormalized ACE_wind) vectorMultiply 100);
+
+                        if (!(lineIntersects [_bulletPosition, _windSourceObstacle]) && !(terrainIntersectASL [_bulletPosition, _windSourceTerrain])) then {
+                            _wind = ACE_wind;
+                            _height = ASLToATL(_bulletPosition) select 2;
+                            _height = 0 max _height min 20;
+                            if (_height < 20) then {
+                                _roughnessLength = _bulletPosition call FUNC(calculateRoughnessLength);
+                                _wind = _wind vectorMultiply (ln(_height / _roughnessLength) / ln(20 / _roughnessLength));
+                            };
+
+                            _trueVelocity = _bulletVelocity vectorDiff _wind;
+                            _trueSpeed = vectorMagnitude _trueVelocity;
+                        };
+                    };
+
+                    _airFrictionRef = _airFriction;
+                    if (GVAR(AdvancedAirDragEnabled) && (count _ballisticCoefficients) == (count _velocityBoundaries) + 1) then {
+                        _dragRef = _deltaT * _airFrictionRef * _bulletSpeed * _bulletSpeed;
+                        _accelRef = (vectorNormalized _bulletVelocity) vectorMultiply (_dragRef);
+                        _bulletVelocity = _bulletVelocity vectorDiff _accelRef;
+
+                        _ballisticCoefficient = (_ballisticCoefficients select 0);
+                        for "_i" from (count _velocityBoundaries) - 1 to 0 step -1 do {
+                            if (_bulletSpeed < (_velocityBoundaries select _i)) exitWith {
+                                _ballisticCoefficient = (_ballisticCoefficients select (_i + 1));
+                            };
+                        };
+
+                        if (GVAR(AtmosphericDensitySimulationEnabled)) then {
+                            _pressure = 1013.25 * exp(-(EGVAR(weather,Altitude) + (_bulletPosition select 2)) / 7990) - 10 * overcast;
+                            _temperature = GET_TEMPERATURE_AT_HEIGHT(_bulletPosition select 2);
+                            _humidity = EGVAR(weather,currentHumidity);
+                            _airDensity = STD_AIR_DENSITY_ICAO;
+                            if (_humidity > 0) then {
+                                private ["_pSat", "_vaporPressure", "_partialPressure"];
+                                // Saturation vapor pressure calculated according to: http://wahiduddin.net/calc/density_algorithms.htm
+                                _pSat = 6.1078 * 10 ^ ((7.5 * _temperature) / (_temperature + 237.3));
+                                _vaporPressure = _humidity * _pSat;
+                                _partialPressure = (_pressure * 100)- _vaporPressure;
+
+                                _airDensity = (_partialPressure * DRY_AIR_MOLAR_MASS + _vaporPressure * WATER_VAPOR_MOLAR_MASS) / (UNIVERSAL_GAS_CONSTANT * KELVIN(_temperature));
+                            } else {
+                                _airDensity = (_pressure * 100) / (SPECIFIC_GAS_CONSTANT_DRY_AIR * KELVIN(_temperature));
+                            };
+                            if (_atmosphereModel == "ICAO") then {
+                                _ballisticCoefficient = (STD_AIR_DENSITY_ICAO / _airDensity) * _ballisticCoefficient;
+                            } else {
+                                _ballisticCoefficient = (STD_AIR_DENSITY_ASM / _airDensity) * _ballisticCoefficient;
+                            };
+                        };
+
+                        _drag = _deltaT * ([_dragModel, _ballisticCoefficient, _trueSpeed] call FUNC(calculateRetardation));
+                        _accel = (vectorNormalized _trueVelocity) vectorMultiply (_drag);
+                        _bulletVelocity = _bulletVelocity vectorDiff _accel;
+                    } else {
+                        if (GVAR(AtmosphericDensitySimulationEnabled)) then {
+                            _pressureDeviation = 1013.25 * exp(-(EGVAR(weather,Altitude) + (_bulletPosition select 2)) / 7990) - 1013.25 - 10 * overcast;
+                            _temperature = GET_TEMPERATURE_AT_HEIGHT(_bulletPosition select 2);
+                            _humidity = EGVAR(weather,currentHumidity);
+                            _airFriction = _airFriction + ((_temperature - 15) * 0.0000015 + _humidity * 0.0000040 + _pressureDeviation * -0.0000009);
+                        };
+
+                        if (_airFriction != _airFrictionRef || vectorMagnitude _wind > 0) then {
+                            _dragRef = _deltaT * _airFrictionRef * _bulletSpeed * _bulletSpeed;
+                            _accelRef = (vectorNormalized _bulletVelocity) vectorMultiply (_dragRef);
+                            _bulletVelocity = _bulletVelocity vectorDiff _accelRef;
+
+                            _drag = _deltaT * _airFriction * _trueSpeed * _trueSpeed;
+                            _accel = (vectorNormalized _trueVelocity) vectorMultiply (_drag);
+                            _bulletVelocity = _bulletVelocity vectorAdd _accel;
+                        };
+                    };
+
+                    if (GVAR(CoriolisEnabled) && _bulletSpeedAvg > 0) then {
+                        _horizontalDeflection = 0.0000729 * (_unit distanceSqr _bullet) * sin(EGVAR(weather,Latitude)) / _bulletSpeedAvg;
+                        _horizontalDeflectionPartial = _horizontalDeflection - (GVAR(bulletDatabaseHDeflect) select _index);
+                        GVAR(bulletDatabaseHDeflect) set[_index, _horizontalDeflection];
+                        _vect = [sin(_bulletDir + 90) * _horizontalDeflectionPartial, cos(_bulletDir + 90) * _horizontalDeflectionPartial, 0];
+
+                        _bulletPosition = _bulletPosition vectorAdd _vect;
+                    };
+
+                    /*
+                    // Negligible effect on the trajectory
+                    if (GVAR(EoetvoesEnabled)) then {
+                        _centripetalAccel = 2 * 0.0000729 * (_muzzleVelocity / -32.2) * cos(EGVAR(weather,Latitude)) * sin(_bulletDir);
+                        _accel = [0, 0, -(_centripetalAccel * _deltaT)];
+
+                        _bulletVelocity = _bulletVelocity vectorAdd _accel;
+                    };
+                    //*/
+
+                    if (GVAR(SpinDriftEnabled)) then {
+                        _spinDrift = _twistDirection * 0.0254 * 1.25 * (_stabilityFactor + 1.2) * _TOF ^ 1.83;
+                        _spinDriftPartial = _spinDrift - (GVAR(bulletDatabaseSpinDrift) select _index);
+                        GVAR(bulletDatabaseSpinDrift) set[_index, _spinDrift];
+                        _vect = [sin(_bulletDir + 90) * _spinDriftPartial, cos(_bulletDir + 90) * _spinDriftPartial, 0];
+
+                        _bulletPosition = _bulletPosition vectorAdd _vect;
+                    };
+                };
+
+                if (GVAR(TransonicRegionEnabled) && _transonicStabilityCoef < 1) then {
+                    if (_bulletSpeed < 345 && _bulletSpeedAvg > 340 && _bulletSpeed > 335) then {
+                        _accel = [(random 0.8) - 0.4, (random 0.8) - 0.4, (random 0.8) - 0.4];
+                        _accel = _accel vectorMultiply (1 - _transonicStabilityCoef);
+                        _bulletVelocity = _bulletVelocity vectorAdd _accel;
+                    };
+                };
+
+                if (_bulletTraceVisible && _bulletSpeed > 600 && _bullet distanceSqr _unit > 400) then {
+                    drop ["\A3\data_f\ParticleEffects\Universal\Refract","","Billboard",1,0.1,getPos _bullet,[0,0,0],0,1.275,1,0,[0.4*_caliber,0.2*_caliber],[[0,0,0,0.6],[0,0,0,0.4]],[1,0],0,0,"","",""];
+                };
+
+                _bullet setVelocity _bulletVelocity;
+                _bullet setPosASL _bulletPosition;
+                true
+            } count GVAR(bulletDatabaseOccupiedIndices);
+
+        }, GVAR(simulationInterval), []] call CBA_fnc_addPerFrameHandler;
+    };
+#endif
--- a/addons/advanced_ballistics/functions/fnc_initModuleSettings.sqf
+++ b/addons/advanced_ballistics/functions/fnc_initModuleSettings.sqf
@ -0,0 +1,35 @@
+/*
+ * Author: Glowbal, Ruthberg
+ * Module for adjusting the advanced ballistics settings
+ *
+ * Arguments:
+ * 0: The module logic <LOGIC>
+ * 1: units <ARRAY>
+ * 2: activated <BOOL>
+ *
+ * Return Value:
+ * None <NIL>
+ *
+ * Public: No
+ */
+
+#include "script_component.hpp"
+
+private ["_logic", "_units", "_activated"];
+_logic = _this select 0;
+_units = _this select 1;
+_activated = _this select 2;
+
+if !(_activated) exitWith {};
+
+[_logic, QGVAR(enabled), "enabled"] call EFUNC(common,readSettingFromModule);
+[_logic, QGVAR(ammoTemperatureEnabled), "ammoTemperatureEnabled"] call EFUNC(common,readSettingFromModule);
+[_logic, QGVAR(barrelLengthInfluenceEnabled), "barrelLengthInfluenceEnabled"] call EFUNC(common,readSettingFromModule);
+[_logic, QGVAR(bulletTraceEnabled), "bulletTraceEnabled"] call EFUNC(common,readSettingFromModule);
+[_logic, QGVAR(onlyActiveForLocalPlayers), "onlyActiveForLocalPlayers"] call EFUNC(common,readSettingFromModule);
+[_logic, QGVAR(disabledInFullAutoMode), "disabledInFullAutoMode"] call EFUNC(common,readSettingFromModule);
+[_logic, QGVAR(alwaysSimulateForSnipers), "alwaysSimulateForSnipers"] call EFUNC(common,readSettingFromModule);
+[_logic, QGVAR(simulationInterval), "simulationInterval"] call EFUNC(common,readSettingFromModule);
+[_logic, QGVAR(simulationRadius), "simulationRadius"] call EFUNC(common,readSettingFromModule);
+
+GVAR(simulationInterval) = 0 max GVAR(simulationInterval) min 0.2;
--- a/addons/advanced_ballistics/functions/fnc_initializeTerrainExtension.sqf
+++ b/addons/advanced_ballistics/functions/fnc_initializeTerrainExtension.sqf
@ -0,0 +1,60 @@
+/*
+ * Author: Ruthberg
+ * Initializes the advanced ballistics dll extension with terrain data
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+if (!hasInterface) exitWith {};
+if (!GVAR(extensionAvailable)) exitWith {};
+
+private ["_initStartTime", "_mapSize", "_mapGrids", "_gridCells", "_x", "_y", "_gridCenter", "_gridHeight", "_gridNumObjects", "_gridSurfaceIsWater"];
+
+_initStartTime = time;
+_mapSize = getNumber (configFile >> "CfgWorlds" >> worldName >> "MapSize");
+
+if (("ace_advanced_ballistics" callExtension format["init:%1:%2", worldName, _mapSize]) == "Terrain already initialized") exitWith {
+    if (GVAR(INIT_MESSAGE_ENABLED)) then {
+        systemChat "AdvancedBallistics: Terrain already initialized";
+    };
+};
+
+_mapGrids = ceil(_mapSize / 50) + 1;
+_gridCells = _mapGrids * _mapGrids;
+
+GVAR(currentGrid) = 0;
+
+[{
+    private ["_args", "_mapGrids", "_gridCells", "_initStartTime"];
+    _args = _this select 0;
+    _mapGrids = _args select 0;
+    _gridCells = _args select 1;
+    _initStartTime = _args select 2;
+    
+    if (GVAR(currentGrid) >= _gridCells) exitWith {
+        if (GVAR(INIT_MESSAGE_ENABLED)) then {
+            systemChat format["AdvancedBallistics: Finished terrain initialization in %1 seconds", ceil(time - _initStartTime)];
+        };
+        [_this select 1] call cba_fnc_removePerFrameHandler;
+    };
+    
+    for "_i" from 1 to 50 do {
+        _x = floor(GVAR(currentGrid) / _mapGrids) * 50;
+        _y = (GVAR(currentGrid) - floor(GVAR(currentGrid) / _mapGrids) * _mapGrids) * 50;
+        _gridCenter = [_x + 25, _y + 25];
+        _gridHeight = round(getTerrainHeightASL _gridCenter);
+        _gridNumObjects = count (_gridCenter nearObjects ["Building", 50]);
+        _gridSurfaceIsWater = if (surfaceIsWater _gridCenter) then {1} else {0};
+        "ace_advanced_ballistics" callExtension format["set:%1:%2:%3", _gridHeight, _gridNumObjects, _gridSurfaceIsWater];
+        GVAR(currentGrid) = GVAR(currentGrid) + 1;
+        if (GVAR(currentGrid) >= _gridCells) exitWith {};
+    };
+        
+}, 0, [_mapGrids, _gridCells, _initStartTime]] call CBA_fnc_addPerFrameHandler
--- a/addons/advanced_ballistics/functions/script_component.hpp
+++ b/addons/advanced_ballistics/functions/script_component.hpp
@ -0,0 +1 @@
+#include "\z\ace\addons\advanced_ballistics\script_component.hpp"
--- a/addons/advanced_ballistics/initKeybinds.sqf
+++ b/addons/advanced_ballistics/initKeybinds.sqf
@ -0,0 +1,11 @@
+["ACE3", QGVAR(ProtractorKey), localize "STR_ACE_AdvancedBallistics_ProtractorKey",
+{
+    // Conditions: canInteract
+    if !([ACE_player, objNull, []] call EFUNC(common,canInteractWith)) exitWith {false};
+
+    // Statement
+    [] call FUNC(displayProtractor);
+    false
+},
+{false},
+[37, [true, true, false]], false, 0] call CBA_fnc_addKeybind; // (CTRL + SHIFT + K)
--- a/addons/advanced_ballistics/script_component.hpp
+++ b/addons/advanced_ballistics/script_component.hpp
@ -0,0 +1,26 @@
+#define COMPONENT advanced_ballistics
+#include "\z\ace\addons\main\script_mod.hpp"
+
+#define USE_ADVANCEDBALLISTICS_DLL
+
+#ifdef DEBUG_ENABLED_ADVANCEDBALLISTICS
+    #define DEBUG_MODE_FULL
+#endif
+
+#ifdef DEBUG_SETTINGS_ADVANCEDBALLISTICS
+    #define DEBUG_SETTINGS DEBUG_SETTINGS_ADVANCEDBALLISTICS
+#endif
+
+#include "\z\ace\addons\main\script_macros.hpp"
+
+#define GRAVITY 9.80665
+#define ABSOLUTE_ZERO_IN_CELSIUS -273.15
+#define KELVIN(t) (t - ABSOLUTE_ZERO_IN_CELSIUS)
+#define CELSIUS(t) (t + ABSOLUTE_ZERO_IN_CELSIUS)
+#define UNIVERSAL_GAS_CONSTANT 8.314
+#define WATER_VAPOR_MOLAR_MASS 0.018016
+#define DRY_AIR_MOLAR_MASS 0.028964
+#define SPECIFIC_GAS_CONSTANT_DRY_AIR 287.058
+#define STD_AIR_DENSITY_ICAO 1.22498
+#define STD_AIR_DENSITY_ASM 1.20885
+#define GET_TEMPERATURE_AT_HEIGHT(h) (EGVAR(weather,currentTemperature) - 0.0065 * (h))
--- a/addons/advanced_ballistics/stringtable.xml
+++ b/addons/advanced_ballistics/stringtable.xml
@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="utf-8"?>
+<!-- Edited with tabler. -->
+<Project name="ACE">
+    <Package name="AdvancedBallistics">
+        <Key ID="STR_ACE_AdvancedBallistics_WindInfoKey">
+            <English>Show Wind Info</English>
+            <Polish>Pokaż inf. o wietrze</Polish>
+        </Key>
+        <Key ID="STR_ACE_AdvancedBallistics_ProtractorKey">
+            <English>Show Protractor</English>
+            <Polish>Pokaż kątomierz</Polish>
+        </Key>
+    </Package>
+</Project>
--- a/addons/ai/CfgWeapons.hpp
+++ b/addons/ai/CfgWeapons.hpp
@ -574,4 +574,198 @@ class CfgWeapons {
            maxRange = 1200; //1000;
        };
    };
+
+    // marksmen marksmen
+    class DMR_03_base_F: Rifle_Long_Base_F {
+        modes[] += {"ACE_Burst_far"};
+
+        class Single: Mode_SemiAuto {
+            minRange = 120;       // 2;
+            minRangeProbab = 0.7; // 0.3;
+            midRangeProbab = 0.3; // 0.7;
+        };
+
+        class FullAuto;
+
+        class single_close_optics1: Single {
+            minRange = 120;        // 2;
+            minRangeProbab = 0.8;  // 0.05;
+            midRangeProbab = 0.05; // 0.8;
+        };
+
+        class single_medium_optics1: single_close_optics1 {
+            minRangeProbab = 0.7;  // 0.05;
+            midRangeProbab = 0.05; // 0.7;
+        };
+
+        class single_far_optics1: single_medium_optics1 {
+            minRange = 400;        // 300;
+            minRangeProbab = 0.5;  // 0.05;
+            midRangeProbab = 0.05; // 0.5;
+        };
+
+        class fullauto_medium: FullAuto {
+            minRange = 20;                // 2;
+            maxRange = 150;               // 100;
+            burst = "3 + round random 5"; // 3;
+        };
+
+        class ACE_Burst_far: fullauto_medium {
+            aiRateOfFire = 2.0;
+            aiRateOfFireDistance = 500;
+            minRange = 400;
+            minRangeProbab = 0.1;
+            midRange = 500;
+            midRangeProbab = 0.2;
+            maxRange = 600;
+            maxRangeProbab = 0.2;
+            burst = "2 + round random 3";
+        };
+    };
+
+    class DMR_05_base_F: Rifle_Long_Base_F {
+        modes[] += {"ACE_Burst_far"};
+
+        class Single: Mode_SemiAuto {
+            minRange = 120;       // 2;
+            minRangeProbab = 0.7; // 0.3;
+            midRangeProbab = 0.3; // 0.7;
+        };
+
+        class FullAuto;
+
+        class single_close_optics1: Single {
+            minRange = 120;        // 2;
+            minRangeProbab = 0.8;  // 0.05;
+            midRangeProbab = 0.05; // 0.8;
+        };
+
+        class single_medium_optics1: single_close_optics1 {
+            minRangeProbab = 0.7;  // 0.05;
+            midRangeProbab = 0.05; // 0.7;
+        };
+
+        class single_far_optics1: single_medium_optics1 {
+            minRange = 400;        // 300;
+            minRangeProbab = 0.5;  // 0.05;
+            midRangeProbab = 0.05; // 0.5;
+        };
+
+        class fullauto_medium: FullAuto {
+            minRange = 20;                // 2;
+            maxRange = 150;               // 100;
+            burst = "3 + round random 5"; // 3;
+        };
+
+        class ACE_Burst_far: fullauto_medium {
+            aiRateOfFire = 2.0;
+            aiRateOfFireDistance = 500;
+            minRange = 400;
+            minRangeProbab = 0.1;
+            midRange = 500;
+            midRangeProbab = 0.2;
+            maxRange = 600;
+            maxRangeProbab = 0.2;
+            burst = "2 + round random 3";
+        };
+    };
+
+    class DMR_06_base_F: Rifle_Long_Base_F {
+        modes[] += {"ACE_Burst_far"};
+
+        class Single: Mode_SemiAuto {
+            minRange = 120;       // 2;
+            minRangeProbab = 0.7; // 0.3;
+            midRangeProbab = 0.3; // 0.7;
+        };
+
+        class FullAuto;
+
+        class single_close_optics1: Single {
+            minRange = 120;        // 2;
+            minRangeProbab = 0.8;  // 0.05;
+            midRangeProbab = 0.05; // 0.8;
+        };
+
+        class single_medium_optics1: single_close_optics1 {
+            minRangeProbab = 0.7;  // 0.05;
+            midRangeProbab = 0.05; // 0.7;
+        };
+
+        class single_far_optics1: single_medium_optics1 {
+            minRange = 400;        // 300;
+            minRangeProbab = 0.5;  // 0.05;
+            midRangeProbab = 0.05; // 0.5;
+        };
+
+        class fullauto_medium: FullAuto {
+            minRange = 20;                // 2;
+            maxRange = 150;               // 100;
+            burst = "3 + round random 5"; // 3;
+        };
+
+        class ACE_Burst_far: fullauto_medium {
+            aiRateOfFire = 2.0;
+            aiRateOfFireDistance = 500;
+            minRange = 400;
+            minRangeProbab = 0.1;
+            midRange = 500;
+            midRangeProbab = 0.2;
+            maxRange = 600;
+            maxRangeProbab = 0.2;
+            burst = "2 + round random 3";
+        };
+    };
+
+    // marksmen medium mg
+    class MMG_01_base_F: Rifle_Long_Base_F {
+        aiDispersionCoefY = 25.0;
+        aiDispersionCoefX = 20.0;
+        modes[] += {"ACE_Burst_far"};
+
+        class manual;
+        class burst;
+        class close;
+        class short;
+        class medium;
+        class ACE_Burst_far: medium {
+            aiRateOfFire = 6.0;
+            aiRateOfFireDistance = 900;
+            minRange = 700;
+            minRangeProbab = 0.1;
+            midRange = 900;
+            midRangeProbab = 0.2;
+            maxRange = 1100;
+            maxRangeProbab = 0.2;
+            burst = "3 + round random 5";
+        };
+
+        class far_optic1;
+        class far_optic2;
+    };
+
+    class MMG_02_base_F: Rifle_Long_Base_F {
+        aiDispersionCoefY = 20.0;
+        aiDispersionCoefX = 15.0;
+        modes[] += {"ACE_Burst_far"};
+
+        class manual;
+        class close;
+        class short;
+        class medium;
+        class ACE_Burst_far: medium {
+            aiRateOfFire = 6.0;
+            aiRateOfFireDistance = 900;
+            minRange = 700;
+            minRangeProbab = 0.1;
+            midRange = 900;
+            midRangeProbab = 0.2;
+            maxRange = 1100;
+            maxRangeProbab = 0.2;
+            burst = "3 + round random 5";
+        };
+
+        class far_optic1;
+        class far_optic2;
+    };
 };
--- a/addons/aircraft/CfgAmmo.hpp
+++ b/addons/aircraft/CfgAmmo.hpp
@ -16,7 +16,7 @@ class CfgAmmo {
 		explosionEffects = "ExploAmmoExplosion";
        model = "\A3\Weapons_f\Data\bullettracer\tracer_red";
    };
-    class ACE_20mm_HEDP : B_20mm {};
+    class ACE_20mm_HE : B_20mm {};
    class ACE_20mm_AP : B_20mm {
        hit = 50;
        indirectHit = 12;
--- a/addons/aircraft/CfgMagazines.hpp
+++ b/addons/aircraft/CfgMagazines.hpp
@ -10,7 +10,7 @@ class CfgMagazines {
    // an extended magazine for the comanche
    class 300Rnd_20mm_shells;
    class ACE_500Rnd_20mm_shells_Comanche: 300Rnd_20mm_shells {
-        ammo = "ACE_20mm_HEDP";
+        ammo = "ACE_20mm_HE";
        count = 500;
    };
 };
--- a/addons/aircraft/stringtable.xml
+++ b/addons/aircraft/stringtable.xml
@ -1,50 +1,49 @@
 <?xml version="1.0" encoding="utf-8"?>
-<!-- Edited with tabler - 2014-12-12 -->
 <Project name="ACE">
-  <Package name="Aircraft">
-    <Key ID="STR_ACE_Aircraft_CMFlareLauncher_Burst_Name">
-      <English>Burst</English>
-      <German>Feuerstoß</German>
-      <Spanish>Ráfaga</Spanish>
-      <Polish>Seria</Polish>
-      <Czech>Dávka</Czech>
-      <French>Rafale</French>
-      <Russian>Очередь</Russian>
-      <Hungarian>Sorozat</Hungarian>
-      <Portuguese>Rajada</Portuguese>
-      <Italian>Raffica</Italian>
-    </Key>
-    <Key ID="STR_ACE_Aircraft_gatling_20mm_Name">
-      <English>XM301</English>
-      <German>XM301</German>
-      <Spanish>XM301</Spanish>
-      <Polish>XM301</Polish>
-      <Czech>XM301</Czech>
-      <French>XM301</French>
-      <Russian>XM301</Russian>
-      <Hungarian>XM301</Hungarian>
-      <Portuguese>XM301</Portuguese>
-      <Italian>XM301</Italian>
-    </Key>
-    <Key ID="STR_ACE_Aircraft_OpenCargoRamp">
-      <English>Open Cargo Door</English>
-      <German>Laderampe öffnen</German>
-      <Spanish>Abrir compuerta de carga</Spanish>
-      <French>Ourvir Rampe Cargo</French>
-      <Polish>Otwórz drzwi ładowni</Polish>
-      <Czech>Otevřít nákladní prostor</Czech>
-      <Hungarian>Rámpát kinyitni</Hungarian>
-      <Russian>Открыть грузовой отсек</Russian>
-    </Key>
-    <Key ID="STR_ACE_Aircraft_CloseCargoRamp">
-      <English>Close Cargo Door</English>
-      <German>Laderampe schließen</German>
-      <Spanish>Cerrar compuerta de carga</Spanish>
-      <French>Fermer la Rampe du Cargo</French>
-      <Polish>Zamknij drzwi ładowni</Polish>
-      <Czech>Zavřít nákladní prostor</Czech>
-      <Hungarian>Rámpát zárni</Hungarian>
-      <Russian>Закрыть грузовой отсек</Russian>
-    </Key>
-  </Package>
+    <Package name="Aircraft">
+        <Key ID="STR_ACE_Aircraft_CMFlareLauncher_Burst_Name">
+            <English>Burst</English>
+            <German>Feuerstoß</German>
+            <Spanish>Ráfaga</Spanish>
+            <Polish>Seria</Polish>
+            <Czech>Dávka</Czech>
+            <French>Contre mesure</French>
+            <Russian>Очередь</Russian>
+            <Hungarian>Sorozat</Hungarian>
+            <Portuguese>Rajada</Portuguese>
+            <Italian>Raffica</Italian>
+        </Key>
+        <Key ID="STR_ACE_Aircraft_gatling_20mm_Name">
+            <English>XM301</English>
+            <German>XM301</German>
+            <Spanish>XM301</Spanish>
+            <Polish>XM301</Polish>
+            <Czech>XM301</Czech>
+            <French>XM301</French>
+            <Russian>XM301</Russian>
+            <Hungarian>XM301</Hungarian>
+            <Portuguese>XM301</Portuguese>
+            <Italian>XM301</Italian>
+        </Key>
+        <Key ID="STR_ACE_Aircraft_OpenCargoRamp">
+            <English>Open Cargo Door</English>
+            <German>Laderampe öffnen</German>
+            <Spanish>Abrir compuerta de carga</Spanish>
+            <French>Ourvir rampe cargo</French>
+            <Polish>Otwórz drzwi ładowni</Polish>
+            <Czech>Otevřít nákladní prostor</Czech>
+            <Hungarian>Rámpát kinyitni</Hungarian>
+            <Russian>Открыть грузовой отсек</Russian>
+        </Key>
+        <Key ID="STR_ACE_Aircraft_CloseCargoRamp">
+            <English>Close Cargo Door</English>
+            <German>Laderampe schließen</German>
+            <Spanish>Cerrar compuerta de carga</Spanish>
+            <French>Fermer rampe cargo</French>
+            <Polish>Zamknij drzwi ładowni</Polish>
+            <Czech>Zavřít nákladní prostor</Czech>
+            <Hungarian>Rámpát zárni</Hungarian>
+            <Russian>Закрыть грузовой отсек</Russian>
+        </Key>
+    </Package>
 </Project>
--- a/addons/atragmx/CfgEventHandlers.hpp
+++ b/addons/atragmx/CfgEventHandlers.hpp
@ -0,0 +1,11 @@
+class Extended_PreInit_EventHandlers {
+    class ADDON {
+        init = QUOTE( call COMPILE_FILE(XEH_preInit) );
+    };
+};
+
+class Extended_PostInit_EventHandlers {
+    class ADDON {
+        init = QUOTE( call COMPILE_FILE(XEH_postInit) );
+    };
+};
--- a/addons/atragmx/CfgVehicles.hpp
+++ b/addons/atragmx/CfgVehicles.hpp
@ -0,0 +1,40 @@
+class CfgVehicles {
+    class Man;
+    class CAManBase: Man {
+        class ACE_SelfActions {
+            class ACE_Equipment {
+                class GVAR(open) {
+                    displayName = "$STR_ACE_ATragMX_OpenATragMXDialog";
+                    condition = QUOTE(call FUNC(can_show));
+                    statement = QUOTE(call FUNC(create_dialog));
+                    showDisabled = 0;
+                    priority = 2;
+                    icon = PATHTOF(UI\ATRAG_Icon.paa);
+                    exceptions[] = {"notOnMap", "isNotInside"};
+                };
+            };
+        };
+    };
+
+    class Item_Base_F;
+    class ACE_Item_ATragMX: Item_Base_F {
+        author = "Ruthberg";
+        scope = 2;
+        scopeCurator = 2;
+        displayName = "ATragMX";
+        vehicleClass = "Items";
+        class TransportItems {
+            class ACE_ATragMX {
+                name = "ACE_ATragMX";
+                count = 1;
+            };
+        };
+    };
+
+    class Box_NATO_Support_F;
+    class ACE_Box_Misc: Box_NATO_Support_F {
+        class TransportItems {
+            MACRO_ADDITEM(ACE_ATragMX,6);
+        };
+    };
+};
--- a/addons/atragmx/CfgWeapons.hpp
+++ b/addons/atragmx/CfgWeapons.hpp
@ -0,0 +1,20 @@
+
+class CfgWeapons {
+    class ACE_ItemCore;
+    class InventoryItem_Base_F;
+
+    class ACE_ATragMX: ACE_ItemCore {
+        author = "Ruthberg";
+        scope = 2;
+        displayName = "$STR_ACE_ATragMX_Name";
+        descriptionShort = "$STR_ACE_ATragMX_Description";
+        model = PATHTOF(data\tdsrecon.p3d);
+        picture = PATHTOF(UI\ATRAG_Icon.paa);
+        icon = "iconObject_circle";
+        mapSize = 0.034;
+
+        class ItemInfo: InventoryItem_Base_F {
+            mass = 2;
+        };
+    };
+};
--- a/addons/atragmx/README.md
+++ b/addons/atragmx/README.md
@ -0,0 +1,10 @@
+ace_atragmx
+===============
+
+ATragMX - Handheld ballistics calculator
+
+## Maintainers
+
+The people responsible for merging changes to this component or answering potential questions.
+
+- [Ruthberg] (http://github.com/Ulteq)
--- a/addons/atragmx/RscTitles.hpp
+++ b/addons/atragmx/RscTitles.hpp
--- a/addons/atragmx/UI/ATRAG.paa
+++ b/addons/atragmx/UI/ATRAG.paa
--- a/addons/atragmx/UI/ATRAG_Icon.paa
+++ b/addons/atragmx/UI/ATRAG_Icon.paa
--- a/addons/atragmx/XEH_postInit.sqf
+++ b/addons/atragmx/XEH_postInit.sqf
@ -0,0 +1,25 @@
+#include "script_component.hpp"
+
+//#include "initKeybinds.sqf"
+
+if (count (profileNamespace getVariable ["ACE_ATragMX_gunList", []]) > 0) then {
+    GVAR(gunList) = profileNamespace getVariable "ACE_ATragMX_gunList";
+} else {
+    // Profile Name, Muzzle Velocity, Zero Range, Scope Base Angle, AirFriction, Bore Height, Scope Unit, Elevation Scope Step, Windage Scope Step, Maximum Elevation, Dialed Elevation, Dialed Windage, Mass, Ammo Class Name, Magazine Class Name, BC, Drag Model, Atmosphere Model
+    GVAR(gunList) =  [["12.7x108mm"       , 820, 100, 0.0659, -0.0008600, 3.81, 0, 0.338, 0.338, 120, 0, 0, 48.28, "B_127x108_Ball"  , "5Rnd_127x108_Mag"        , 0.700, 1, "ASM" ],
+                      ["12.7x99mm"        , 880, 100, 0.0607, -0.0008600, 3.81, 0, 0.338, 0.338, 120, 0, 0, 41.92, "B_127x99_Ball"   , "5Rnd_mas_127x99_Stanag"  , 0.670, 1, "ASM" ],
+                      ["12.7x54mm"        , 290, 100, 0.3913, -0.0014000, 3.81, 0, 0.338, 0.338, 120, 0, 0, 61.56, "B_127x54_Ball"   , "10Rnd_127x54_Mag"        , 1.050, 1, "ASM" ],
+                      ["10.4x77mm"        , 910, 100, 0.0572, -0.0004800, 3.81, 0, 0.338, 0.338, 120, 0, 0, 27.15, "B_408_Ball"      , "7Rnd_408_Mag"            , 0.970, 1, "ASM" ],
+                      ["9.3×64mm"         , 870, 100, 0.0632, -0.0007500, 3.81, 0, 0.338, 0.338, 120, 0, 0, 16.20, "B_93x64_Ball"    , "10Rnd_93x64_DMR_05_Mag"  , 0.368, 1, "ASM" ],
+                      ["8.6×70mm"         , 915, 100, 0.0572, -0.0006100, 3.81, 0, 0.338, 0.338, 120, 0, 0, 16.20, "B_338_Ball"      , "10Rnd_338_Mag"           , 0.322, 7, "ICAO"],
+                      ["7.62x51mm"        , 850, 100, 0.0639, -0.0010000, 3.81, 0, 0.338, 0.338, 120, 0, 0, 9.460, "B_762x51_Ball"   , "20Rnd_762x51_Mag"        , 0.393, 1, "ICAO"],
+                      ["6.5x39mm"         , 800, 100, 0.0689, -0.0009000, 3.81, 0, 0.338, 0.338, 120, 0, 0, 7.776, "B_65x39_Caseless", "30Rnd_65x39_caseless_mag", 0.263, 1, "ICAO"],
+                      ["5.56x45mm"        , 920, 100, 0.0584, -0.0012650, 3.81, 0, 0.338, 0.338, 120, 0, 0, 4.000, "B_556x45_Ball"   , "30Rnd_556x45_Stanag"     , 0.304, 1, "ASM" ],
+                      ["5.56x45mm Mk262"  , 850, 100, 0.0643, -0.0011250, 3.81, 0, 0.338, 0.338, 120, 0, 0, 4.990, "RH_556x45_Mk262" , "RH_30Rnd_556x45_Mk262"   , 0.361, 1, "ASM" ]];
+    
+    profileNamespace setVariable ["ACE_ATragMX_gunList", GVAR(gunList)];
+};
+
+[] call FUNC(init);
+
+["RangerfinderData", {_this call FUNC(sord)}] call EFUNC(common,addEventHandler);
--- a/addons/atragmx/XEH_preInit.sqf
+++ b/addons/atragmx/XEH_preInit.sqf
@ -0,0 +1,48 @@
+#include "script_component.hpp"
+
+ADDON = false;
+
+PREP(add_new_gun);
+PREP(calculate_range_card);
+PREP(calculate_scope_base_angle);
+PREP(calculate_solution);
+PREP(calculate_target_range_assist);
+PREP(calculate_target_solution);
+PREP(calculate_target_speed_assist);
+PREP(can_show);
+PREP(change_gun);
+PREP(create_dialog);
+PREP(cycle_range_card_columns);
+PREP(cycle_scope_unit);
+PREP(delete_gun);
+PREP(init);
+PREP(parse_input);
+PREP(reset_relative_click_memory);
+PREP(save_gun);
+PREP(show_add_new_gun);
+PREP(show_gun_list);
+PREP(show_main_page);
+PREP(show_range_card);
+PREP(show_range_card_setup);
+PREP(show_target_range_assist);
+PREP(show_target_speed_assist);
+PREP(show_target_speed_assist_timer);
+PREP(sord);
+PREP(target_speed_assist_timer);
+PREP(toggle_gun_list);
+PREP(toggle_range_card);
+PREP(toggle_range_card_setup);
+PREP(toggle_target_range_assist);
+PREP(toggle_target_speed_assist);
+PREP(update_atmosphere);
+PREP(update_gun);
+PREP(update_range_card);
+PREP(update_relative_click_memory);
+PREP(update_result);
+PREP(update_scope_unit);
+PREP(update_target);
+PREP(update_target_selection);
+PREP(update_unit_selection);
+PREP(update_zero_range);
+
+ADDON = true;
--- a/addons/atragmx/config.cpp
+++ b/addons/atragmx/config.cpp
@ -0,0 +1,17 @@
+#include "script_component.hpp"
+
+class CfgPatches {
+    class ADDON {
+        units[] = {"ACE_Item_ATragMX"};
+        weapons[] = {"ACE_ATragMX"};
+        requiredVersion = REQUIRED_VERSION;
+        requiredAddons[] = {"ACE_common", "ACE_weather"};
+        author = "Ruthberg";
+        VERSION_CONFIG;
+    };
+};
+
+#include "CfgEventHandlers.hpp"
+#include "CfgVehicles.hpp"
+#include "CfgWeapons.hpp"
+#include "RscTitles.hpp"
--- a/addons/atragmx/data/tdsrecon.p3d
+++ b/addons/atragmx/data/tdsrecon.p3d
--- a/addons/atragmx/data/tdsrecon.rvmat
+++ b/addons/atragmx/data/tdsrecon.rvmat
@ -0,0 +1,69 @@
+class StageTI {
+    texture="a3\data_f\default_ti_ca.paa";
+};
+ambient[]={1,1,1,1};
+diffuse[]={1,1,1,1};
+forcedDiffuse[]={0,0,0,0};
+emmisive[]={0,0,0,1};
+specular[]={0.05000001,0.05000001,0.05000001,1};
+specularPower=50;
+PixelShaderID="Super";
+VertexShaderID="Super";
+class Stage1 {
+    texture="z\ace\addons\atragmx\data\tdsrecon_nohq.paa";
+    uvSource="tex";
+    class uvTransform {
+        aside[]={1,0,0};
+        up[]={0,1,0};
+        dir[]={0,0,0};
+        pos[]={0,0,0};
+    };
+};
+class Stage2 {
+    texture="#(argb,8,8,3)color(0.5,0.5,0.5,1,DT)";
+    uvSource="tex";
+    class uvTransform {
+        aside[]={0,9,0};
+        up[]={4.5,0,0};
+        dir[]={0,0,0};
+        pos[]={0,0,0};
+    };
+};
+class Stage3 {
+    texture="#(argb,8,8,3)color(0,0,0,0)";
+    uvSource="tex";
+    class uvTransform {
+        aside[]={1,0,0};
+        up[]={0,1,0};
+        dir[]={0,0,0};
+        pos[]={0,0,0};
+    };
+};
+class Stage4 {
+    texture="#(argb,8,8,3)color(1,1,1,1,AS)";
+    uvSource="tex";
+    class uvTransform {
+        aside[]={1,0,0};
+        up[]={0,1,0};
+        dir[]={0,0,0};
+        pos[]={0,0,0};
+    };
+};
+class Stage5 {
+    texture="#(argb,8,8,3)color(1,1,1,1,SMDI)";
+    uvSource="tex";
+    class uvTransform {
+        aside[]={1,0,0};
+        up[]={0,1,0};
+        dir[]={0,0,0};
+        pos[]={0,0,0};
+    };
+};
+class Stage6 {
+    texture="#(ai,64,64,1)fresnel(1.5,1.22)";
+    uvSource="none";
+};
+class Stage7 {
+    texture="a3\data_f\env_land_co.paa";
+    uvSource="none";
+};
--- a/addons/atragmx/data/tdsrecon_co.paa
+++ b/addons/atragmx/data/tdsrecon_co.paa
--- a/addons/atragmx/data/tdsrecon_nohq.paa
+++ b/addons/atragmx/data/tdsrecon_nohq.paa
--- a/addons/atragmx/functions/fnc_add_new_gun.sqf
+++ b/addons/atragmx/functions/fnc_add_new_gun.sqf
@ -0,0 +1,29 @@
+/*
+ * Author: Ruthberg
+ * Adds a new (default) gun profile to the profileNamespace
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_add_new_gun
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+private ["_gunName", "_gunProfileEntry"];
+
+_gunName = ctrlText 11001;
+if (_gunName != "") then {
+    _gunProfileEntry = [_gunName, 850, 500, 0.280, -0.0010000, 3.81, 0, 0.338, 0.338, 120, 0, 0, 9.460, "", "", 0.393, 1, "ICAO"];
+
+    GVAR(gunList) = GVAR(gunList) + [_gunProfileEntry];
+
+    lbAdd [6000, _gunProfileEntry select 0];
+
+    profileNamespace setVariable ["ACE_ATragMX_gunList", GVAR(gunList)];
+};
--- a/addons/atragmx/functions/fnc_calculate_range_card.sqf
+++ b/addons/atragmx/functions/fnc_calculate_range_card.sqf
@ -0,0 +1,62 @@
+/*
+ * Author: Ruthberg
+ * Calculates the range card output based on the current data set
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_calculate_range_card
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+[] call FUNC(parse_input);
+
+private ["_scopeBaseAngle"];
+_scopeBaseAngle = ((GVAR(workingMemory) select GVAR(currentTarget)) select 3);
+
+private ["_bulletMass", "_boreHeight", "_airFriction", "_muzzleVelocity", "_bc", "_dragModel", "_atmosphereModel"];
+_bulletMass = (GVAR(workingMemory) select GVAR(currentTarget)) select 12;
+_boreHeight = (GVAR(workingMemory) select GVAR(currentTarget)) select 5;
+_airFriction = (GVAR(workingMemory) select GVAR(currentTarget)) select 4;
+_muzzleVelocity = (GVAR(workingMemory) select GVAR(currentTarget)) select 1;
+_bc = (GVAR(workingMemory) select GVAR(currentTarget)) select 15;
+_dragModel = (GVAR(workingMemory) select GVAR(currentTarget)) select 16;
+_atmosphereModel = (GVAR(workingMemory) select GVAR(currentTarget)) select 17;
+
+private ["_temperature", "_barometricPressure", "_relativeHumidity"];
+_temperature = (GVAR(temperature) select GVAR(currentTarget));
+_barometricPressure = (GVAR(barometricPressure) select GVAR(currentTarget));
+_relativeHumidity = (GVAR(relativeHumidity) select GVAR(currentTarget));
+if (GVAR(currentUnit) == 1) then
+{
+    _temperature = (_temperature - 32) / 1.8;
+    _barometricPressure = _barometricPressure * 33.8638866667;
+};
+
+private ["_windSpeed", "_windDirection", "_inclinationAngle", "_targetSpeed", "_targetRange"];
+_windSpeed = (GVAR(windSpeed) select GVAR(currentTarget));
+_windDirection = (GVAR(windDirection) select GVAR(currentTarget));
+_inclinationAngle = (GVAR(inclinationAngle) select GVAR(currentTarget));
+_targetSpeed = (GVAR(targetSpeed) select GVAR(currentTarget));
+_targetRange = GVAR(rangeCardEndRange);
+if (GVAR(currentUnit) != 2) then
+{
+    _targetRange = _targetRange / 1.0936133;
+};
+if (GVAR(currentUnit) == 1) then
+{
+    _windSpeed = _windSpeed / 2.23693629;
+    _targetSpeed = _targetSpeed / 2.23693629;
+};
+
+GVAR(rangeCardData) = [];
+
+private ["_result"];
+_result = [_scopeBaseAngle, _bulletMass, _boreHeight, _airFriction, _muzzleVelocity, _temperature, _barometricPressure, _relativeHumidity, 1000,
+            _windSpeed, _windDirection, _inclinationAngle, _targetSpeed, _targetRange, _bc, _dragModel, _atmosphereModel, true] call FUNC(calculate_solution);
--- a/addons/atragmx/functions/fnc_calculate_scope_base_angle.sqf
+++ b/addons/atragmx/functions/fnc_calculate_scope_base_angle.sqf
@ -0,0 +1,39 @@
+/*
+ * Author: Ruthberg
+ * Calculates a new scope base angle
+ *
+ * Arguments:
+ * 0: Bullet mass <NUMBER>
+ * 1: Bore height <NUMBER>
+ * 2: air friction <NUMBER>
+ * 3: muzzle velocity <NUMBER>
+ * 4: zero range <NUMBER>
+ *
+ * Return Value:
+ * scope base angle <NUMBER>
+ *
+ * Example:
+ * call ace_atragmx_calculate_scope_base_angle
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+private ["_bulletMass", "_boreHeight", "_airFriction", "_muzzleVelocity", "_zeroRange"];
+_bulletMass     = _this select 0;
+_boreHeight     = _this select 1;
+_airFriction    = _this select 2;
+_muzzleVelocity = _this select 3;
+_zeroRange      = _this select 4;
+
+private ["_scopeBaseAngle"];
+_scopeBaseAngle = 0;
+
+private ["_temperature", "_barometricPressure", "_relativeHumidity"];
+_temperature = 15;
+_barometricPressure = 1013.25;
+_relativeHumidity = 0;
+
+_result = [_scopeBaseAngle, _bulletMass, _boreHeight, _airFriction, _muzzleVelocity, _temperature, _barometricPressure, _relativeHumidity, 1000, 0, 0, 0, 0, _zeroRange, _airFriction, 1, "ICAO", false] call FUNC(calculate_solution);
+
+_scopeBaseAngle + (_result select 0) / 60
--- a/addons/atragmx/functions/fnc_calculate_solution.sqf
+++ b/addons/atragmx/functions/fnc_calculate_solution.sqf
@ -0,0 +1,157 @@
+/*
+ * Author: Ruthberg
+ * Calculates the fireing solution
+ *
+ * Arguments:
+ * 0: Scope base angle <NUMBER>
+ * 1: Bullet mass <NUMBER>
+ * 2: Bore height <NUMBER>
+ * 3: air friction <NUMBER>
+ * 4: muzzle velocity <NUMBER>
+ * 5: temperature <NUMBER>
+ * 6: barometric pressure <NUMBER>
+ * 7: relative humidity <NUMBER>
+ * 8: simulation steps <NUMBER>
+ * 9: wind speed <NUMBER>
+ * 10: wind direction <NUMBER>
+ * 11: inclination angle <NUMBER>
+ * 12: target speed <NUMBER>
+ * 13: target range <NUMBER>
+ * 14: ballistic coefficient <NUMBER>
+ * 15: drag model <NUMBER>
+ * 16: atmosphere model <STRING>
+ * 17: Store range card data? <BOOL>
+ *
+ * Return Value:
+ * 0: Elevation <NUMBER>
+ * 1: Windage <NUMBER>
+ * 2: Lead <NUMBER>
+ * 3: Time of fligth <NUMBER>
+ * 4: Remaining velocity <NUMBER>
+ * 4: Remaining kinetic energy <NUMBER>
+ *
+ * Example:
+ * call ace_atragmx_calculate_target_range_assist
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+private ["_scopeBaseAngle", "_bulletMass", "_boreHeight", "_airFriction", "_muzzleVelocity", "_temperature", "_barometricPressure", "_relativeHumidity", "_simSteps", "_windSpeed", "_windDirection", "_inclinationAngle", "_targetSpeed", "_targetRange", "_bc", "_dragModel", "_atmosphereModel", "_storeRangeCardData"];
+_scopeBaseAngle     = _this select 0;
+_bulletMass         = _this select 1;
+_boreHeight         = _this select 2;
+_airFriction        = _this select 3;
+_muzzleVelocity     = _this select 4;
+_temperature        = _this select 5;
+_barometricPressure = _this select 6;
+_relativeHumidity   = _this select 7;
+_simSteps           = _this select 8;
+_windSpeed          = _this select 9;
+_windDirection      = _this select 10;
+_inclinationAngle   = _this select 11;
+_targetSpeed        = _this select 12;
+_targetRange        = _this select 13;
+_bc                 = _this select 14;
+_dragModel          = _this select 15;
+_atmosphereModel    = _this select 16;
+_storeRangeCardData = _this select 17;
+
+private ["_bulletPos", "_bulletVelocity", "_bulletAccel", "_bulletSpeed", "_gravity", "_deltaT"];
+_bulletPos = [0, 0, 0];
+_bulletVelocity = [0, 0, 0];
+_bulletAccel = [0, 0, 0];
+_bulletSpeed = 0;
+_gravity = [0, sin(_scopeBaseAngle + _inclinationAngle) * -9.80665, cos(_scopeBaseAngle + _inclinationAngle) * -9.80665];
+_deltaT = 1 / _simSteps;
+
+private ["_elevation", "_windage", "_lead", "_TOF", "_trueVelocity", "_trueSpeed", "_kineticEnergy"];
+_elevation = 0;
+_windage = 0;
+_lead = 0;
+_TOF = 0;
+_trueVelocity = [0, 0, 0];
+_trueSpeed = 0;
+
+private ["_n", "_range", "_rangeFactor"];
+_n = 0;
+_range = 0;
+_rangeFactor = 1;
+if (_storeRangeCardData) then {
+    if (GVAR(currentUnit) != 2) then {
+        _rangeFactor = 1.0936133;
+    };
+    GVAR(rangeCardData) = [];
+};
+
+private ["_wind"];
+_wind = [cos(270 - _windDirection * 30) * _windSpeed, sin(270 - _windDirection * 30) * _windSpeed, 0];
+if ((missionNamespace getVariable [QEGVAR(advanced_ballistics,enabled), false]) && (missionNamespace getVariable [QEGVAR(advanced_ballistics,AdvancedAirDragEnabled), false])) then {
+    _bc = [_bc, _temperature, _barometricPressure, _relativeHumidity, _atmosphereModel] call EFUNC(advanced_ballistics,calculateAtmosphericCorrection);
+};
+
+_TOF = 0;
+
+_bulletPos set [0, 0];
+_bulletPos set [1, 0];
+_bulletPos set [2, -(_boreHeight / 100)];
+
+_bulletVelocity set [0, 0];
+_bulletVelocity set [1, Cos(_scopeBaseAngle) * _muzzleVelocity];
+_bulletVelocity set [2, Sin(_scopeBaseAngle) * _muzzleVelocity];
+
+while {_TOF < 15 && (_bulletPos select 1) < _targetRange} do {
+    _bulletSpeed = vectorMagnitude _bulletVelocity;
+
+    _trueVelocity = _bulletVelocity vectorDiff _wind;
+    _trueSpeed = vectorMagnitude _trueVelocity;
+
+    if (missionNamespace getVariable [QEGVAR(advanced_ballistics,enabled), false]) then {
+        if (missionNamespace getVariable [QEGVAR(advanced_ballistics,AdvancedAirDragEnabled), false]) then {
+            private ["_drag"];
+            _drag = -1 * ([_dragModel, _bc, _trueSpeed] call EFUNC(advanced_ballistics,calculateRetardation));
+            _bulletAccel = (vectorNormalized _trueVelocity) vectorMultiply (_drag);
+        };
+    } else {
+        _bulletAccel = _trueVelocity vectorMultiply (_trueSpeed * _airFriction);
+    };
+
+    _bulletAccel = _bulletAccel vectorAdd _gravity;
+
+    _bulletVelocity = _bulletVelocity vectorAdd (_bulletAccel vectorMultiply _deltaT);
+    _bulletPos = _bulletPos vectorAdd (_bulletVelocity vectorMultiply _deltaT);
+
+    _TOF = _TOF + _deltaT;
+
+    if (_storeRangeCardData) then {
+        _range = GVAR(rangeCardStartRange) + _n * GVAR(rangeCardIncrement);
+        if ((_bulletPos select 1) * _rangeFactor >= _range && _range <= GVAR(rangeCardEndRange)) then {
+            if ((_bulletPos select 1) > 0) then {
+                _elevation = - atan((_bulletPos select 2) / (_bulletPos select 1));
+                _windage = - atan((_bulletPos select 0) / (_bulletPos select 1));
+            };
+            if (_range != 0) then {
+                _lead = (_targetSpeed * _TOF) / (Tan(3.38 / 60) * _range);
+            };
+            _kineticEnergy = 0.5 * (_bulletMass / 1000 * (_bulletSpeed ^ 2));
+            _kineticEnergy = _kineticEnergy * 0.737562149;
+
+            GVAR(rangeCardData) set [_n, [_range, _elevation * 60, _windage * 60, _lead, _TOF, _bulletSpeed, _kineticEnergy]];
+            _n = _n + 1;
+        };
+    };
+};
+
+if ((_bulletPos select 1) > 0) then {
+    _elevation = - atan((_bulletPos select 2) / (_bulletPos select 1));
+    _windage = - atan((_bulletPos select 0) / (_bulletPos select 1));
+};
+
+if (_targetRange != 0) then {
+    _lead = (_targetSpeed * _TOF) / (Tan(3.38 / 60) * _targetRange);
+};
+
+_kineticEnergy = 0.5 * (_bulletMass / 1000 * (_bulletSpeed ^ 2));
+_kineticEnergy = _kineticEnergy * 0.737562149;
+
+[_elevation * 60, _windage * 60, _lead, _TOF, _bulletSpeed, _kineticEnergy]
--- a/addons/atragmx/functions/fnc_calculate_target_range_assist.sqf
+++ b/addons/atragmx/functions/fnc_calculate_target_range_assist.sqf
@ -0,0 +1,97 @@
+/*
+ * Author: Ruthberg
+ * Calculates the target range and updates the output fields
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_calculate_target_range_assist
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+private ["_targetSize", "_imageSize", "_angle", "_estRange"];
+
+_angle = parseNumber(ctrlText 7012);
+_targetSize = parseNumber(ctrlText 7010);
+if (GVAR(rangeAssistUseTargetHeight)) then {
+    _targetSize = _targetSize * cos(_angle);
+};
+switch (GVAR(rangeAssistTargetSizeUnit)) do {
+    case 0: {
+        _targetSize = _targetSize * 0.0254;
+    };
+    case 1: {
+        _targetSize = _targetSize * 0.3048;
+    };
+    case 2: {
+        _targetSize = _targetSize * 0.01;
+    };
+};
+_imageSize = parseNumber(ctrlText 7011);
+switch (GVAR(rangeAssistImageSizeUnit)) do {
+    case 0: {
+        _imageSize = _imageSize / 6400 * 360;
+    };
+    case 1: {
+        _imageSize = _imageSize / 60;
+    };
+    case 2: {
+        _imageSize = _imageSize / 60 / 1.047;
+    };
+};
+_estRange = parseNumber(ctrlText 7013);
+if (GVAR(currentUnit) != 2) then {
+    _estRange = _estRange / 1.0936133;
+};
+
+switch (_this) do {
+    case 0: {
+        _targetSize = tan(_imageSize) * _estRange;
+
+        if (GVAR(rangeAssistUseTargetHeight)) then {
+            _targetSize = _targetSize / cos(_angle);
+        };
+
+        switch (GVAR(rangeAssistTargetSizeUnit)) do {
+            case 0: {
+                _targetSize = _targetSize / 0.0254;
+            };
+            case 1: {
+                _targetSize = _targetSize / 0.3048;
+            };
+            case 2: {
+                _targetSize = _targetSize / 0.01;
+            };
+        };
+
+        ctrlSetText [7010, Str(Round(_targetSize * 100) / 100)];
+    };
+    case 1: {
+        _imageSize = atan(_targetSize / _estRange);
+
+        switch (GVAR(rangeAssistImageSizeUnit)) do {
+            case 0: {
+                _imageSize = _imageSize * 6400 / 360;
+            };
+            case 1: {
+                _imageSize = _imageSize * 60;
+            };
+            case 2: {
+                _imageSize = _imageSize * 60 * 1.047;
+            };
+        };
+
+        ctrlSetText [7011, Str(Round(_imageSize * 100) / 100)];
+    };
+    case 2: {
+        _estRange = _targetSize / tan(_imageSize);
+
+        ctrlSetText [7013, Str(Round(_estRange))];
+    };
+};
--- a/addons/atragmx/functions/fnc_calculate_target_solution.sqf
+++ b/addons/atragmx/functions/fnc_calculate_target_solution.sqf
@ -0,0 +1,67 @@
+/*
+ * Author: Ruthberg
+ * Calculates the fireing solution and updates the result input/output fields
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_calculate_target_solution
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+[] call FUNC(parse_input);
+
+private ["_scopeBaseAngle"];
+_scopeBaseAngle = ((GVAR(workingMemory) select GVAR(currentTarget)) select 3);
+
+private ["_bulletMass", "_boreHeight", "_airFriction", "_muzzleVelocity", "_bc", "_dragModel", "_atmosphereModel"];
+_bulletMass = (GVAR(workingMemory) select GVAR(currentTarget)) select 12;
+_boreHeight = (GVAR(workingMemory) select GVAR(currentTarget)) select 5;
+_airFriction = (GVAR(workingMemory) select GVAR(currentTarget)) select 4;
+_muzzleVelocity = (GVAR(workingMemory) select GVAR(currentTarget)) select 1;
+_bc = (GVAR(workingMemory) select GVAR(currentTarget)) select 15;
+_dragModel = (GVAR(workingMemory) select GVAR(currentTarget)) select 16;
+_atmosphereModel = (GVAR(workingMemory) select GVAR(currentTarget)) select 17;
+
+private ["_temperature", "_barometricPressure", "_relativeHumidity"];
+_temperature = (GVAR(temperature) select GVAR(currentTarget));
+_barometricPressure = (GVAR(barometricPressure) select GVAR(currentTarget));
+_relativeHumidity = (GVAR(relativeHumidity) select GVAR(currentTarget));
+if (GVAR(currentUnit) == 1) then
+{
+    _temperature = (_temperature - 32) / 1.8;
+    _barometricPressure = _barometricPressure * 33.8638866667;
+};
+
+private ["_windSpeed", "_windDirection", "_inclinationAngle", "_targetSpeed", "_targetRange"];
+_windSpeed = (GVAR(windSpeed) select GVAR(currentTarget));
+_windDirection = (GVAR(windDirection) select GVAR(currentTarget));
+_inclinationAngle = (GVAR(inclinationAngle) select GVAR(currentTarget));
+_targetSpeed = (GVAR(targetSpeed) select GVAR(currentTarget));
+_targetRange = (GVAR(targetRange) select GVAR(currentTarget));
+if (GVAR(currentUnit) != 2) then
+{
+    _targetRange = _targetRange / 1.0936133;
+};
+if (GVAR(currentUnit) == 1) then
+{
+    _windSpeed = _windSpeed / 2.23693629;
+    _targetSpeed = _targetSpeed / 2.23693629;
+};
+
+_result = [_scopeBaseAngle, _bulletMass, _boreHeight, _airFriction, _muzzleVelocity, _temperature, _barometricPressure, _relativeHumidity, 1000,
+            _windSpeed, _windDirection, _inclinationAngle, _targetSpeed, _targetRange, _bc, _dragModel, _atmosphereModel, false] call FUNC(calculate_solution);
+
+GVAR(elevationOutput) set [GVAR(currentTarget), _result select 0];
+GVAR(windageOutput) set [GVAR(currentTarget), _result select 1];
+GVAR(leadOutput) set [GVAR(currentTarget), _result select 2];
+GVAR(tofOutput) set [GVAR(currentTarget), _result select 3];
+GVAR(velocityOutput) set [GVAR(currentTarget), _result select 4];
+
+[] call FUNC(update_result);
--- a/addons/atragmx/functions/fnc_calculate_target_speed_assist.sqf
+++ b/addons/atragmx/functions/fnc_calculate_target_speed_assist.sqf
@ -0,0 +1,56 @@
+/*
+ * Author: Ruthberg
+ * Calculates the target speed and updates the output fields
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_calculate_target_speed_assist
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+private ["_targetRange", "_numTicks", "_timeSecs", "_estSpeed"];
+
+_targetRange = parseNumber(ctrlText 8004);
+_numTicks = parseNumber(ctrlText 8005);
+_timeSecs = parseNumber(ctrlText 8006);
+_estSpeed = 0;
+
+if (GVAR(currentUnit) != 2) then
+{
+    _targetRange = _targetRange / 1.0936133;
+};
+
+switch (GVAR(rangeAssistImageSizeUnit)) do
+{
+    case 0:
+    {
+        _numTicks = _numTicks / 6400 * 360;
+    };
+    case 1:
+    {
+        _numTicks = _numTicks / 60;
+    };
+    case 2:
+    {
+        _numTicks = _numTicks / 60 / 1.047;
+    };
+};
+
+if (_timeSecs > 0) then
+{
+    _estSpeed = tan(_numTicks) * _targetRange / _timeSecs;
+};
+
+if (GVAR(currentUnit) == 1) then
+{
+    _estSpeed = _estSpeed * 2.23693629;
+};
+
+ctrlSetText [8007, Str(Round(_estSpeed * 10) / 10)];
--- a/addons/atragmx/functions/fnc_can_show.sqf
+++ b/addons/atragmx/functions/fnc_can_show.sqf
@ -0,0 +1,18 @@
+/*
+ * Authors: Ruthberg
+ * Tests if the ATragMX dialog can be shown
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * can_show <BOOL>
+ *
+ * Example:
+ * call ace_atragmx_fnc_can_show
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+(("ACE_ATragMX" in (uniformItems ACE_player)) || ("ACE_ATragMX" in (vestItems ACE_player))) && !(underwater ACE_player);
--- a/addons/atragmx/functions/fnc_change_gun.sqf
+++ b/addons/atragmx/functions/fnc_change_gun.sqf
@ -0,0 +1,38 @@
+/*
+ * Author: Ruthberg
+ * Selects a new gun profile and updates the gun column and the result input/output fields
+ *
+ * Arguments:
+ * gunID <number>
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_change_gun
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+if (_this < 0 || _this > (count GVAR(gunList)) - 1) exitWith {};
+
+GVAR(workingMemory) set [GVAR(currentTarget), +(GVAR(gunList) select _this)];
+GVAR(currentGun) set [GVAR(currentTarget), _this];
+
+lbSetCurSel [6000, (GVAR(currentGun) select GVAR(currentTarget))];
+
+if ((GVAR(scopeUnits) select (GVAR(currentScopeUnit) select GVAR(currentTarget))) != "Clicks") then
+{
+    GVAR(currentScopeUnit) set [GVAR(currentTarget), (GVAR(workingMemory) select GVAR(currentTarget)) select 6];
+};
+
+[] call FUNC(update_gun);
+
+GVAR(elevationOutput) set [GVAR(currentTarget), 0];
+GVAR(windageOutput) set [GVAR(currentTarget), 0];
+GVAR(leadOutput) set [GVAR(currentTarget), 0];
+GVAR(tofOutput) set [GVAR(currentTarget), 0];
+GVAR(velocityOutput) set [GVAR(currentTarget), 0];
+
+[] call FUNC(update_result);
--- a/addons/atragmx/functions/fnc_create_dialog.sqf
+++ b/addons/atragmx/functions/fnc_create_dialog.sqf
@ -0,0 +1,40 @@
+/*
+ * Author: Ruthberg
+ * Creates the ATragMX dialog
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_create_dialog
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+//if (dialog) exitWith { false };
+if (underwater ACE_player) exitWith { false };
+if (!("ACE_ATragMX" in (uniformItems ACE_player)) && !("ACE_ATragMX" in (vestItems ACE_player))) exitWith { false };
+
+createDialog 'ATragMX_Display';
+
+call FUNC(update_target_selection);
+
+true call FUNC(show_main_page);
+
+false call FUNC(show_add_new_gun);
+false call FUNC(show_gun_list);
+false call FUNC(show_range_card);
+false call FUNC(show_range_card_setup);
+false call FUNC(show_target_range_assist);
+false call FUNC(show_target_speed_assist);
+false call FUNC(show_target_speed_assist_timer);
+
+{
+    lbAdd [6000, _x select 0];
+} forEach GVAR(gunList);
+
+true
--- a/addons/atragmx/functions/fnc_cycle_range_card_columns.sqf
+++ b/addons/atragmx/functions/fnc_cycle_range_card_columns.sqf
@ -0,0 +1,22 @@
+/*
+ * Author: Ruthberg
+ * Cycles through the range card columns
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_cycle_range_card_columns
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+GVAR(rangeCardCurrentColumn) = (GVAR(rangeCardCurrentColumn) + 1) % (count GVAR(rangeCardLastColumns));
+
+ctrlSetText [5006, (GVAR(rangeCardLastColumns) select GVAR(rangeCardCurrentColumn))];
+
+[] call FUNC(update_range_card);
--- a/addons/atragmx/functions/fnc_cycle_scope_unit.sqf
+++ b/addons/atragmx/functions/fnc_cycle_scope_unit.sqf
@ -0,0 +1,23 @@
+/*
+ * Author: Ruthberg
+ * Cycles through the scope units
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_cycle_scope_unit
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+[] call FUNC(parse_input);
+
+GVAR(currentScopeUnit) set [GVAR(currentTarget), ((GVAR(currentScopeUnit) select GVAR(currentTarget)) + 1) % (count GVAR(scopeUnits))];
+
+[] call FUNC(update_scope_unit);
+[] call FUNC(update_result);
--- a/addons/atragmx/functions/fnc_delete_gun.sqf
+++ b/addons/atragmx/functions/fnc_delete_gun.sqf
@ -0,0 +1,34 @@
+/*
+ * Author: Ruthberg
+ * Deletes the currently selected gun profile from the profileNamespace
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_delete_gun
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+private ["_index"];
+_index = lbCurSel 6000;
+
+if (_index == -1) exitWith {};
+
+for "_i" from 0 to (count GVAR(currentGun)) - 1 do {
+    if ((GVAR(currentGun) select _i) > _index) then {
+        GVAR(currentGun) set [_i, (GVAR(currentGun) select _i) - 1];
+    };
+};
+
+GVAR(gunList) set [_index, 0];
+GVAR(gunList) = GVAR(gunList) - [0];
+
+lbDelete [6000, _index];
+
+profileNamespace setVariable ["ACE_ATragMX_gunList", GVAR(gunList)];
--- a/addons/atragmx/functions/fnc_init.sqf
+++ b/addons/atragmx/functions/fnc_init.sqf
@ -0,0 +1,58 @@
+/*
+ * Author: Ruthberg
+ * Inits all global variables with the default values
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_init
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+GVAR(workingMemory) = [+(GVAR(gunList) select 0), +(GVAR(gunList) select 0), +(GVAR(gunList) select 0), +(GVAR(gunList) select 0)];
+
+GVAR(scopeUnits) = ["MILs", "TMOA", "SMOA", "Clicks"];
+
+GVAR(rangeCardStartRange) = 200;
+GVAR(rangeCardEndRange) = 2000;
+GVAR(rangeCardIncrement) = 50;
+GVAR(rangeCardLastColumns) = ["Lead", "RemV", "RemE", "TmFlt"];
+GVAR(rangeCardCurrentColumn) = 3;
+GVAR(rangeCardData) = [];
+
+GVAR(GVAR(rangeAssistTargetSizeUnit)s) = ["in", "ft", "cm", "m"];
+GVAR(rangeAssistTargetSizeUnit) = 2;
+GVAR(rangeAssistImageSizeUnits) = ["MIL", "TMOA", "IOA"];
+GVAR(rangeAssistImageSizeUnit) = 0;
+GVAR(rangeAssistUseTargetHeight) = true;
+
+GVAR(speedAssistNumTicksUnits) = ["MIL", "TMOA", "IOA"];
+GVAR(speedAssistNumTicksUnit) = 0;
+GVAR(speedAssistTimer) = true;
+
+GVAR(currentUnit) = 2;
+GVAR(currentGun) = [0, 0, 0, 0];
+GVAR(currentTarget) = 0;
+GVAR(currentScopeUnit) = [0, 0, 0, 0];
+
+GVAR(temperature) = [15, 15, 15, 15];
+GVAR(barometricPressure) = [1013.25, 1013.25, 1013.25, 1013.25];
+GVAR(relativeHumidity) = [0.5, 0.5, 0.5, 0.5];
+
+GVAR(windSpeed) = [0, 0, 0, 0];
+GVAR(windDirection) = [12, 12, 12, 12];
+GVAR(inclinationAngle) = [0, 0, 0, 0];
+GVAR(targetSpeed) = [0, 0, 0, 0];
+GVAR(targetRange) = [0, 0, 0, 0];
+
+GVAR(elevationOutput) = [0, 0, 0, 0];
+GVAR(windageOutput) = [0, 0, 0, 0];
+GVAR(leadOutput) = [0, 0, 0, 0];
+GVAR(tofOutput) = [0, 0, 0, 0];
+GVAR(velocityOutput) = [0, 0, 0, 0];
--- a/addons/atragmx/functions/fnc_parse_input.sqf
+++ b/addons/atragmx/functions/fnc_parse_input.sqf
@ -0,0 +1,89 @@
+/*
+ * Author: Ruthberg
+ * Parses all input fields in the gun, atmosphere and target column and the result input fields
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_parse_input
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+GVAR(temperature) set [GVAR(currentTarget), parseNumber(ctrlText 200)];
+GVAR(barometricPressure) set [GVAR(currentTarget), 0 max parseNumber(ctrlText 210)];
+GVAR(relativeHumidity) set [GVAR(currentTarget), (0 max parseNumber(ctrlText 220) min 100) / 100];
+
+GVAR(windSpeed) set [GVAR(currentTarget), 0 max abs(parseNumber(ctrlText 300)) min 50];
+GVAR(windDirection) set [GVAR(currentTarget), 1 max Round(parseNumber(ctrlText 310)) min 12];
+GVAR(inclinationAngle) set [GVAR(currentTarget), -60 max parseNumber(ctrlText 320) min 60];
+GVAR(targetSpeed) set [GVAR(currentTarget), 0 max abs(parseNumber(ctrlText 330)) min 50];
+GVAR(targetRange) set [GVAR(currentTarget), 0 max abs(parseNumber(ctrlText 340)) min 4000];
+
+private ["_boreHeight", "_bulletMass", "_airFriction", "_muzzleVelocity"];
+_boreHeight = parseNumber(ctrlText 100);
+_bulletMass = parseNumber(ctrlText 110);
+if ((missionNamespace getVariable [QEGVAR(advanced_ballistics,enabled), false]) && (missionNamespace getVariable [QEGVAR(advanced_ballistics,AdvancedAirDragEnabled), false])) then {
+    _airFriction = 0.1 max parseNumber(ctrlText 120) min 2;
+} else {
+    _airFriction = parseNumber(ctrlText 120) / -1000;
+};
+_muzzleVelocity = parseNumber(ctrlText 130);
+if (GVAR(currentUnit) == 1) then
+{
+    _boreHeight = _boreHeight * 2.54;
+    _bulletMass = _bulletMass * 0.06479891;
+    _muzzleVelocity = _muzzleVelocity / 3.2808399;
+};
+_boreHeight = 0.1 max _boreHeight min 10;
+_bulletMass = 1 max _bulletMass min 100;
+_muzzleVelocity = 100 max _muzzleVelocity min 1400;
+
+(GVAR(workingMemory) select GVAR(currentTarget)) set [5, _boreHeight];
+(GVAR(workingMemory) select GVAR(currentTarget)) set [12, _bulletMass];
+if ((missionNamespace getVariable [QEGVAR(advanced_ballistics,enabled), false]) && (missionNamespace getVariable [QEGVAR(advanced_ballistics,AdvancedAirDragEnabled), false])) then {
+    (GVAR(workingMemory) select GVAR(currentTarget)) set [15, _airFriction];
+} else {
+    (GVAR(workingMemory) select GVAR(currentTarget)) set [4, _airFriction];
+};
+(GVAR(workingMemory) select GVAR(currentTarget)) set [1, _muzzleVelocity];
+
+private ["_elevationCur", "_elevationCur", "_elevationScopeStep", "_windageScopeStep"];
+_elevationCur = parseNumber(ctrlText 402);
+_windageCur = parseNumber(ctrlText 412);
+
+switch ((GVAR(currentScopeUnit) select GVAR(currentTarget))) do
+{
+    case 0:
+    {		
+        _elevationCur = _elevationCur * 3.38;
+        _windageCur = _windageCur * 3.38;
+    };
+    
+    case 2:
+    {		
+        _elevationCur = _elevationCur / 1.047;
+        _windageCur = _windageCur / 1.047;
+    };
+    
+    case 3:
+    {
+        _elevationScopeStep = ((GVAR(workingMemory) select GVAR(currentTarget)) select 7);
+        _windageScopeStep = ((GVAR(workingMemory) select GVAR(currentTarget)) select 8);
+        
+        _elevationCur = _elevationCur * _elevationScopeStep;
+        _windageCur = _windageCur * _windageScopeStep;
+    };
+};
+
+(GVAR(workingMemory) select GVAR(currentTarget)) set [10, _elevationCur];
+(GVAR(workingMemory) select GVAR(currentTarget)) set [11, _windageCur];
+
+[] call FUNC(update_gun);
+[] call FUNC(update_atmosphere);
+[] call FUNC(update_target);
--- a/addons/atragmx/functions/fnc_reset_relative_click_memory.sqf
+++ b/addons/atragmx/functions/fnc_reset_relative_click_memory.sqf
@ -0,0 +1,21 @@
+/*
+ * Author: Ruthberg
+ * Resets the relative click memory and updates the result input/output fields
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_reset_relative_click_memory
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+(GVAR(workingMemory) select GVAR(currentTarget)) set [10, 0];
+(GVAR(workingMemory) select GVAR(currentTarget)) set [11, 0];
+
+[] call FUNC(update_result);
--- a/addons/atragmx/functions/fnc_save_gun.sqf
+++ b/addons/atragmx/functions/fnc_save_gun.sqf
@ -0,0 +1,28 @@
+/*
+ * Author: Ruthberg
+ * Saves the currently select gun profile into the profileNamespace
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_save_gun
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+private ["_index"];
+_index = 0 max (lbCurSel 6000);
+
+GVAR(gunList) set [_index, +(GVAR(workingMemory) select GVAR(currentTarget))];
+
+lbClear 6000;
+{
+    lbAdd [6000, _x select 0];
+} forEach GVAR(gunList);
+
+profileNamespace setVariable ["ACE_ATragMX_gunList", GVAR(gunList)];
--- a/addons/atragmx/functions/fnc_show_add_new_gun.sqf
+++ b/addons/atragmx/functions/fnc_show_add_new_gun.sqf
@ -0,0 +1,18 @@
+/*
+ * Author: Ruthberg
+ * Shows/Hides add new gun controls
+ *
+ * Arguments:
+ * visible - <BOOL>
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_show_add_new_gun
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+{ctrlShow [_x, _this]} forEach [11000, 11001, 11002, 11003];
--- a/addons/atragmx/functions/fnc_show_gun_list.sqf
+++ b/addons/atragmx/functions/fnc_show_gun_list.sqf
@ -0,0 +1,18 @@
+/*
+ * Author: Ruthberg
+ * Shows/Hides the gun list controls
+ *
+ * Arguments:
+ * visible - <BOOL>
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_show_gun_list
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+{ctrlShow [_x, _this]} forEach [6000, 6001, 6002, 6003, 6004, 6005, 6006, 6007];
--- a/addons/atragmx/functions/fnc_show_main_page.sqf
+++ b/addons/atragmx/functions/fnc_show_main_page.sqf
@ -0,0 +1,19 @@
+/*
+ * Author: Ruthberg
+ * Shows/Hides the main menu controls
+ *
+ * Arguments:
+ * visible - <BOOL>
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_show_main_page
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+{ctrlShow [_x, _this]} forEach [10, 100, 11, 110, 12, 120, 13, 130, 14, 140, 20, 200, 21, 210, 22, 220, 30, 300, 31, 310, 32, 320, 33, 330, 34, 340, 40, 400, 401, 402, 403, 41, 410, 411, 412, 42, 420,
+                                500, 501, 502, 503, 600, 601, 602, 603, 1000, 2000, 3000, 4000, 4001, 4002, 4003, 4004, 4005, 4006, 4007, 4008];
--- a/addons/atragmx/functions/fnc_show_range_card.sqf
+++ b/addons/atragmx/functions/fnc_show_range_card.sqf
@ -0,0 +1,18 @@
+/*
+ * Author: Ruthberg
+ * Shows/Hides the range card controls
+ *
+ * Arguments:
+ * visible - <BOOL>
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_show_range_card
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+{ctrlShow [_x, _this]} forEach [5000, 5001, 5002, 5003, 5004, 5005, 5006, 5007];
--- a/addons/atragmx/functions/fnc_show_range_card_setup.sqf
+++ b/addons/atragmx/functions/fnc_show_range_card_setup.sqf
@ -0,0 +1,18 @@
+/*
+ * Author: Ruthberg
+ * Shows/Hides the range card setup controls
+ *
+ * Arguments:
+ * visible - <BOOL>
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_show_range_card_setup
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+{ctrlShow [_x, _this]} forEach [10000, 10001, 10002, 10003, 10004, 10005, 10006, 10007, 10008, 10009];
--- a/addons/atragmx/functions/fnc_show_target_range_assist.sqf
+++ b/addons/atragmx/functions/fnc_show_target_range_assist.sqf
@ -0,0 +1,18 @@
+/*
+ * Author: Ruthberg
+ * Shows/Hides the target range assist controls
+ *
+ * Arguments:
+ * visible - <BOOL>
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_show_target_range_assist
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+{ctrlShow [_x, _this]} forEach [7000, 7001, 7002, 7003, 7004, 7005, 7006, 7007, 7008, 7009, 7010, 7011, 7012, 7013, 7014, 7015, 7016, 7017, 7018, 7019, 7020];
--- a/addons/atragmx/functions/fnc_show_target_speed_assist.sqf
+++ b/addons/atragmx/functions/fnc_show_target_speed_assist.sqf
@ -0,0 +1,18 @@
+/*
+ * Author: Ruthberg
+ * Shows/Hides the target speed assist controls
+ *
+ * Arguments:
+ * visible - <BOOL>
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_show_target_speed_assist
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+{ctrlShow [_x, _this]} forEach [8000, 8001, 8002, 8003, 8004, 8005, 8006, 8007, 8008, 8009, 8010, 8011, 8012, 8013, 8014, 8015];
--- a/addons/atragmx/functions/fnc_show_target_speed_assist_timer.sqf
+++ b/addons/atragmx/functions/fnc_show_target_speed_assist_timer.sqf
@ -0,0 +1,18 @@
+/*
+ * Author: Ruthberg
+ * Shows/Hides the target speed assist timer controls
+ *
+ * Arguments:
+ * visible - <BOOL>
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_show_target_speed_assist_timer
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+{ctrlShow [_x, _this]} forEach [9000, 9001, 9002];
--- a/addons/atragmx/functions/fnc_sord.sqf
+++ b/addons/atragmx/functions/fnc_sord.sqf
@ -0,0 +1,27 @@
+/*
+ * Author: Ruthberg
+ * Handles incoming data packets from the Vectronix Vector LRF
+ *
+ * Arguments:
+ * 0: Slope distance (Meters) <NUMBER>
+ * 1: Azimuth (Degrees) <NUMBER>
+ * 2: Inclination (Degrees) <NUMBER>
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * [1000, 45, 1] call ace_microdagr_fnc_recieveRangefinderData
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+private ["_slopeDistance", "_azimuth", "_inclination"];
+_slopeDistance = _this select 0;
+_azimuth       = _this select 1;
+_inclination   = _this select 2;
+
+//_inclination = asin((ACE_player weaponDirection currentWeapon ACE_player) select 2);
+GVAR(inclinationAngle) set [GVAR(currentTarget), _inclination];
+GVAR(targetRange) set [GVAR(currentTarget), _slopeDistance];
--- a/addons/atragmx/functions/fnc_target_speed_assist_timer.sqf
+++ b/addons/atragmx/functions/fnc_target_speed_assist_timer.sqf
@ -0,0 +1,48 @@
+/*
+ * Author: Ruthberg
+ * Shows and starts the target speed assist timer
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_fnc_target_speed_assist_timer
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+#define _dsp (uiNamespace getVariable "ATragMX_Display")
+
+if !(ctrlVisible 9000) then {
+
+    false call FUNC(show_target_speed_assist);
+    true call FUNC(show_target_speed_assist_timer);
+
+    ctrlSetFocus (_dsp displayCtrl 9002);
+    
+    [{
+        private ["_args", "_startTime"];
+        _args = _this select 0;
+        _startTime = _args select 0;
+        
+        if (!(GVAR(speedAssistTimer))) exitWith {
+            GVAR(speedAssistTimer) = true;
+            
+            ctrlSetText [8006, Str(Round((time - _startTime) * 10) / 10)];
+
+            [] call FUNC(calculate_target_speed_assist);
+
+            false call FUNC(show_target_speed_assist_timer);
+            true call FUNC(show_target_speed_assist);
+            
+            [_this select 1] call cba_fnc_removePerFrameHandler;
+        };
+        
+        ctrlSetText [9001, Str(Round((time - _startTime) * 10) / 10)];
+        
+    }, 0.1, [time]] call CBA_fnc_addPerFrameHandler;
+};
--- a/addons/atragmx/functions/fnc_toggle_gun_list.sqf
+++ b/addons/atragmx/functions/fnc_toggle_gun_list.sqf
@ -0,0 +1,36 @@
+/*
+ * Author: Ruthberg
+ * Toggles the gun list screen on/off
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_fnc_toggle_gun_list
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+#define _dsp (uiNamespace getVariable "ATragMX_Display")
+
+if (ctrlVisible 6000) then
+{
+    false call FUNC(show_gun_list);
+    true call FUNC(show_main_page);
+    
+    if (_this) then {
+        (lbCurSel 6000) call FUNC(change_gun);
+    };
+} else
+{
+    false call FUNC(show_main_page);
+    true call FUNC(show_gun_list);
+    
+    ctrlSetFocus (_dsp displayCtrl 6002);
+
+    lbSetCurSel [6000, (GVAR(currentGun) select GVAR(currentTarget))];
+};
--- a/addons/atragmx/functions/fnc_toggle_range_card.sqf
+++ b/addons/atragmx/functions/fnc_toggle_range_card.sqf
@ -0,0 +1,33 @@
+/*
+ * Author: Ruthberg
+ * Toggles the range card screen on/off
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_fnc_toggle_range_card
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+#define _dsp (uiNamespace getVariable "ATragMX_Display")
+
+if (ctrlVisible 5006) then
+{
+    false call FUNC(show_range_card);
+    true call FUNC(show_main_page);
+} else
+{
+    false call FUNC(show_main_page);
+    true call FUNC(show_range_card);
+    
+    ctrlSetFocus (_dsp displayCtrl 5001);
+    
+    [] call FUNC(calculate_range_card);
+    [] call FUNC(update_range_card);
+};
--- a/addons/atragmx/functions/fnc_toggle_range_card_setup.sqf
+++ b/addons/atragmx/functions/fnc_toggle_range_card_setup.sqf
@ -0,0 +1,44 @@
+/*
+ * Author: Ruthberg
+ * Toggles the range card setup screen on/off
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_fnc_toggle_range_card_setup
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+#define _dsp (uiNamespace getVariable "ATragMX_Display")
+
+if (ctrlVisible 10000) then
+{
+    false call FUNC(show_range_card_setup);
+    true call FUNC(show_range_card);
+    
+    if (_this == 1) then
+    {
+        GVAR(rangeCardStartRange) = 0 max Round(parseNumber(ctrlText 10003)) min 3000;
+        GVAR(rangeCardEndRange) = 0 max Round(parseNumber(ctrlText 10004)) min 3000;
+        GVAR(rangeCardIncrement) = 1 max Round(parseNumber(ctrlText 10005)) min 3000;
+        
+        [] call FUNC(calculate_range_card);
+        [] call FUNC(update_range_card);
+    };
+} else
+{
+    false call FUNC(show_range_card);
+    true call FUNC(show_range_card_setup);
+    
+    ctrlSetFocus (_dsp displayCtrl 10006);
+    
+    ctrlSetText [10003, Str(Round(GVAR(rangeCardStartRange)))];
+    ctrlSetText [10004, Str(Round(GVAR(rangeCardEndRange)))];
+    ctrlSetText [10005, Str(Round(GVAR(rangeCardIncrement)))];
+};
--- a/addons/atragmx/functions/fnc_toggle_target_range_assist.sqf
+++ b/addons/atragmx/functions/fnc_toggle_target_range_assist.sqf
@ -0,0 +1,47 @@
+/*
+ * Author: Ruthberg
+ * Toggles the target range assist screen on/off
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_fnc_toggle_target_range_assist
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+#define _dsp (uiNamespace getVariable "ATragMX_Display")
+
+if (ctrlVisible 7000) then
+{
+    false call FUNC(show_target_range_assist);
+    true call FUNC(show_main_page);
+    
+    if (_this == 1) then
+    {
+        ctrlSetText [320, Str(parseNumber(ctrlText 7012))];
+        ctrlSetText [340, Str(parseNumber(ctrlText 7013))];
+    };
+} else
+{
+    false call FUNC(show_main_page);
+    true call FUNC(show_target_range_assist);
+    
+    ctrlSetFocus (_dsp displayCtrl 7018);
+    
+    ctrlSetText [7012, Str(parseNumber(ctrlText 320))];
+    ctrlSetText [7013, Str(parseNumber(ctrlText 340))];
+
+    if (GVAR(currentUnit) != 2) then
+    {
+        ctrlSetText [7016, "Yards"];
+    } else
+    {
+        ctrlSetText [7016, "Meters"];
+    };
+};
--- a/addons/atragmx/functions/fnc_toggle_target_speed_assist.sqf
+++ b/addons/atragmx/functions/fnc_toggle_target_speed_assist.sqf
@ -0,0 +1,54 @@
+/*
+ * Author: Ruthberg
+ * Toggles the target speed assist screen on/off
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_fnc_toggle_target_speed_assist
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+#define _dsp (uiNamespace getVariable "ATragMX_Display")
+
+if (ctrlVisible 8000) then
+{
+    false call FUNC(show_target_speed_assist);
+    true call FUNC(show_main_page);
+    
+    if (_this == 1) then
+    {
+        [] call FUNC(calculate_target_speed_assist);
+        ctrlSetText [330, Str(parseNumber(ctrlText 8007))];
+    };
+} else
+{
+    false call FUNC(show_main_page);
+    true call FUNC(show_target_speed_assist);
+    
+    ctrlSetFocus (_dsp displayCtrl 8012);
+    
+    ctrlSetText [8004, Str(Round((GVAR(targetRange) select GVAR(currentTarget))))];
+
+    if (GVAR(currentUnit) != 2) then
+    {
+        ctrlSetText [8008, "Yards"];
+    } else
+    {
+        ctrlSetText [8008, "Meters"];
+    };
+    
+    if (GVAR(currentUnit) != 1) then
+    {
+        ctrlSetText [8011, "m/s"];
+    } else
+    {
+        ctrlSetText [8011, "mph"];
+    };
+};
--- a/addons/atragmx/functions/fnc_update_atmosphere.sqf
+++ b/addons/atragmx/functions/fnc_update_atmosphere.sqf
@ -0,0 +1,24 @@
+/*
+ * Author: Ruthberg
+ * Updates all atmosphere column input fields
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_fnc_update_atmosphere
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+ctrlSetText [200, Str(Round((GVAR(temperature) select GVAR(currentTarget)) * 10) / 10)];
+if (GVAR(currentUnit) == 1) then {
+    ctrlSetText [210, Str(Round((GVAR(barometricPressure) select GVAR(currentTarget)) * 100) / 100)];
+} else {
+    ctrlSetText [210, Str(Round(GVAR(barometricPressure) select GVAR(currentTarget)))];
+};
+ctrlSetText [220, Str(Round((GVAR(relativeHumidity) select GVAR(currentTarget)) * 100 * 10) / 10)];
--- a/addons/atragmx/functions/fnc_update_gun.sqf
+++ b/addons/atragmx/functions/fnc_update_gun.sqf
@ -0,0 +1,53 @@
+/*
+ * Author: Ruthberg
+ * Updates all gun column input fields
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_fnc_update_gun
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+ctrlSetText [1000, (GVAR(workingMemory) select GVAR(currentTarget)) select 0];
+if (GVAR(currentUnit) == 1) then
+{
+    ctrlSetText [ 100, Str(Round(((GVAR(workingMemory) select GVAR(currentTarget)) select 5) / 2.54 * 100) / 100)];
+} else
+{
+    ctrlSetText [ 100, Str(Round(((GVAR(workingMemory) select GVAR(currentTarget)) select 5) * 100) / 100)];
+};
+if (GVAR(currentUnit) == 1) then
+{
+    ctrlSetText [ 110, Str(Round(((GVAR(workingMemory) select GVAR(currentTarget)) select 12) * 15.4323584))];
+} else
+{
+    ctrlSetText [ 110, Str(Round((GVAR(workingMemory) select GVAR(currentTarget)) select 12))];
+};
+if ((missionNamespace getVariable [QEGVAR(advanced_ballistics,enabled), false]) && (missionNamespace getVariable [QEGVAR(advanced_ballistics,AdvancedAirDragEnabled), false])) then {
+    ctrlSetText [ 120, Str(Round(((GVAR(workingMemory) select GVAR(currentTarget)) select 15) * 1000) / 1000)];
+} else {
+    ctrlSetText [ 120, Str(Round(((GVAR(workingMemory) select GVAR(currentTarget)) select 4) * -1000 * 1000) / 1000)];
+};
+if (GVAR(currentUnit) == 1) then
+{
+    ctrlSetText [130, Str(Round(((GVAR(workingMemory) select GVAR(currentTarget)) select 1) * 3.2808399))];
+} else
+{
+    ctrlSetText [130, Str(Round((GVAR(workingMemory) select GVAR(currentTarget)) select 1))];
+};
+if (GVAR(currentUnit) == 2) then
+{
+    ctrlSetText [140, Str(Round((GVAR(workingMemory) select GVAR(currentTarget)) select 2))];
+} else
+{
+    ctrlSetText [140, Str(Round(((GVAR(workingMemory) select GVAR(currentTarget)) select 2) * 1.0936133))];
+};
+
+[] call FUNC(update_scope_unit);
--- a/addons/atragmx/functions/fnc_update_range_card.sqf
+++ b/addons/atragmx/functions/fnc_update_range_card.sqf
@ -0,0 +1,104 @@
+/*
+ * Author: Ruthberg
+ * Updates the range card listbox content
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_fnc_update_range_card
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+private ["_range", "_elevation", "_windage", "_lead", "_TOF", "_velocity", "_kineticEnergy", "_rangeOutput", "_elevationOutput", "_windageOutput", "_lastColumnOutput"];
+_lastColumnOutput = "";
+
+ctrlSetText [5006, (GVAR(rangeCardLastColumns) select GVAR(rangeCardCurrentColumn))];
+
+if (GVAR(currentUnit) != 2) then
+{
+    ctrlSetText [5003, "Yards"];
+} else
+{
+    ctrlSetText [5003, "Meters"];
+};
+
+lnbClear 5007;
+
+{
+    _range = _x select 0;
+    _elevation = _x select 1;
+    _windage = _x select 2;
+    _lead = _x select 3;
+    _TOF =  _x select 4;
+    _velocity = _x select 5;
+    _kineticEnergy = _x select 6;
+    
+    switch ((GVAR(currentScopeUnit) select GVAR(currentTarget))) do
+    {
+        case 0:
+        {
+            _elevation = _elevation / 3.38;
+            _windage = _windage / 3.38;
+        };
+        
+        case 2:
+        {
+            _elevation = _elevation * 1.047;
+            _windage = _windage * 1.047;
+        };
+        
+        case 3:
+        {
+            _elevationScopeStep = ((GVAR(workingMemory) select GVAR(currentTarget)) select 7);
+            _windageScopeStep = ((GVAR(workingMemory) select GVAR(currentTarget)) select 8);
+            
+            _elevation = Round(_elevation / _elevationScopeStep);
+            _windage = Round(_windage / _windageScopeStep);
+        };
+    };
+    
+    _elevationOutput = Str(Round(_elevation * 100) / 100);
+    _windageOutput = Str(Round(_windage * 100) / 100);
+    
+    _rangeOutput = Str(_range);
+    if (_velocity < 340.29) then
+    {
+        _rangeOutput = _rangeOutput + "*";
+    };
+    
+    if (GVAR(currentUnit) == 1) then
+    {
+        _velocity = _velocity * 3.2808399;
+    };
+    
+    switch (GVAR(rangeCardCurrentColumn)) do
+    {
+        case 0:
+        {
+            _lastColumnOutput = Str(Round(_lead * 100) / 100);
+        };
+        
+        case 1:
+        {
+            _lastColumnOutput = Str(Round(_velocity));
+        };
+        
+        case 2:
+        {
+            _lastColumnOutput = Str(Round(_kineticEnergy));
+        };
+        
+        case 3:
+        {
+            _lastColumnOutput = Str(Round(_TOF * 100) / 100);
+        }
+    };
+    
+    lnbAddRow [5007, [_rangeOutput, _elevationOutput, _windageOutput, _lastColumnOutput]];
+} forEach GVAR(rangeCardData);
--- a/addons/atragmx/functions/fnc_update_relative_click_memory.sqf
+++ b/addons/atragmx/functions/fnc_update_relative_click_memory.sqf
@ -0,0 +1,21 @@
+/*
+ * Author: Ruthberg
+ * Updates the relative click memory
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_fnc_update_relative_click_memory
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+(GVAR(workingMemory) select GVAR(currentTarget)) set [10, (GVAR(elevationOutput) select GVAR(currentTarget))];
+(GVAR(workingMemory) select GVAR(currentTarget)) set [11, (GVAR(windageOutput) select GVAR(currentTarget))];
+
+[] call FUNC(update_result);
--- a/addons/atragmx/functions/fnc_update_result.sqf
+++ b/addons/atragmx/functions/fnc_update_result.sqf
@ -0,0 +1,80 @@
+/*
+ * Author: Ruthberg
+ * Updates the result input and output fields
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_fnc_update_result
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+private ["_elevationAbs", "_elevationRel", "_elevationCur", "_windageAbs", "_windageRel", "_windageCur", "_lead", "_elevationScopeStep", "_windageScopeStep"];
+_elevationAbs = (GVAR(elevationOutput) select GVAR(currentTarget));
+_windageAbs = (GVAR(windageOutput) select GVAR(currentTarget));
+
+_elevationCur = (GVAR(workingMemory) select GVAR(currentTarget)) select 10;
+_windageCur = (GVAR(workingMemory) select GVAR(currentTarget)) select 11;
+
+_elevationRel = _elevationAbs - _elevationCur;
+_windageRel = _windageAbs - _windageCur;
+
+_lead = (GVAR(leadOutput) select GVAR(currentTarget));
+
+switch ((GVAR(currentScopeUnit) select GVAR(currentTarget))) do
+{
+    case 0:
+    {
+        _elevationAbs = _elevationAbs / 3.38;
+        _windageAbs = _windageAbs / 3.38;
+        
+        _elevationRel = _elevationRel / 3.38;
+        _windageRel = _windageRel / 3.38;
+        
+        _elevationCur = _elevationCur / 3.38;
+        _windageCur = _windageCur / 3.38;
+    };
+    
+    case 2:
+    {
+        _elevationAbs = _elevationAbs * 1.047;
+        _windageAbs = _windageAbs * 1.047;
+        
+        _elevationRel = _elevationRel * 1.047;
+        _windageRel = _windageRel * 1.047;
+        
+        _elevationCur = _elevationCur * 1.047;
+        _windageCur = _windageCur * 1.047;
+    };
+    
+    case 3:
+    {
+        _elevationScopeStep = ((GVAR(workingMemory) select GVAR(currentTarget)) select 7);
+        _windageScopeStep = ((GVAR(workingMemory) select GVAR(currentTarget)) select 8);
+        
+        _elevationAbs = Round(_elevationAbs / _elevationScopeStep);
+        _windageAbs = Round(_windageAbs / _windageScopeStep);
+        
+        _elevationRel = Round(_elevationRel / _elevationScopeStep);
+        _windageRel = Round(_windageRel / _windageScopeStep);
+        
+        _elevationCur = Round(_elevationCur / _elevationScopeStep);
+        _windageCur = Round(_windageCur / _windageScopeStep);
+    };
+};
+
+ctrlSetText [400, Str(Round(_elevationAbs * 100) / 100)];
+ctrlSetText [401, Str(Round(_elevationRel * 100) / 100)];
+ctrlSetText [402, Str(Round(_elevationCur * 100) / 100)];
+
+ctrlSetText [410, Str(Round(_windageAbs * 100) / 100)];
+ctrlSetText [411, Str(Round(_windageRel * 100) / 100)];
+ctrlSetText [412, Str(Round(_windageCur * 100) / 100)];
+
+ctrlSetText [420, Str(Round(_lead * 100) / 100)];
--- a/addons/atragmx/functions/fnc_update_scope_unit.sqf
+++ b/addons/atragmx/functions/fnc_update_scope_unit.sqf
@ -0,0 +1,19 @@
+/*
+ * Author: Ruthberg
+ * Updates the scope unit fields
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_fnc_update_scope_unit
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+ctrlSetText [2000, GVAR(scopeUnits) select (GVAR(currentScopeUnit) select GVAR(currentTarget))];
+ctrlSetText [5000, GVAR(scopeUnits) select (GVAR(currentScopeUnit) select GVAR(currentTarget))];
--- a/addons/atragmx/functions/fnc_update_target.sqf
+++ b/addons/atragmx/functions/fnc_update_target.sqf
@ -0,0 +1,37 @@
+/*
+ * Author: Ruthberg
+ * Updates all target column input fields
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_fnc_update_target
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+if (!isNil QGVAR(windSpeed)) then
+{
+    ctrlSetText [300, Str(Round((GVAR(windSpeed) select GVAR(currentTarget)) * 100) / 100)];
+};
+if (!isNil QGVAR(windDirection)) then
+{
+    ctrlSetText [310, Str(Round((GVAR(windDirection) select GVAR(currentTarget))))];
+};
+if (!isNil QGVAR(inclinationAngle)) then
+{
+    ctrlSetText [320, Str(Round((GVAR(inclinationAngle) select GVAR(currentTarget))))];
+};
+if (!isNil QGVAR(targetSpeed)) then
+{
+    ctrlSetText [330, Str(Round((GVAR(targetSpeed) select GVAR(currentTarget)) * 100) / 100)];
+};
+if (!isNil QGVAR(targetRange)) then
+{
+    ctrlSetText [340, Str(Round((GVAR(targetRange) select GVAR(currentTarget))))];
+};
--- a/addons/atragmx/functions/fnc_update_target_selection.sqf
+++ b/addons/atragmx/functions/fnc_update_target_selection.sqf
@ -0,0 +1,29 @@
+/*
+ * Author: Ruthberg
+ * Updates all input fields based on the currently selected target
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_fnc_update_target_selection
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+#define _dsp (uiNamespace getVariable "ATragMX_Display")
+
+(_dsp displayCtrl 500) ctrlEnable true;
+(_dsp displayCtrl 501) ctrlEnable true;
+(_dsp displayCtrl 502) ctrlEnable true;
+(_dsp displayCtrl 503) ctrlEnable true;
+
+(_dsp displayCtrl 500 + GVAR(currentTarget)) ctrlEnable false;
+
+ctrlSetFocus (_dsp displayCtrl 3000);
+
+[] call FUNC(update_unit_selection);
--- a/addons/atragmx/functions/fnc_update_unit_selection.sqf
+++ b/addons/atragmx/functions/fnc_update_unit_selection.sqf
@ -0,0 +1,29 @@
+/*
+ * Author: Ruthberg
+ * Updates all input fields based on the currently selected unit
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_fnc_update_unit_selection
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+#define _dsp (uiNamespace getVariable "ATragMX_Display")
+
+(_dsp displayCtrl 600) ctrlEnable true;
+(_dsp displayCtrl 601) ctrlEnable true;
+(_dsp displayCtrl 602) ctrlEnable true;
+
+(_dsp displayCtrl 600 + GVAR(currentUnit)) ctrlEnable false;
+
+[] call FUNC(update_gun);
+[] call FUNC(update_atmosphere);
+[] call FUNC(update_target);
+[] call FUNC(update_result);
--- a/addons/atragmx/functions/fnc_update_zero_range.sqf
+++ b/addons/atragmx/functions/fnc_update_zero_range.sqf
@ -0,0 +1,55 @@
+/*
+ * Author: Ruthberg
+ * Updates the scope base angle based on the zero range input
+ *
+ * Arguments:
+ * Nothing
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * call ace_atragmx_fnc_update_zero_range
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+private ["_scopeBaseAngle"];
+_scopeBaseAngle = ((GVAR(workingMemory) select GVAR(currentTarget)) select 3);
+
+private ["_bulletMass", "_boreHeight", "_airFriction", "_muzzleVelocity", "_bc", "_dragModel", "_atmosphereModel"];
+_bulletMass = (GVAR(workingMemory) select GVAR(currentTarget)) select 12;
+_boreHeight = (GVAR(workingMemory) select GVAR(currentTarget)) select 5;
+_airFriction = (GVAR(workingMemory) select GVAR(currentTarget)) select 4;
+_muzzleVelocity = (GVAR(workingMemory) select GVAR(currentTarget)) select 1;
+_bc = (GVAR(workingMemory) select GVAR(currentTarget)) select 15;
+_dragModel = (GVAR(workingMemory) select GVAR(currentTarget)) select 16;
+_atmosphereModel = (GVAR(workingMemory) select GVAR(currentTarget)) select 17;
+
+private ["_zeroRange"];
+_zeroRange = Round(parseNumber(ctrlText 140));
+if (GVAR(currentUnit) != 2) then
+{
+    _zeroRange = _zeroRange / 1.0936133;
+};
+if (_zeroRange < 10) exitWith {
+    (GVAR(workingMemory) select GVAR(currentTarget)) set [2, _zeroRange];
+    (GVAR(workingMemory) select GVAR(currentTarget)) set [3, 0];
+};
+
+private ["_temperature", "_barometricPressure", "_relativeHumidity"];
+_temperature = (GVAR(temperature) select GVAR(currentTarget));
+_barometricPressure = (GVAR(barometricPressure) select GVAR(currentTarget));
+_relativeHumidity = (GVAR(relativeHumidity) select GVAR(currentTarget));
+if (GVAR(currentUnit) == 1) then
+{
+    _temperature = (_temperature - 32) / 1.8;
+    _barometricPressure = _barometricPressure * 33.8638866667;
+};
+
+private ["_result"];
+_result = [_scopeBaseAngle, _bulletMass, _boreHeight, _airFriction, _muzzleVelocity, _temperature, _barometricPressure, _relativeHumidity, 1000, 0, 0, 0, 0, _zeroRange, _bc, _dragModel, _atmosphereModel, false] call FUNC(calculate_solution);
+
+(GVAR(workingMemory) select GVAR(currentTarget)) set [2, _zeroRange];
+(GVAR(workingMemory) select GVAR(currentTarget)) set [3, _scopeBaseAngle + (_result select 0) / 60];
--- a/addons/atragmx/functions/script_component.hpp
+++ b/addons/atragmx/functions/script_component.hpp
@ -0,0 +1 @@
+#include "\z\ace\addons\atragmx\script_component.hpp"
--- a/addons/atragmx/initKeybinds.sqf
+++ b/addons/atragmx/initKeybinds.sqf
@ -0,0 +1,11 @@
+["ACE3", QGVAR(ATragMXDialogKey), localize "STR_ACE_ATragMX_ATragMXDialogKey",
+{
+    // Conditions: canInteract
+    if !([ACE_player, objNull, []] call EFUNC(common,canInteractWith)) exitWith {false};
+    
+    // Statement
+    [] call FUNC(create_dialog);
+    false
+},
+{false},
+[197, [false, false, false]], false, 0] call CBA_fnc_addKeybind; // (PRINT)
--- a/addons/atragmx/script_component.hpp
+++ b/addons/atragmx/script_component.hpp
@ -0,0 +1,12 @@
+#define COMPONENT atragmx
+#include "\z\ace\addons\main\script_mod.hpp"
+
+#ifdef DEBUG_ENABLED_ATRAGMX
+    #define DEBUG_MODE_FULL
+#endif
+
+#ifdef DEBUG_SETTINGS_ATRAGMX
+    #define DEBUG_SETTINGS DEBUG_SETTINGS_ATRAGMX
+#endif
+
+#include "\z\ace\addons\main\script_macros.hpp"
--- a/addons/atragmx/stringtable.xml
+++ b/addons/atragmx/stringtable.xml
@ -0,0 +1,30 @@
+<?xml version="1.0" encoding="utf-8"?>
+<!-- Edited with tabler. -->
+<Project name="ACE">
+    <Package name="ATragMX">
+        <Key ID="STR_ACE_ATragMX_Name">
+            <English>ATragMX</English>
+            <German>ATragMX</German>
+            <Spanish>ATragMX</Spanish>
+            <French>ATragMX</French>
+            <Polish>ATragMX</Polish>
+            <Czech>ATragMX</Czech>
+            <Italian>ATragMX</Italian>
+            <Hungarian>ATragMX</Hungarian>
+            <Portuguese>ATragMX</Portuguese>
+            <Russian>ATragMX</Russian>
+        </Key>
+        <Key ID="STR_ACE_ATragMX_OpenATragMXDialog">
+            <English>Open ATragMX</English>
+            <Polish>Otwórz ATragMX</Polish>
+        </Key>
+        <Key ID="STR_ACE_ATragMX_Description">
+            <English>Rugged PDA with ATragMX</English>
+            <Polish>Przenośny PDA z kalkulatorem balistycznym ATragMX</Polish>
+        </Key>
+        <Key ID="STR_ACE_ATragMX_ATragMXDialogKey">
+            <English>Open ATragMX</English>
+            <Polish>Otwórz ATragMX</Polish>
+        </Key>
+    </Package>
+</Project>
--- a/addons/attach/CfgMagazines.hpp
+++ b/addons/attach/CfgMagazines.hpp
@ -2,11 +2,31 @@
 class CfgMagazines {
    class CA_Magazine;
    class B_IR_Grenade: CA_Magazine {
-        ACE_Attachable = 1;
+        ACE_Attachable = "B_IRStrobe";
+    };
+
+    class O_IR_Grenade: B_IR_Grenade {
+        ACE_Attachable = "O_IRStrobe";
+    };
+
+    class I_IR_Grenade: B_IR_Grenade {
+        ACE_Attachable = "I_IRStrobe";
    };

    class SmokeShell;
    class Chemlight_green: SmokeShell {
-        ACE_Attachable = 1;
+        ACE_Attachable = "Chemlight_green";
+    };
+
+    class Chemlight_blue: Chemlight_green {
+        ACE_Attachable = "Chemlight_blue";
+    };
+
+    class Chemlight_red: Chemlight_green {
+        ACE_Attachable = "Chemlight_red";
+    };
+
+    class Chemlight_yellow: Chemlight_green {
+        ACE_Attachable = "Chemlight_yellow";
    };
 };
--- a/addons/attach/CfgWeapons.hpp
+++ b/addons/attach/CfgWeapons.hpp
@ -4,7 +4,7 @@ class CfgWeapons {
    class InventoryItem_Base_F;

    class ACE_IR_Strobe_Item: ACE_ItemCore {
-        ACE_attachable = 1;
+        ACE_attachable = "ACE_IR_Strobe_Effect";
        author = "$STR_ACE_Common_ACETeam";
        scope = 2;
        displayName = "$STR_ACE_IrStrobe_Name";
--- a/addons/attach/functions/fnc_attach.sqf
+++ b/addons/attach/functions/fnc_attach.sqf
@ -25,35 +25,19 @@ _itemClassname = [_args, 0, ""] call CBA_fnc_defaultParam;
 //Sanity Check (_unit has item in inventory, not over attach limit)
 if ((_itemClassname == "") || {!(_this call FUNC(canAttach))}) exitWith {ERROR("Tried to attach, but check failed");};

-_itemVehClass = "";
-_onAtachText = "";
 _selfAttachPosition = [_unit, [-0.05, 0, 0.12], "rightshoulder"];

-switch (true) do {
-case (_itemClassname == "ACE_IR_Strobe_Item"): {
-        _itemVehClass = "ACE_IR_Strobe_Effect";
-        _onAtachText = localize "STR_ACE_Attach_IrStrobe_Attached";
-        //_selfAttachPosition = [_unit, [0, -0.11, 0.16], "pilot"];  //makes it attach to the head a bit better, shoulder is not good for visibility - eRazeri
-    };
-case (_itemClassname == "B_IR_Grenade"): {
-        _itemVehClass = "B_IRStrobe";
-        _onAtachText = localize "STR_ACE_Attach_IrGrenade_Attached";
-    };
-case (_itemClassname == "O_IR_Grenade"): {
-        _itemVehClass = "O_IRStrobe";
-        _onAtachText = localize "STR_ACE_Attach_IrGrenade_Attached";
-    };
-case (_itemClassname == "I_IR_Grenade"): {
-        _itemVehClass = "I_IRStrobe";
-        _onAtachText = localize "STR_ACE_Attach_IrGrenade_Attached";
-    };
-case (toLower _itemClassname in ["chemlight_blue", "chemlight_green", "chemlight_red", "chemlight_yellow"]): {
-        _itemVehClass = _itemClassname;
-        _onAtachText = localize "STR_ACE_Attach_Chemlight_Attached";
-    };
+_itemVehClass = getText (configFile >> "CfgWeapons" >> _itemClassname >> "ACE_Attachable");
+_onAtachText = getText (configFile >> "CfgWeapons" >> _itemClassname >> "displayName");
+
+if (_itemVehClass == "") then {
+    _itemVehClass = getText (configFile >> "CfgMagazines" >> _itemClassname >> "ACE_Attachable");
+    _onAtachText = getText (configFile >> "CfgMagazines" >> _itemClassname >> "displayName");
 };

-if (_itemVehClass == "") exitWith {ERROR("no _itemVehClass for Item");};
+if (_itemVehClass == "") exitWith {ERROR("no ACE_Attachable for Item");};
+
+_onAtachText = format [localize "STR_ACE_Attach_Item_Attached", _onAtachText];

 if (_unit == _attachToVehicle) then {  //Self Attachment
    _unit removeItem _itemClassname;  // Remove item
--- a/addons/attach/functions/fnc_detach.sqf
+++ b/addons/attach/functions/fnc_detach.sqf
@ -73,14 +73,9 @@ _attachToVehicle setVariable [QGVAR(Objects), _attachedObjects, true];
 _attachToVehicle setVariable [QGVAR(ItemNames), _attachedItems, true];

 // Display message
-switch (true) do {
-case (_itemName == "ACE_IR_Strobe_Item") : {
-        [localize "STR_ACE_Attach_IrStrobe_Detached"] call EFUNC(common,displayTextStructured);
-    };
-case (toLower _itemName in ["b_ir_grenade", "o_ir_grenade", "i_ir_grenade"]) : {
-        [localize "STR_ACE_Attach_IrGrenade_Detached"] call EFUNC(common,displayTextStructured);
-    };
-case (toLower _itemName in ["chemlight_blue", "chemlight_green", "chemlight_red", "chemlight_yellow"]) : {
-        [localize "STR_ACE_Attach_Chemlight_Detached"] call EFUNC(common,displayTextStructured);
-    };
+_itemDisplayName = getText (configFile >> "CfgWeapons" >> _itemName >> "displayName");
+if (_itemDisplayName == "") then {
+    _itemDisplayName = getText (configFile >> "CfgMagazines" >> _itemName >> "displayName");
 };
+
+[format [localize "STR_ACE_Attach_Item_Detached", _itemDisplayName]] call EFUNC(common,displayTextStructured);
--- a/addons/attach/functions/fnc_getChildrenAttachActions.sqf
+++ b/addons/attach/functions/fnc_getChildrenAttachActions.sqf
@ -26,7 +26,7 @@ _actions = [];
    if !(_x in _listed) then {
        _listed pushBack _x;
        _item = ConfigFile >> "CfgMagazines" >> _x;
-        if (getNumber (_item >> "ACE_Attachable") == 1) then {
+        if (getText (_item >> "ACE_Attachable") != "") then {
            _displayName = getText(_item >> "displayName");
            _picture = getText(_item >> "picture");
            _action = [_x, _displayName, _picture, {_this call FUNC(attach)}, {_this call FUNC(canAttach)}, {}, [_x]] call EFUNC(interact_menu,createAction);
@ -39,7 +39,7 @@ _actions = [];
    if !(_x in _listed) then {
        _listed pushBack _x;
        _item = ConfigFile >> "CfgWeapons" >> _x;
-        if (getNumber (_item >> "ACE_Attachable") == 1) then {
+        if (getText (_item >> "ACE_Attachable") != "") then {
            _displayName = getText(_item >> "displayName");
            _picture = getText(_item >> "picture");
            _action = [_x, _displayName, _picture, {_this call FUNC(attach)}, {_this call FUNC(canAttach)}, {}, [_x]] call EFUNC(interact_menu,createAction);
--- a/Show More
+++ b/Show More
				`@ -0,0 +1 @@`
				`#include "\z\ace\addons\advanced_ballistics\script_component.hpp"`
				`@ -0,0 +1 @@`
				`#include "\z\ace\addons\atragmx\script_component.hpp"`