mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
43 lines
1.2 KiB
Plaintext
43 lines
1.2 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: commy2
|
|
* Called by repair action / progress bar. Raise events to set the new hitpoint damage.
|
|
*
|
|
* Arguments:
|
|
* 0: Unit that does the repairing <OBJECT>
|
|
* 1: Vehicle to repair <OBJECT>
|
|
* 2: Selected hitpoint <STRING>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [unit, vehicle, "hitpoint"] call ace_repair_fnc_doRemoveTrack
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_unit", "_vehicle", "_hitPoint"];
|
|
TRACE_3("params",_unit,_vehicle,_hitPoint);
|
|
|
|
// get current hitpoint damage
|
|
private _hitPointDamage = _vehicle getHitPointDamage _hitPoint;
|
|
|
|
// can't remove destroyed or already removed wheel
|
|
if (_hitPointDamage >= 1) exitWith {};
|
|
|
|
// don't die by spawning / moving the wheel
|
|
[QEGVAR(common,fixCollision), _unit] call CBA_fnc_localEvent;
|
|
|
|
// spawn track
|
|
private _newTrack = ["ACE_Track", getPosASL _unit, _hitPointDamage] call FUNC(spawnObject);
|
|
TRACE_2("new track created",_newTrack,damage _newTrack);
|
|
|
|
// raise event to set the new hitpoint damage
|
|
[QGVAR(setWheelHitPointDamage), [_vehicle, _hitPoint, 1], _vehicle] call CBA_fnc_targetEvent;
|
|
|
|
// display text message if enabled
|
|
if (GVAR(DisplayTextOnRepair)) then {
|
|
[localize LSTRING(RemovedTrack)] call EFUNC(common,displayTextStructured);
|
|
};
|