mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
51 lines
1.6 KiB
Plaintext
51 lines
1.6 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: Bohemia Interactive
|
|
* Module function for spawning mines
|
|
* Edited to remove forced map markers and mines being revealed to players
|
|
*
|
|
* Arguments:
|
|
* 0: The module logic <LOGIC>
|
|
* 1: units <ARRAY>
|
|
* 2: activated <BOOL>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [LOGIC, [bob, kevin], true] call ace_zeus_fnc_bi_moduleMine
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_logic", "_units", "_activated"];
|
|
|
|
if (_activated) then {
|
|
_explosive = gettext (configfile >> "cfgvehicles" >> typeof _logic >> "explosive");
|
|
if (_explosive != "") then {
|
|
_explosive = createvehicle [_explosive,position _logic,[],0,"none"];
|
|
_explosive attachto [_logic];
|
|
|
|
// Added by ace_zeus to control if mines are revealed
|
|
if (GVAR(revealMines) > 0) then {
|
|
//--- Reveal the mine to curator's side
|
|
{
|
|
_side = (getassignedcuratorunit _x) call bis_fnc_objectSide;
|
|
_side revealmine _explosive;
|
|
} forEach (objectcurators _logic);
|
|
|
|
if (GVAR(revealMines) > 1) then {
|
|
//--- Mark minefields in the map
|
|
[] spawn bis_fnc_drawMinefields;
|
|
};
|
|
};
|
|
|
|
//--- Show hint to curator who placed the object
|
|
[[["Curator","PlaceMines"],nil,nil,nil,nil,nil,nil,true],"bis_fnc_advHint",_logic] call bis_fnc_mp;
|
|
|
|
waituntil {sleep 0.1; isnull _explosive || isnull _logic || !alive _logic};
|
|
if (isnull _logic) then {deletevehicle _explosive;} else {_explosive setdamage 1;};
|
|
deletevehicle _logic;
|
|
};
|
|
};
|