mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
99c85e3c12
* move overheating cookoff into separate function * move heatCoef and require mission restart for setting change - move heatCoef to a more sensible place - require mission restart for heatCoef setting change (it gets cached per ammo type) * add exit to ammo temp loop if cookoffCoef is changed to 0 mid-mission - add exit to ammo temp loop if cookoffCoef is changed to 0 mid-mission, this prevents an issue where all weapon cookoff regardless of temp, because required temp gets multiplied by cookoffCoef which has been set to 0. * file end new line * update header for ace_overheating_fnc_cookoffWeapon * use ambientTemperature as floor for weapon and ammo temp * add coolingCoef setting * improve feature documentation * add fnc_cookoffWeapon to XEH_PREP * add type of jam to ace_weaponJammed local event - add type of jam to ace_weaponJammed local event - fix #8637 * fix misspelling Co-authored-by: TyroneMF <TyroneMF@hotmail.com> * clear all weapon heat on death * Update addons/overheating/functions/fnc_updateTemperature.sqf Co-authored-by: GhostIsSpooky <69561145+Salluci@users.noreply.github.com> * deprecate ace_overheating_fnc_getBarrelMass, cache weapon bolt and barrel mass values - cache closed bolt value by moving config look up to ace_overheating_fnc_getWeaponData - cache barrel mass value by moving calculation from ace_overheating_fnc_getBarrelMass to ace_overheating_fnc_getWeaponData - deprecate ace_overheating_fnc_getBarrelMass to be a wrapper for ace_overheating_fnc_getWeaponData that only returns barrel mass * add public functions to get and set weapon and ammo temperature * add `canCoolWeaponWithItem` function, workaround for #8657 * Apply suggestions from code review Co-authored-by: PabstMirror <pabstmirror@gmail.com> * add coef setting for addition heat from suppressor * Update fnc_overheat.sqf * improve fnc_canCoolWeaponWithItem * remove extra ( * Move canCoolWeaponWithItem action code to function * Use hashmaps and reset on settings change * Apply suggestions from code review Co-authored-by: jonpas <jonpas33@gmail.com> Co-authored-by: TyroneMF <TyroneMF@hotmail.com> Co-authored-by: GhostIsSpooky <69561145+Salluci@users.noreply.github.com> Co-authored-by: PabstMirror <pabstmirror@gmail.com> Co-authored-by: jonpas <jonpas33@gmail.com>
67 lines
2.2 KiB
Plaintext
67 lines
2.2 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: drofseh
|
|
* Cookoff loaded round.
|
|
*
|
|
* Arguments:
|
|
* 0: Unit <OBJECT>
|
|
* 1: Weapon <STRING>
|
|
* 2: Is Weapon Jammed <BOOL>
|
|
* 3: Type of Jam <STRING>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [player, currentWeapon player, true, "Fire"] call ace_overheating_fnc_cookoffWeapon
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_unit", "_weapon", "_canUnjam", "_jamType"];
|
|
TRACE_4("params",_unit,_weapon,_canUnjam,_jamType);
|
|
|
|
// a weapon with a failure to fire or dud type jam will be unjammed from cooking off
|
|
// this is first so that the fired event from the cookoff can also cause a jam
|
|
if (_canUnjam && {_jamType in ["Fire","Dud"]}) then {
|
|
[_unit, currentMuzzle _unit, true] call FUNC(clearJam);
|
|
|
|
// clearJam will remove a dud round, but so will the forced fire, so give back the lost round and shoot it
|
|
if (_jamType isEqualTo "Dud") then {
|
|
_unit setAmmo [_weapon, (_unit ammo _weapon) + 1];
|
|
};
|
|
};
|
|
|
|
// get valid mode and muzzle for the main weapon, we don't want the cookoff to come from an underbarrel launcher
|
|
([_weapon] call FUNC(getWeaponData)) params ["", "", "", "_modes", "_muzzle", "_reloadTime"];
|
|
|
|
// get an appropriate firemode and muzzle, cache the current muzzle
|
|
// trying to match firemodes and switching back to the cached muzzle will hide the change from the player and prevent unexpected mode/muzzle changes (going from full auto to semi auto, or from underbarrel GL to rifle for example)
|
|
private _muzzleCache = currentMuzzle _unit;
|
|
private _mode = currentWeaponMode _unit;
|
|
if !(_mode in _modes) then {
|
|
_mode = _modes select 0;
|
|
};
|
|
|
|
// delay cookoff to ensure any previous animation from a fired event is finished
|
|
[
|
|
{
|
|
params ["_unit", "_mode", "_muzzle", "_muzzleCache"];
|
|
|
|
// fire the cookoff
|
|
_unit forceWeaponFire [_muzzle, _mode];
|
|
|
|
// switch back to the cached muzzle if required
|
|
if (_muzzle != _muzzleCache) then {
|
|
_unit selectWeapon _muzzleCache;
|
|
};
|
|
|
|
[
|
|
[localize LSTRING(WeaponCookedOff)],
|
|
true // allows the hint to be overwritten by another hint, such as a jam or another cookoff
|
|
] call CBA_fnc_notify;
|
|
},
|
|
[_unit, _mode, _muzzle, _muzzleCache],
|
|
_reloadTime
|
|
] call CBA_fnc_waitAndExecute;
|