ACE3/addons/medical_treatment/functions/fnc_tourniquetLocal.sqf

#include "..\script_component.hpp"
/*
 * Author: Glowbal
 * Local callback for applying a tourniquet to a patient.
 *
 * Arguments:
 * 0: Patient <OBJECT>
 * 1: Body Part <STRING>
 *
 * Return Value:
 * None
 *
 * Example:
 * [player, "LeftLeg"] call ace_medical_treatment_fnc_tourniquetLocal
 *
 * Public: No
 */

params ["_patient", "_bodyPart"];
TRACE_2("tourniquetLocal",_patient,_bodyPart);

private _partIndex = ALL_BODY_PARTS find tolowerANSI _bodyPart;

private _tourniquets = GET_TOURNIQUETS(_patient);
_tourniquets set [_partIndex, CBA_missionTime];
_patient setVariable [VAR_TOURNIQUET, _tourniquets, true];

[_patient] call EFUNC(medical_status,updateWoundBloodLoss);

private _nearPlayers = (_patient nearEntities ["CAManBase", 6]) select {_x call EFUNC(common,isPlayer)};
TRACE_1("clearConditionCaches: tourniquetLocal",_nearPlayers);
[QEGVAR(interact_menu,clearConditionCaches), [], _nearPlayers] call CBA_fnc_targetEvent;