mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
59 lines
1.8 KiB
Plaintext
59 lines
1.8 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: 654wak654
|
|
* Loads selected pylon configuration from either config or profileNamespace.
|
|
*
|
|
* Arguments:
|
|
* None
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [] call ace_pylons_fnc_onButtonLoad
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
[false] call FUNC(onPylonMirror);
|
|
(CONTROL(ID_DIALOG) ID_CHECKBOX_MIRROR) cbSetChecked false;
|
|
|
|
private _loadoutName = ctrlText ID_EDIT_LOADOUTNAME;
|
|
private _fnc_setSelections = {
|
|
params ["_mags", "_turrets"];
|
|
|
|
{
|
|
_x params ["_combo", "_mirroredIndex", "_button"];
|
|
|
|
private _index = 0;
|
|
for "_i" from 1 to ((lbSize _combo) - 1) do {
|
|
if ((_combo lbData _i) == (_mags param [_forEachIndex, ""])) exitWith {
|
|
_index = _i;
|
|
};
|
|
};
|
|
_combo lbSetCurSel _index;
|
|
|
|
[_button, false, _turrets select _forEachIndex] call FUNC(onButtonTurret);
|
|
} forEach GVAR(comboBoxes);
|
|
};
|
|
|
|
private _pylonComponent = configFile >> "CfgVehicles" >> typeOf GVAR(currentAircraft) >> "Components" >> "TransportPylonsComponent";
|
|
private _loadoutFound = {
|
|
if (getText (_x >> "displayName") isEqualTo _loadoutName) exitWith {
|
|
// Get default turrets from config
|
|
private _turrets = ("true" configClasses (_pylonComponent >> "Pylons")) apply {getArray (_x >> "turret")};
|
|
[getArray (_x >> "attachment"), _turrets] call _fnc_setSelections;
|
|
true
|
|
};
|
|
false
|
|
} forEach ("true" configClasses (_pylonComponent >> "Presets"));
|
|
|
|
if (_loadoutFound) exitWith {};
|
|
|
|
private _aircraftLoadouts = profileNamespace getVariable [QGVAR(aircraftLoadouts), []];
|
|
{
|
|
if ((_x select 0) isEqualTo _loadoutName && {(_x select 3) isEqualTo typeOf GVAR(currentAircraft)}) exitWith {
|
|
[_x select 1, _x select 2] call _fnc_setSelections;
|
|
};
|
|
} forEach _aircraftLoadouts;
|