mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
bca8b01860
* Add search to teleport players UI * Change group side icons to look better * Improve teleport UI and add stringtable entries * Add Assign Repair Vehicle module * Add Assign Repair Facility module * Add Assign Engineer module * Add Full Heal module * Add Suicide Bomber module * Make heal module work without ace_medical * Add suicide bomber module translations * Improve attribute cargo to use displayName * Improve set engineer ui * ACE_Curator for repair modules + author array * Add angle param to getModuleDestination * Prevent multiple suicide bomber modules on same target * Heal module: support BI scripted revive system * Requested changes
76 lines
1.9 KiB
Plaintext
76 lines
1.9 KiB
Plaintext
/*
|
|
* Author: mharis001
|
|
* Initalizes the "Set Engineer" Zeus module display.
|
|
*
|
|
* Arguments:
|
|
* 0: setEngineer controls group <CONTROL>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [CONTROL] call ace_zeus_fnc_ui_setEngineer
|
|
*
|
|
* Public: No
|
|
*/
|
|
#include "script_component.hpp"
|
|
|
|
params ["_control"];
|
|
|
|
// Generic init
|
|
private _display = ctrlParent _control;
|
|
private _ctrlButtonOK = _display displayCtrl 1; // IDC_OK
|
|
private _logic = GETMVAR(BIS_fnc_initCuratorAttributes_target,objNull);
|
|
TRACE_1("logicObject",_logic);
|
|
|
|
_control ctrlRemoveAllEventHandlers "setFocus";
|
|
|
|
// Validate module target
|
|
private _unit = attachedTo _logic;
|
|
TRACE_1("unit",_unit);
|
|
|
|
scopeName "Main";
|
|
private _fnc_errorAndClose = {
|
|
params ["_msg"];
|
|
_display closeDisplay 0;
|
|
deleteVehicle _logic;
|
|
[_msg] call FUNC(showMessage);
|
|
breakOut "Main";
|
|
};
|
|
|
|
switch (false) do {
|
|
case !(isNull _unit): {
|
|
[LSTRING(NothingSelected)] call _fnc_errorAndClose;
|
|
};
|
|
case (_unit isKindOf "CAManBase"): {
|
|
[LSTRING(OnlyInfantry)] call _fnc_errorAndClose;
|
|
};
|
|
case (alive _unit): {
|
|
[LSTRING(OnlyAlive)] call _fnc_errorAndClose;
|
|
};
|
|
};
|
|
|
|
// Specific onLoad stuff
|
|
private _fnc_onUnload = {
|
|
private _logic = GETMVAR(BIS_fnc_initCuratorAttributes_target,objNull);
|
|
if (isNull _logic) exitWith {};
|
|
|
|
deleteVehicle _logic;
|
|
};
|
|
|
|
private _fnc_onConfirm = {
|
|
params [["_ctrlButtonOK", controlNull, [controlNull]]];
|
|
|
|
private _display = ctrlParent _ctrlButtonOK;
|
|
if (isNull _display) exitWith {};
|
|
|
|
private _logic = GETMVAR(BIS_fnc_initCuratorAttributes_target,objnull);
|
|
if (isNull _logic) exitWith {};
|
|
|
|
private _value = lbCurSel (_display displayCtrl 86947);
|
|
[attachedTo _logic, _value + 1] call FUNC(moduleSetEngineer); // +1 since lbCurSel zero-indexed
|
|
};
|
|
|
|
_display displayAddEventHandler ["Unload", _fnc_onUnload];
|
|
_ctrlButtonOK ctrlAddEventHandler ["ButtonClick", _fnc_onConfirm];
|