mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
44050df98b
* Modernize and cleanup medical_treatment
* One line for each old public function
* Fix litterCleanupDelay name
* Improve adjustment calcs / wound blood loss / medications
fix func descriptions
Calc wound blood loss on events
reorder includes so scritpmacroMed has global effect
trivial optimization for getCardiacOutput
Fix var
Fix wounds not reopening (nil _category)
Fix surgical kit inherting canBandage conditional
debug hitpoints
Update ACE_Medical_Treatment_Actions.hpp
Use woundBleeding for IS_BLEEDING macro
rework medication vars
comments
Reset var in init / fullHeal
Update addons/medical_treatment/functions/fnc_onMedicationUsage.sqf
Co-Authored-By: PabstMirror <pabstmirror@gmail.com>
* Change wound data array
Drop unique id and merge classId and category
* Splinting and treatment and gui
* Add arm fractures and aim effects
* localizations and event
* fix
* fix merge for renamed files
* Fixes and code review changes
* Move medical logs clearing to treatment
* More cleanup work
* cleanup
* Apply suggestions from code review
Co-Authored-By: PabstMirror <pabstmirror@gmail.com>
* formating, rename bone images
* Fix args for setDead call in actionPlaceInBodyBag
* Apply suggestions from code review
Co-Authored-By: PabstMirror <pabstmirror@gmail.com>
* disable calls to extension
* Update fnc_onMedicationUsage.sqf
* Medical - Skip unneeded setVars on initUnit (#6949)
* Medical - Transfer state machine state on locality (#6950)
* Medical - Transfer state machine state on locality
* Fix feedback isUnconscious var
* Exclude AI
* Make UAV excludes consistant, formating
* Update fnc_treatmentFullHealLocal.sqf
* reset fractures on respawn
* Fix merge
* Add PAK time coefficient setting
* Fix medication
* Add ace_medical_replacementItems config array
* checkItems performance improvement
* Treatment - cap max animation speed (#6995)
* Treatment - cap max animation speed
and add lock to prevent AF from reseting anim
* Update fnc_getBandageTime.sqf
* Use local version of setAnimSpeedCoef
* Revert "Use local version of setAnimSpeedCoef"
This reverts commit 36c22a9047.
* Move replacementItems compiling to preInit
* Improve replacementItems compiling
* Cleanup splint functions, use macros for fractures
* Rename splintCondition to canSplint
* Add cprCreatesPulse setting
* Cleanup remaining functions
* Capitalize stringtable entry names
* getStitchTime function and fix treatment locations
* Update addons/medical_treatment/functions/fnc_getHealTime.sqf
Co-Authored-By: SilentSpike <silentspike100+Github@gmail.com>
73 lines
2.5 KiB
Plaintext
73 lines
2.5 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: SilentSpike
|
|
* Finds the wound most effective to bandage on the given bodypart of the patient for the given bandage type.
|
|
*
|
|
* Arguments:
|
|
* 0: Patient <OBJECT>
|
|
* 1: Treatment classname <STRING>
|
|
* 2: Body part index <NUMBER>
|
|
*
|
|
* Return Value:
|
|
* [Wound, Index, Effectiveness] <ARRAY, NUMBER, NUMBER>
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_patient", "_bandage", "_partIndex"];
|
|
|
|
// Get the default effectiveness for the used bandage
|
|
private _config = configFile >> QUOTE(ADDON) >> "Bandaging";
|
|
private _effectiveness = getNumber (_config >> "effectiveness");
|
|
|
|
if (isClass (_config >> _bandage)) then {
|
|
_config = (_config >> _bandage);
|
|
|
|
if (isNumber (_config >> "effectiveness")) then {
|
|
_effectiveness = getNumber (_config >> "effectiveness");
|
|
};
|
|
};
|
|
|
|
// Iterate over open wounds to find the most effective target
|
|
private _openWounds = _patient getVariable [QEGVAR(medical,openWounds), []];
|
|
if (_openWounds isEqualTo []) exitWith { [EMPTY_WOUND, -1, -1] };
|
|
|
|
private _wound = EMPTY_WOUND;
|
|
private _woundIndex = -1;
|
|
private _effectivenessFound = -1;
|
|
|
|
{
|
|
_x params ["_classID", "_partIndexN", "_amountOf", "_bleeding", "_damage"];
|
|
|
|
// Ignore wounds on other bodyparts
|
|
if (_partIndexN == _partIndex) then {
|
|
private _woundEffectiveness = _effectiveness;
|
|
|
|
// Select the classname from the wound classname storage
|
|
private _className = EGVAR(medical_damage,woundClassNamesComplex) select _classID;
|
|
|
|
// Get the effectiveness of the bandage on this wound type
|
|
if (isClass (_config >> _className)) then {
|
|
private _woundTreatmentConfig = _config >> _className;
|
|
|
|
if (isNumber (_woundTreatmentConfig >> "effectiveness")) then {
|
|
_woundEffectiveness = getNumber (_woundTreatmentConfig >> "effectiveness");
|
|
};
|
|
} else {
|
|
// Basic medical bandage just has a base level config (same effectivenes for all wound types)
|
|
if (_bandage != "BasicBandage") then {
|
|
WARNING_2("No config for wound type [%1] config base [%2]",_className,_config);
|
|
};
|
|
};
|
|
|
|
// Track most effective found so far
|
|
if (_woundEffectiveness * _amountOf * _bleeding > _effectivenessFound * (_wound select 3) * (_wound select 4)) then {
|
|
_effectivenessFound = _woundEffectiveness;
|
|
_woundIndex = _forEachIndex;
|
|
_wound = _x;
|
|
};
|
|
};
|
|
} forEach _openWounds;
|
|
|
|
[_wound, _woundIndex, _effectivenessFound]
|