mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
51 lines
1.8 KiB
Plaintext
51 lines
1.8 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: KoffeinFlummi, Ruthberg
|
|
* Applies the adjustment for the current scope
|
|
*
|
|
* Arguments:
|
|
* 0: Unit <OBJECT>
|
|
* 1: Absolute elevation <NUMBER>
|
|
* 2: Absolute windage <NUMBER>
|
|
* 3: Absolute zero reference <NUMBER>
|
|
*
|
|
* Return Value:
|
|
* True <BOOL>
|
|
*
|
|
* Example:
|
|
* [player, 1.3, 0.3, 0.1] call ace_scopes_fnc_applyScopeAdjustment
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_unit", "_elevation", "_windage", "_zero"];
|
|
|
|
private _weaponIndex = [_unit, currentWeapon _unit] call EFUNC(common,getWeaponIndex);
|
|
|
|
private _adjustment = _unit getVariable [QGVAR(Adjustment), [[0, 0, 0], [0, 0, 0], [0, 0, 0]]];
|
|
private _adjustmentDifference = (_adjustment select _weaponIndex) vectorDiff [_elevation, _windage, _zero];
|
|
if (_adjustmentDifference isEqualTo [0,0,0]) exitWith {false}; // Don't coninue if no adjustment is made
|
|
|
|
_adjustment set [_weaponIndex, [_elevation, _windage, _zero]];
|
|
[_unit, QGVAR(Adjustment), _adjustment, 0.5] call EFUNC(common,setVariablePublic);
|
|
|
|
playSound selectRandom ["ACE_Scopes_Click_1", "ACE_Scopes_Click_2", "ACE_Scopes_Click_3"];
|
|
|
|
// slightly rotate the player if looking through optic
|
|
if (cameraView == "GUNNER") then {
|
|
if (!GVAR(simplifiedZeroing)) then {
|
|
// Convert adjustmentDifference from mils to degrees
|
|
_adjustmentDifference = _adjustmentDifference apply {MRAD_TO_DEG(_x)};
|
|
_adjustmentDifference params ["_elevationDifference", "_windageDifference"];
|
|
private _pitchBankYaw = [_unit] call EFUNC(common,getPitchBankYaw);
|
|
_pitchBankYaw params ["_pitch", "_bank", "_yaw"];
|
|
_pitch = _pitch + _elevationDifference;
|
|
_yaw = _yaw + _windageDifference;
|
|
[_unit, _pitch, _bank, _yaw] call EFUNC(common,setPitchBankYaw);
|
|
};
|
|
} else {
|
|
[] call FUNC(showZeroing);
|
|
};
|
|
|
|
true
|