mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
0acbde1489
* Copy the array properly when using preStart cache in openBox * Fix add and removeVirtualItems erroring out when passing false as arg * Disable face, voice, and insignia tabs in 3DEN * Move grenadeList and putList outside of foreach in scanConfig * Fix grenadeList and putList indentation * Change the camera handling in onArsenalClose Fixes the camera not being focused on the player after using ACE Arsenal on an other unit outside of zeus / 3DEN. Remove the code that moved the curatorCam near the edited unit after ACE Arsenal is closed. * Fix message control overflowing, move width defines to defines.hpp * Add ability to exit arsenal and not apply a loadout in 3DEN * Add ACE3 logo to common, fix config pathing to a non existing file
54 lines
1.5 KiB
Plaintext
54 lines
1.5 KiB
Plaintext
/*
|
|
* Author: Alganthe
|
|
* Open arsenal.
|
|
*
|
|
* Arguments:
|
|
* 0: Box <OBJECT>
|
|
* 1: Unit to open the arsenal on <OBJECT>
|
|
* 2: Ignore virtual items and fill arsenal <BOOL>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [_box, player] call ace_arsenal_fnc_openBox
|
|
*
|
|
* Public: Yes
|
|
*/
|
|
#include "script_component.hpp"
|
|
|
|
params [["_object", objNull, [objNull]], ["_center", objNull, [objNull]], ["_mode", false, [false]]];
|
|
|
|
if (
|
|
isNull _object ||
|
|
{isNull _center} ||
|
|
{!(_center isKindOf "Man")} ||
|
|
{!(isNull objectParent _center) && {!is3DEN}}
|
|
) exitWith {};
|
|
|
|
if (isNil {_object getVariable [QGVAR(virtualItems), nil]} && {!_mode}) exitWith {
|
|
[localize LSTRING(noVirtualItems), false, 5, 1] call EFUNC(common,displayText);
|
|
};
|
|
|
|
if (canSuspend) exitWith {
|
|
[{_this call FUNC(openBox)}, _this] call CBA_fnc_directCall;
|
|
};
|
|
|
|
private _displayToUse = [findDisplay 46, findDIsplay 312] select (!isNull findDisplay 312);
|
|
_displayToUse = [_displayToUse, findDisplay 313] select (is3DEN);
|
|
|
|
if (isNil "_displayToUse" || {!isnil QGVAR(camera)}) exitWith {
|
|
[localize LSTRING(CantOpenDisplay), false, 5, 1] call EFUNC(common,displayText);
|
|
};
|
|
|
|
if (_mode) then {
|
|
GVAR(virtualItems) = +(uiNamespace getVariable QGVAR(configItems));
|
|
} else {
|
|
GVAR(virtualItems) = +(_object getVariable [QGVAR(virtualItems), [
|
|
[[], [], []], [[], [], [], []], [], [], [], [], [], [], [], [], [], [], [], [], [], [], [], []
|
|
]]);
|
|
};
|
|
|
|
GVAR(center) = _center;
|
|
_displayToUse createDisplay QGVAR(display);
|