mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
53 lines
1.4 KiB
Plaintext
53 lines
1.4 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: jaynus
|
|
* Receives either requests for synchronization from clients, or the synchronization data from the server.
|
|
*
|
|
* Arguments [Client]:
|
|
* 0: eventName <STRING>
|
|
* 1: eventLog <ARRAY>
|
|
*
|
|
* Arguments [Server]:
|
|
* 0: eventName <STRING>
|
|
* 1: client <OBJECT>
|
|
*
|
|
* Return Value:
|
|
* Event is successed <BOOL>
|
|
*
|
|
* Example:
|
|
* ["name", [LOG]] call ace_common_fnc__handleRequestSyncedEvent //Client
|
|
* ["name", bob] call ace_common_fnc__handleRequestSyncedEvent//Server
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
//SEH_s
|
|
if (isServer) then {
|
|
// Find the event name, and shovel out the events to the client
|
|
params ["_eventName", "_client"];
|
|
|
|
if !([GVAR(syncedEvents), _eventName] call CBA_fnc_hashHasKey) exitWith {
|
|
ERROR_1("Request for synced event - key [%1] not found.", _eventName);
|
|
false
|
|
};
|
|
|
|
private _eventEntry = [GVAR(syncedEvents), _eventName] call CBA_fnc_hashGet;
|
|
_eventEntry params ["", "_eventLog"];
|
|
|
|
["ACEs", [_eventName, _eventLog], _client] call CBA_fnc_targetEvent;
|
|
} else {
|
|
params ["_eventName", "_eventLog"];
|
|
|
|
// This is the client handling the response from the server
|
|
// Start running the events
|
|
{
|
|
_x params ["", "_eventArgs","_ttl"];
|
|
[_eventName, _eventArgs, _ttl] call FUNC(_handleSyncedEvent);
|
|
false
|
|
} count _eventLog;
|
|
|
|
INFO_1("[%1] synchronized",_eventName);
|
|
};
|
|
|
|
true
|