mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
49 lines
1.1 KiB
Plaintext
49 lines
1.1 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: Ir0n1E
|
|
* Put weapon into gunbag.
|
|
*
|
|
* Arguments:
|
|
* 0: Unit <OBJECT>
|
|
* 1: Target <OBJECT>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [player, target] call ace_gunbag_fnc_toGunbagCallback
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_unit", "_target"];
|
|
|
|
private _weapon = primaryWeapon _unit;
|
|
private _gunbag = backpackContainer _target;
|
|
|
|
private _state = [_unit, _weapon] call EFUNC(common,getWeaponState);
|
|
|
|
/*
|
|
* example return value _state
|
|
* [["","","optic_Aco",""],["arifle_MX_GL_ACO_F","GL_3GL_F"],["30Rnd_65x39_caseless_mag","1Rnd_HE_Grenade_shell"],[30,1]]
|
|
*/
|
|
|
|
_state params ["_items", "", "_magazines", "_ammo"];
|
|
|
|
private _mass = [_weapon, _items, _magazines] call FUNC(calculateMass);
|
|
|
|
{
|
|
_magazines set [_forEachIndex, [_x, _ammo select _forEachIndex]];
|
|
} forEach _magazines;
|
|
|
|
_unit removeWeapon _weapon;
|
|
|
|
// add virtual load
|
|
[_target, _gunbag, _mass] call EFUNC(movement,addLoadToUnitContainer);
|
|
_gunbag setVariable [QGVAR(gunbagWeapon), [_weapon, _items, _magazines], true];
|
|
|
|
// play sound
|
|
if (["ace_backpacks"] call EFUNC(common,isModLoaded)) then {
|
|
[_target, _gunbag] call EFUNC(backpacks,backpackOpened);
|
|
};
|