mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
59af3e1f6d
* medical_treatment * advanced_throwing * common, csw * Update fnc_replaceRegisteredItems.sqf * Sanitised numerous components * Update XEH_postInit.sqf * Update XEH_postInit.sqf * FUNC -> LINKFUNC * Changed tagging hashmap * Reverted some changes * Reverted some changes * Update XEH_clientInit.sqf * Tweaks and fixes * Fix number replacements * Minor cleanup * Update fnc_getMagazineName.sqf * Update fnc_getMagazineName.sqf * Minor improvement * Made factions case-sensitive and added `toLowerANSI` to be safe * Update fnc_getDetectedObject.sqf * Update addons/common/functions/fnc_actionKeysNamesConverted.sqf Co-authored-by: Grim <69561145+LinkIsGrim@users.noreply.github.com> * Throw error if item doesn't exist --------- Co-authored-by: Salluci <69561145+Salluci@users.noreply.github.com> Co-authored-by: johnb432 <58661205+johnb432@users.noreply.github.com>
40 lines
1.2 KiB
Plaintext
40 lines
1.2 KiB
Plaintext
#include "..\script_component.hpp"
|
|
/*
|
|
* Author: Glowbal, commy2
|
|
* Handles the wounds received event by triggering any needed blood creation.
|
|
*
|
|
* Arguments:
|
|
* 0: Unit <OBJECT>
|
|
* 1: Damage done to each body part <ARRAY>
|
|
* 2: Shooter <OBJECT>
|
|
* 3: Ammo classname or damage type <STRING>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [player, "Body", 0.5, badGuy] call ace_medical_blood_fnc_handleWoundReceived
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_unit", "_allDamages", "_shooter", "_damageType"];
|
|
(_allDamages select 0) params ["_damage"];
|
|
|
|
// Don't bleed if damage type does not cause bleeding
|
|
if (_damageType in (uiNamespace getVariable QGVAR(noBloodDamageTypes))) exitWith {};
|
|
|
|
// Don't bleed when players only and a non-player unit is wounded
|
|
if (GVAR(enabledFor) == BLOOD_ONLY_PLAYERS && {!isPlayer _unit && {_unit != ACE_player}}) exitWith {};
|
|
|
|
// Don't bleed on the ground if in a vehicle
|
|
if (!isNull objectParent _unit && {!(vehicle _unit isKindOf "StaticWeapon")}) exitWith {};
|
|
|
|
private _bulletDir = if (isNull _shooter) then {
|
|
random 360 // Cannot calculate the direction properly, pick a random direction
|
|
} else {
|
|
_shooter getDir _unit // Calculate the bullet direction
|
|
};
|
|
|
|
[QGVAR(spurt), [_unit, _bulletDir, _damage min 1]] call CBA_fnc_serverEvent;
|