mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
49 lines
1.5 KiB
Plaintext
49 lines
1.5 KiB
Plaintext
/*
|
|
* Author: Glowbal
|
|
* Calculates the blood volume change and decreases the IVs given to the unit.
|
|
*
|
|
* Arguments:
|
|
* 0: The Unit <OBJECT>
|
|
* 1: Time since last update <NUMBER>
|
|
* 2: Global Sync Values (bloodbags) <BOOL>
|
|
*
|
|
* ReturnValue:
|
|
* Blood volume change (liters per second) <NUMBER>
|
|
*
|
|
* Public: No
|
|
*/
|
|
#include "script_component.hpp"
|
|
|
|
params ["_unit", "_deltaT", "_syncValues"];
|
|
|
|
private _bloodVolume = _unit getVariable [QGVAR(bloodVolume), DEFAULT_BLOOD_VOLUME];
|
|
private _bloodVolumeChange = -_deltaT * (_unit call FUNC(getBloodLoss));
|
|
|
|
if (!isNil {_unit getVariable QGVAR(ivBags)}) then {
|
|
private _bloodBags = _unit getVariable [QGVAR(ivBags), []];
|
|
|
|
_bloodBags = _bloodBags apply {
|
|
_x params ["_bagVolumeRemaining"];
|
|
|
|
private _bagChange = (_deltaT * GVAR(ivFlowRate) * IV_CHANGE_PER_SECOND) min _bagVolumeRemaining; // absolute value of the change in miliLiters
|
|
_bagVolumeRemaining = _bagVolumeRemaining - _bagChange;
|
|
_bloodVolumeChange = _bloodVolumeChange + (_bagChange / 1000);
|
|
|
|
if (_bagVolumeRemaining < 0.01) then {
|
|
[]
|
|
} else {
|
|
[_bagVolumeRemaining]
|
|
};
|
|
};
|
|
|
|
_bloodBags = _bloodBags - [[]]; // remove empty bags
|
|
|
|
if (_bloodBags isEqualTo []) then {
|
|
_unit setVariable [QGVAR(ivBags), nil, true]; // no bags left - clear variable (always globaly sync this)
|
|
} else {
|
|
_unit setVariable [QGVAR(ivBags), _bloodBags, _syncValues];
|
|
};
|
|
};
|
|
|
|
_bloodVolumeChange
|