mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
0400a857e6
* Fix vanilla throwing block failing after priming, simplify muzzle ammo (can only be 1 or 0, 1 doesn't influence anything if no appliccable throwable in inventory) * Disable select grenade keys when advanced throwing is active * Fix #4375 - select next grenade cycles between first 2 grenade muzzles due to setAmmo
61 lines
1.9 KiB
Plaintext
61 lines
1.9 KiB
Plaintext
/*
|
|
* Author: Dslyecxi, Jonpas
|
|
* Primes the throwable, creates global throwable vehicle and throws Fired XEH.
|
|
*
|
|
* Arguments:
|
|
* 0: Unit <OBJECT>
|
|
* 1: Show Hint <BOOL> (default: false)
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [unit] call ace_advanced_throwing_fnc_prime
|
|
*
|
|
* Public: No
|
|
*/
|
|
#include "script_component.hpp"
|
|
|
|
params ["_unit", ["_showHint", false]];
|
|
TRACE_2("params",_unit,_showHint);
|
|
|
|
_unit setVariable [QGVAR(primed), true];
|
|
|
|
// Remove item before cooking to prevent weaponselect showing more throwables than there actually are in inventory
|
|
private _throwableMag = (currentThrowable _unit) select 0;
|
|
_unit removeItem _throwableMag;
|
|
|
|
private _throwableType = getText (configFile >> "CfgMagazines" >> _throwableMag >> "ammo");
|
|
private _muzzle = _unit getVariable [QGVAR(activeMuzzle), ""];
|
|
|
|
// Set muzzle ammo to 0 to block vanilla throwing (can only be 0 or 1), removeItem above resets it
|
|
_unit setAmmo [_muzzle, 0];
|
|
|
|
// Create actual throwable globally
|
|
private _activeThrowableOld = _unit getVariable [QGVAR(activeThrowable), objNull];
|
|
private _activeThrowable = createVehicle [_throwableType, _activeThrowableOld, [], 0, "CAN_COLLIDE"];
|
|
_unit setVariable [QGVAR(activeThrowable), _activeThrowable];
|
|
deleteVehicle _activeThrowableOld;
|
|
|
|
// Throw Fired XEH
|
|
[QGVAR(throwFiredXEH), [
|
|
_unit, // unit
|
|
"Throw", // weapon
|
|
_muzzle, // muzzle
|
|
_muzzle, // mode
|
|
_throwableType, // ammo
|
|
_throwableMag, // magazine
|
|
_activeThrowable // projectile
|
|
]] call CBA_fnc_globalEvent;
|
|
|
|
if (_showHint) then {
|
|
// Show primed hint
|
|
private _displayNameShort = getText (configFile >> "CfgMagazines" >> _throwableMag >> "displayNameShort");
|
|
private _picture = getText (configFile >> "CfgMagazines" >> _throwableMag >> "picture");
|
|
|
|
[[_displayNameShort, localize LSTRING(Primed)] joinString " ", _picture] call EFUNC(common,displayTextPicture);
|
|
|
|
// Change controls hint for RMB
|
|
call FUNC(updateControlsHint);
|
|
};
|