mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
76 lines
3.0 KiB
Plaintext
76 lines
3.0 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: PabstMirror
|
|
* Cycles fire mode for any missileGuidance enabled ammo that has multiple attack profiles
|
|
*
|
|
* Arguments:
|
|
* None
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [] call ace_missileguidance_fnc_cycleAttackProfileKeyDown
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
TRACE_1("cycle fire mode",_this);
|
|
|
|
if (!alive ACE_player) exitWith {};
|
|
if (!([ACE_player, objNull, ["isNotInside"]] call EFUNC(common,canInteractWith))) exitWith {};
|
|
|
|
|
|
private _currentShooter = objNull;
|
|
private _currentMagazine = "";
|
|
if (isNull (ACE_controlledUAV param [0, objNull])) then {
|
|
if (((vehicle ACE_player) == ACE_player) || {ACE_player call CBA_fnc_canUseWeapon}) then {
|
|
_currentShooter = ACE_player;
|
|
_currentMagazine = currentMagazine ACE_player;
|
|
} else {
|
|
_currentShooter = vehicle ACE_player;
|
|
private _turretPath = if (ACE_player == (driver _currentShooter)) then {[-1]} else {ACE_player call CBA_fnc_turretPath};
|
|
_currentMagazine = _currentShooter currentMagazineTurret _turretPath;
|
|
};
|
|
} else {
|
|
_currentShooter = ACE_controlledUAV select 0;
|
|
private _turretPath = ACE_controlledUAV select 2;
|
|
_currentMagazine = _currentShooter currentMagazineTurret _turretPath;
|
|
};
|
|
|
|
if (_currentMagazine == "") exitWith {TRACE_1("no magazine",_currentMagazine)};
|
|
|
|
private _ammo = getText (configFile >> "CfgMagazines" >> _currentMagazine >> "ammo");
|
|
|
|
TRACE_3("",_currentShooter,_currentMagazine,_ammo);
|
|
|
|
// Bail if guidance is disabled for this ammo
|
|
if ((getNumber (configFile >> "CfgAmmo" >> _ammo >> QUOTE(ADDON) >> "enabled")) != 1) exitWith {TRACE_1("not enabled",_ammo)};
|
|
|
|
// Verify ammo has explicity added guidance config (ignore inheritances)
|
|
private _configs = configProperties [(configFile >> "CfgAmmo" >> _ammo), QUOTE(configName _x == QUOTE(QUOTE(ADDON))), false];
|
|
if ((count _configs) < 1) exitWith {TRACE_2("not explicity enabled",_ammo,_configs)};
|
|
|
|
private _attackProfiles = getArray (configFile >> "CfgAmmo" >> _ammo >> QUOTE(ADDON) >> "attackProfiles");
|
|
if ((count _attackProfiles) <= 1) exitWith {TRACE_1("no choices for attack profile",_attackProfiles)};
|
|
|
|
private _currentFireMode = _currentShooter getVariable [QGVAR(attackProfile), "#undefined"];
|
|
|
|
// Just like onFired, this is case sensitive!
|
|
private _index = _attackProfiles find _currentFireMode;
|
|
if (_index == -1) then {
|
|
_index = _attackProfiles find (getText (configFile >> "CfgAmmo" >> _ammo >> QUOTE(ADDON) >> "defaultAttackProfile"));
|
|
};
|
|
_index = (_index + 1) % (count _attackProfiles);
|
|
private _nextFireMode = _attackProfiles select _index;
|
|
TRACE_4("",_currentFireMode,_nextFireMode,_index,_attackProfiles);
|
|
|
|
_currentShooter setVariable [QGVAR(attackProfile), _nextFireMode, false];
|
|
|
|
playSound "ACE_Sound_Click";
|
|
|
|
if ((getNumber (configFile >> "CfgAmmo" >> _ammo >> QUOTE(ADDON) >> "showHintOnCycle")) == 1) then {
|
|
private _localizedName = getText (configFile >> QGVAR(AttackProfiles) >> _nextFireMode >> "name");
|
|
[_localizedName] call EFUNC(common,displayTextStructured);
|
|
};
|