mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
44050df98b
* Modernize and cleanup medical_treatment * One line for each old public function * Fix litterCleanupDelay name * Improve adjustment calcs / wound blood loss / medications fix func descriptions Calc wound blood loss on events reorder includes so scritpmacroMed has global effect trivial optimization for getCardiacOutput Fix var Fix wounds not reopening (nil _category) Fix surgical kit inherting canBandage conditional debug hitpoints Update ACE_Medical_Treatment_Actions.hpp Use woundBleeding for IS_BLEEDING macro rework medication vars comments Reset var in init / fullHeal Update addons/medical_treatment/functions/fnc_onMedicationUsage.sqf Co-Authored-By: PabstMirror <pabstmirror@gmail.com> * Change wound data array Drop unique id and merge classId and category * Splinting and treatment and gui * Add arm fractures and aim effects * localizations and event * fix * fix merge for renamed files * Fixes and code review changes * Move medical logs clearing to treatment * More cleanup work * cleanup * Apply suggestions from code review Co-Authored-By: PabstMirror <pabstmirror@gmail.com> * formating, rename bone images * Fix args for setDead call in actionPlaceInBodyBag * Apply suggestions from code review Co-Authored-By: PabstMirror <pabstmirror@gmail.com> * disable calls to extension * Update fnc_onMedicationUsage.sqf * Medical - Skip unneeded setVars on initUnit (#6949) * Medical - Transfer state machine state on locality (#6950) * Medical - Transfer state machine state on locality * Fix feedback isUnconscious var * Exclude AI * Make UAV excludes consistant, formating * Update fnc_treatmentFullHealLocal.sqf * reset fractures on respawn * Fix merge * Add PAK time coefficient setting * Fix medication * Add ace_medical_replacementItems config array * checkItems performance improvement * Treatment - cap max animation speed (#6995) * Treatment - cap max animation speed and add lock to prevent AF from reseting anim * Update fnc_getBandageTime.sqf * Use local version of setAnimSpeedCoef * Revert "Use local version of setAnimSpeedCoef" This reverts commit 36c22a90473fd0670ab97f3a373e4ae08493ff52. * Move replacementItems compiling to preInit * Improve replacementItems compiling * Cleanup splint functions, use macros for fractures * Rename splintCondition to canSplint * Add cprCreatesPulse setting * Cleanup remaining functions * Capitalize stringtable entry names * getStitchTime function and fix treatment locations * Update addons/medical_treatment/functions/fnc_getHealTime.sqf Co-Authored-By: SilentSpike <silentspike100+Github@gmail.com>
99 lines
3.3 KiB
Plaintext
99 lines
3.3 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: BaerMitUmlaut
|
|
* Handles any audible, visual and physical effects of fatigue.
|
|
*
|
|
* Arguments:
|
|
* 0: Unit <OBJECT>
|
|
* 1: Fatigue <NUMBER>
|
|
* 2: Speed <NUMBER>
|
|
* 3: Overexhausted <BOOL>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [_player, 0.5, 3.3, true] call ace_advanced_fatigue_fnc_handleEffects
|
|
*
|
|
* Public: No
|
|
*/
|
|
params ["_unit", "_fatigue", "_speed", "_overexhausted"];
|
|
|
|
#ifdef DEBUG_MODE_FULL
|
|
systemChat str _fatigue;
|
|
systemChat str vectorMagnitude velocity _unit;
|
|
#endif
|
|
|
|
// - Audible effects ----------------------------------------------------------
|
|
GVAR(lastBreath) = GVAR(lastBreath) + 1;
|
|
if (_fatigue > 0.4 && {GVAR(lastBreath) > (_fatigue * -10 + 9)} && {!underwater _unit}) then {
|
|
switch (true) do {
|
|
case (_fatigue < 0.6): {
|
|
playSound (QGVAR(breathLow) + str(floor random 6));
|
|
};
|
|
case (_fatigue < 0.85): {
|
|
playSound (QGVAR(breathMid) + str(floor random 6));
|
|
};
|
|
default {
|
|
playSound (QGVAR(breathMax) + str(floor random 6));
|
|
};
|
|
};
|
|
GVAR(lastBreath) = 0;
|
|
};
|
|
|
|
// - Visual effects -----------------------------------------------------------
|
|
GVAR(ppeBlackoutLast) = GVAR(ppeBlackoutLast) + 1;
|
|
if (GVAR(ppeBlackoutLast) == 1) then {
|
|
GVAR(ppeBlackout) ppEffectAdjust [1,1,0,[0,0,0,1],[0,0,0,0],[1,1,1,1],[10,10,0,0,0,0.1,0.5]];
|
|
GVAR(ppeBlackout) ppEffectCommit 1;
|
|
} else {
|
|
if (_fatigue > 0.85) then {
|
|
if (GVAR(ppeBlackoutLast) > (100 - _fatigue * 100) / 3) then {
|
|
GVAR(ppeBlackout) ppEffectAdjust [1,1,0,[0,0,0,1],[0,0,0,0],[1,1,1,1],[2,2,0,0,0,0.1,0.5]];
|
|
GVAR(ppeBlackout) ppEffectCommit 1;
|
|
GVAR(ppeBlackoutLast) = 0;
|
|
};
|
|
};
|
|
};
|
|
|
|
// - Physical effects ---------------------------------------------------------
|
|
if (GVAR(isSwimming)) exitWith {
|
|
if (GVAR(setAnimExclusions) isEqualTo []) then {
|
|
_unit setAnimSpeedCoef linearConversion [0.7, 0.9, _fatigue, 1, 0.5, true];
|
|
};
|
|
if ((isSprintAllowed _unit) && {_fatigue > 0.7}) then {
|
|
[_unit, "blockSprint", QUOTE(ADDON), true] call EFUNC(common,statusEffect_set);
|
|
} else {
|
|
if ((!isSprintAllowed _unit) && {_fatigue < 0.7}) then {
|
|
[_unit, "blockSprint", QUOTE(ADDON), false] call EFUNC(common,statusEffect_set);
|
|
};
|
|
};
|
|
};
|
|
if ((getAnimSpeedCoef _unit) != 1) then {
|
|
if (GVAR(setAnimExclusions) isEqualTo []) then {
|
|
TRACE_1("reset",getAnimSpeedCoef _unit);
|
|
_unit setAnimSpeedCoef 1;
|
|
};
|
|
};
|
|
|
|
if (_overexhausted) then {
|
|
[_unit, "forceWalk", QUOTE(ADDON), true] call EFUNC(common,statusEffect_set);
|
|
} else {
|
|
if (isForcedWalk _unit && {_fatigue < 0.7}) then {
|
|
[_unit, "forceWalk", QUOTE(ADDON), false] call EFUNC(common,statusEffect_set);
|
|
} else {
|
|
if ((isSprintAllowed _unit) && {_fatigue > 0.7}) then {
|
|
[_unit, "blockSprint", QUOTE(ADDON), true] call EFUNC(common,statusEffect_set);
|
|
} else {
|
|
if ((!isSprintAllowed _unit) && {_fatigue < 0.6}) then {
|
|
[_unit, "blockSprint", QUOTE(ADDON), false] call EFUNC(common,statusEffect_set);
|
|
};
|
|
};
|
|
};
|
|
};
|
|
|
|
_unit setVariable [QGVAR(aimFatigue), _fatigue];
|
|
|
|
private _aimCoef = [missionNamespace, "ACE_setCustomAimCoef", "max"] call EFUNC(common,arithmeticGetResult);
|
|
_unit setCustomAimCoef _aimCoef;
|