mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
9be0b8b6c6
* Add Zeus module for burning units * Add ACE_Curator * Simplified module code * Remove double module declaration Co-authored-by: mharis001 <34453221+mharis001@users.noreply.github.com> Co-authored-by: PabstMirror <pabstmirror@gmail.com> Co-authored-by: mharis001 <34453221+mharis001@users.noreply.github.com>
43 lines
862 B
Plaintext
43 lines
862 B
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: BaerMitUmlaut
|
|
* Inflames a unit.
|
|
*
|
|
* Arguments:
|
|
* 0: The module logic <OBJECT>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [LOGIC] call ace_zeus_fnc_moduleBurn
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_logic"];
|
|
|
|
if !(local _logic) exitWith {};
|
|
|
|
private _unit = attachedTo _logic;
|
|
deleteVehicle _logic;
|
|
|
|
switch (false) do {
|
|
case !(isNull _unit): {
|
|
[LSTRING(NothingSelected)] call FUNC(showMessage);
|
|
};
|
|
case (_unit isKindOf "CAManBase"): {
|
|
[LSTRING(OnlyInfantry)] call FUNC(showMessage);
|
|
};
|
|
case (alive _unit): {
|
|
[LSTRING(OnlyAlive)] call FUNC(showMessage);
|
|
};
|
|
case (["ace_fire"] call EFUNC(common,isModLoaded)): {
|
|
[LSTRING(RequiresAddon)] call FUNC(showMessage);
|
|
};
|
|
default {
|
|
[QEGVAR(fire,burn), [_unit, 5]] call CBA_fnc_globalEvent;
|
|
};
|
|
};
|
|
|