mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
ab769757d9
Stuff Normalize Depends - Skip Glass Repair Fix spawned wheel/track not having correct damage getHitpointString robustness, hatchback fuelHitpoint, fix count errors - Formatting local -> private Fix Stuff
43 lines
1.2 KiB
Plaintext
43 lines
1.2 KiB
Plaintext
/*
|
|
* Author: commy2
|
|
* Called by repair action / progress bar. Raise events to set the new hitpoint damage.
|
|
*
|
|
* Arguments:
|
|
* 0: Unit that does the repairing <OBJECT>
|
|
* 1: Vehicle to repair <OBJECT>
|
|
* 2: Selected hitpoint <STRING>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [unit, vehicle, "hitpoint"] call ace_repair_fnc_doRemoveWheel
|
|
*
|
|
* Public: No
|
|
*/
|
|
#include "script_component.hpp"
|
|
|
|
params ["_unit", "_vehicle", "_hitPoint"];
|
|
TRACE_3("params",_unit,_vehicle,_hitPoint);
|
|
|
|
// get current hitpoint damage
|
|
private _hitPointDamage = _vehicle getHitPointDamage _hitPoint;
|
|
|
|
// can't remove destroyed or already removed wheel
|
|
if (_hitPointDamage >= 1) exitWith {};
|
|
|
|
// don't die by spawning / moving the wheel
|
|
["fixCollision", _unit] call EFUNC(common,localEvent);
|
|
|
|
// spawn wheel
|
|
private _newWheel = ["ACE_Wheel", getPosASL _unit, _hitPointDamage] call FUNC(spawnObject);
|
|
TRACE_2("new wheel created",_newWheel,damage _newWheel);
|
|
|
|
// raise event to set the new hitpoint damage
|
|
["setWheelHitPointDamage", _vehicle, [_vehicle, _hitPoint, 1]] call EFUNC(common,targetEvent);
|
|
|
|
// display text message if enabled
|
|
if (GVAR(DisplayTextOnRepair)) then {
|
|
[localize LSTRING(RemovedWheel)] call EFUNC(common,displayTextStructured);
|
|
};
|