mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
49 lines
1.3 KiB
Plaintext
49 lines
1.3 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: Nelson Duarte, AACO, SilentSpike
|
|
* Function used to add projectiles to be drawn when a unit fires
|
|
*
|
|
* Arguments:
|
|
* Fired EH arguments
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* _unit addEventHandler ["Fired",{_this call ace_spectator_fnc_handleFired}]
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params [
|
|
"_unit",
|
|
["_weapon", "", [""]],
|
|
"", // Muzzle
|
|
"", // Mode
|
|
["_ammo", "", [""]], // Ammo
|
|
"", // Magazine
|
|
["_projectile", objNull, [objNull]]
|
|
];
|
|
|
|
// Remove the EH when spectator is no longer active or unit is removed
|
|
if (isNil QGVAR(entitiesToDraw) || {!(_unit in GVAR(entitiesToDraw))}) exitWith {
|
|
//USES_VARIABLES ["_thisEventHandler"]
|
|
_unit removeEventHandler ["Fired", _thisEventHandler];
|
|
SETVAR(_unit,GVAR(firedEH),nil);
|
|
};
|
|
|
|
// Fire time used for unit icon highlighting
|
|
_unit setVariable [QGVAR(highlightTime), time + FIRE_HIGHLIGHT_TIME];
|
|
|
|
// expensive, but any non local units might have this as null for 'global' projectiles (like grenades)
|
|
if (isNull _projectile) then {
|
|
_projectile = nearestObject [_unit, _ammo];
|
|
};
|
|
|
|
// Store projectiles / grenades for drawing
|
|
if (_weapon == "Throw") then {
|
|
[QGVAR(addToGrenadeTracking), [_projectile]] call CBA_fnc_localEvent;
|
|
} else {
|
|
[QGVAR(addToProjectileTracking), [_projectile]] call CBA_fnc_localEvent;
|
|
};
|