mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
56 lines
1.7 KiB
Plaintext
56 lines
1.7 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: Garth 'L-H' de Wet, Ruthberg, edited by commy2 for better MP and eventual AI support
|
|
* Starts the deploy process for sandbags.
|
|
*
|
|
* Arguments:
|
|
* 0: unit <OBJECT>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [ACE_player] call ace_sandbag_fnc_deploy
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_unit"];
|
|
|
|
// prevent the placing unit from running
|
|
[_unit, "forceWalk", "ACE_Sandbag", true] call EFUNC(common,statusEffect_set);
|
|
[_unit, "blockThrow", "ACE_Sandbag", true] call EFUNC(common,statusEffect_set);
|
|
|
|
// create the sandbag
|
|
private _sandBag = createVehicle ["ACE_SandbagObject_NoGeo", [0, 0, 0], [], 0, "NONE"];
|
|
|
|
GVAR(sandBag) = _sandBag;
|
|
|
|
// prevent collisions with sandbag
|
|
[QEGVAR(common,enableSimulationGlobal), [_sandBag, false]] call CBA_fnc_serverEvent;
|
|
|
|
GVAR(deployDirection) = 0;
|
|
|
|
// pfh that runs while the deployment is in progress
|
|
GVAR(deployPFH) = [{
|
|
(_this select 0) params ["_unit", "_sandBag"];
|
|
|
|
if (isNull _sandBag) exitWith {
|
|
[_unit] call FUNC(deployCancel);
|
|
};
|
|
|
|
_sandBag setPosASL (eyePos _unit vectorAdd (positionCameraToWorld [0, 0, 1] vectorDiff positionCameraToWorld [0, 0, 0]));
|
|
_sandBag setDir (GVAR(deployDirection) + getDir _unit);
|
|
}, 0, [_unit, _sandBag]] call CBA_fnc_addPerFrameHandler;
|
|
|
|
// add mouse button action and hint
|
|
[localize LSTRING(ConfirmDeployment), localize LSTRING(CancelDeployment), localize LSTRING(ScrollAction)] call EFUNC(interaction,showMouseHint);
|
|
|
|
_unit setVariable [QGVAR(Deploy), [
|
|
_unit, "DefaultAction",
|
|
{GVAR(deployPFH) != -1},
|
|
{[_this select 0] call FUNC(deployConfirm)}
|
|
] call EFUNC(common,addActionEventHandler)];
|
|
|
|
_unit setVariable [QGVAR(isDeploying), true, true];
|