mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
52 lines
1.7 KiB
Plaintext
52 lines
1.7 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: PabstMirror
|
|
* Handles the keypad entries from the "Mark" Application
|
|
*
|
|
* Arguments:
|
|
* 0: String version of Keypad entry ["ok","del","1",...] <STRING>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* ["ok"] call ace_microdagr_fnc_appMarkKeypadEntry
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_keypadButton"];
|
|
|
|
disableSerialization;
|
|
private _display = uiNamespace getVariable [[QGVAR(RscTitleDisplay), QGVAR(DialogDisplay)] select (GVAR(currentShowMode) == DISPLAY_MODE_DIALOG), displayNull];
|
|
|
|
if (isNull _display) exitWith {ERROR("No Display");};
|
|
|
|
if (GVAR(currentApplicationPage) != APP_MODE_MARK) exitWith {};
|
|
|
|
private _editText = ctrlText (_display displayCtrl IDC_MODEMARK_CORDSEDIT);
|
|
|
|
switch (_keypadButton) do {
|
|
case ("ok"): {
|
|
if ((count GVAR(newWaypointPosition)) == 0) then {
|
|
private _actualPos = [_editText, true] call EFUNC(common,getMapPosFromGrid);
|
|
_actualPos set [2, (getTerrainHeightASL _actualPos)];
|
|
GVAR(newWaypointPosition) = _actualPos;
|
|
[APP_MODE_MARK] call FUNC(saveCurrentAndSetNewMode);
|
|
} else {
|
|
[_editText, GVAR(newWaypointPosition)] call FUNC(deviceAddWaypoint);
|
|
[APP_MODE_WAYPOINTS] call FUNC(saveCurrentAndSetNewMode);
|
|
};
|
|
};
|
|
case ("del"): {
|
|
_editText = _editText select [0, (((count _editText) - 1) max 0)];
|
|
(_display displayCtrl IDC_MODEMARK_CORDSEDIT) ctrlSetText _editText;
|
|
ctrlSetFocus (_display displayCtrl IDC_MODEMARK_CORDSEDIT);
|
|
};
|
|
default {
|
|
_editText = _editText + _keypadButton;
|
|
(_display displayCtrl IDC_MODEMARK_CORDSEDIT) ctrlSetText _editText;
|
|
ctrlSetFocus (_display displayCtrl IDC_MODEMARK_CORDSEDIT);
|
|
};
|
|
};
|