mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
45 lines
1.0 KiB
Plaintext
45 lines
1.0 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: SilentSpike
|
|
* Function used to select the camera vision mode
|
|
*
|
|
* Arguments:
|
|
* 0: New vision mode <NUMBER>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [-1] call ace_spectator_fnc_cam_setVisionMode
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_newVision"];
|
|
|
|
private _oldVision = GVAR(camVision);
|
|
private _visions = GVAR(availableVisions);
|
|
|
|
// If new vision isn't available then keep current (unless current also isn't)
|
|
if !(_newVision in _visions) then {
|
|
_newVision = _visions select ((_visions find _oldVision) max 0);
|
|
};
|
|
|
|
// Vision mode does not apply to fps view
|
|
if (GVAR(camMode) != MODE_FPS) then {
|
|
// 0+ are all thermal vision types
|
|
if (_newVision < 0) then {
|
|
false setCamUseTi 0;
|
|
camUseNVG (_newVision >= VISION_NVG);
|
|
} else {
|
|
true setCamUseTi _newVision;
|
|
};
|
|
|
|
// Give user feedback that vision mode changed
|
|
if (_newVision != _oldVision) then {
|
|
playSound "RscDisplayCurator_visionMode";
|
|
|
|
GVAR(camVision) = _newVision;
|
|
};
|
|
};
|