mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
46 lines
1.5 KiB
Plaintext
46 lines
1.5 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: commy2, Dystopian
|
|
* Check if unit can carry the object. Doesn't check weight.
|
|
*
|
|
* Arguments:
|
|
* 0: Unit that should do the carrying <OBJECT>
|
|
* 1: Object to carry <OBJECT>
|
|
*
|
|
* Return Value:
|
|
* Can the unit carry the object? <BOOL>
|
|
*
|
|
* Example:
|
|
* [player, cursorTarget] call ace_dragging_fnc_canCarry
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_unit", "_target"];
|
|
|
|
if !(alive _target && {_target getVariable [QGVAR(canCarry), false]} && {isNull objectParent _target}) exitWith {false};
|
|
|
|
if !([_unit, _target, []] call EFUNC(common,canInteractWith)) exitWith {false};
|
|
|
|
//#2644 - Units with injured legs cannot bear the extra weight of carrying an object
|
|
//The fireman carry animation does not slow down for injured legs, so you could carry and run
|
|
if ((_unit getHitPointDamage "HitLegs") >= 0.5) exitWith {false};
|
|
|
|
// Static weapons need to be empty for carrying (ignore UAV AI)
|
|
if (_target isKindOf "StaticWeapon") exitWith {
|
|
crew _target findIf {getText (configOf _x >> "simulation") != "UAVPilot"} == -1
|
|
};
|
|
|
|
// Units need to be unconscious or limping
|
|
if (_target isKindOf "CAManBase") exitWith {
|
|
lifeState _target isEqualTo "INCAPACITATED"
|
|
|| {_target getHitPointDamage "HitLegs" >= 0.5}
|
|
};
|
|
|
|
// Check max items for WeaponHolders
|
|
if (["WeaponHolder", "WeaponHolderSimulated"] findIf {_target isKindOf _x} != -1) exitWith {
|
|
(count (weaponCargo _target + magazineCargo _target + itemCargo _target)) <= MAX_DRAGGED_ITEMS
|
|
};
|
|
|
|
true // return
|