mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
b489750d5b
* Optimizations with private, params, and isEqualType * Fixed tab being used instead of space * Fixed tabs inserted by notepad++ * More usage of new private syntax and params - changed a few checks for an array being empty to `_arr isEqualTo []` rather than `count _arr == 0` - added more uses of `private` on the same line as the variable is declared - added more uses of params to assign variables passed as parameters - removed unnecessary parentheses - removed several unnecessary variable declarations with private array syntax * clean up and formatting
49 lines
1.5 KiB
Plaintext
49 lines
1.5 KiB
Plaintext
/*
|
|
* Author: Bohemia Interactive
|
|
* Module function for spawning mines
|
|
* Edited to remove forced map markers and mines being revealed to players
|
|
*
|
|
* Arguments:
|
|
* 0: The module logic <LOGIC>
|
|
* 1: units <ARRAY>
|
|
* 2: activated <BOOL>
|
|
*
|
|
* Return Value:
|
|
* nil
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
#include "script_component.hpp"
|
|
|
|
params ["_logic", "_units", "_activated"];
|
|
|
|
if (_activated) then {
|
|
_explosive = gettext (configFile >> "CfgVehicles" >> typeOf _logic >> "explosive");
|
|
if (_explosive != "") then {
|
|
_explosive = createvehicle [_explosive,position _logic,[],0,"none"];
|
|
_explosive attachto [_logic];
|
|
|
|
// Added by ace_zeus to control if mines are revealed
|
|
if (GVAR(revealMines) > 0) then {
|
|
//--- Reveal the mine to curator's side
|
|
{
|
|
_side = (getassignedcuratorunit _x) call bis_fnc_objectSide;
|
|
_side revealmine _explosive;
|
|
} forEach (objectcurators _logic);
|
|
|
|
if (GVAR(revealMines) > 1) then {
|
|
//--- Mark minefields in the map
|
|
[] spawn bis_fnc_drawMinefields;
|
|
};
|
|
};
|
|
|
|
//--- Show hint to curator who placed the object
|
|
[[["Curator","PlaceMines"],nil,nil,nil,nil,nil,nil,true],"bis_fnc_advHint",_logic] call bis_fnc_mp;
|
|
|
|
waitUntil {sleep 0.1; isnull _explosive || isnull _logic || !alive _logic};
|
|
if (isnull _logic) then {deletevehicle _explosive;} else {_explosive setdamage 1;};
|
|
deletevehicle _logic;
|
|
};
|
|
};
|