mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
48 lines
1.6 KiB
Plaintext
48 lines
1.6 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: bux, commy2
|
|
* Hide or show the secondary weapon magazine inventory slot to prevent unloading of dummy magazines.
|
|
*
|
|
* Arguments:
|
|
* 0: unit - Object the event handler is assigned to <OBJECT>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [player] call ace_disposable_fnc_updateInventoryDisplay;
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
disableSerialization;
|
|
params ["_player", ["_display",(findDisplay 602),[displayNull]]];
|
|
TRACE_2("params",_player,_display);
|
|
|
|
_player removeMagazines "ACE_PreloadedMissileDummy";
|
|
_player removeMagazines "ACE_FiredMissileDummy";
|
|
|
|
if (isNull _display) exitWith {};
|
|
|
|
private _launcher = secondaryWeapon _player;
|
|
|
|
if (_launcher == "" || {getText (configFile >> "CfgWeapons" >> _launcher >> "ACE_UsedTube") == ""}) then {
|
|
private _control = _display displayCtrl 627;
|
|
private _config = configFile >> "RscDisplayInventory" >> "controls" >> "SlotSecondaryMagazine";
|
|
_control ctrlSetPosition [getNumber (_config >> "x"), getNumber (_config >> "y"), getNumber (_config >> "w"), getNumber (_config >> "h")];
|
|
_control ctrlCommit 0;
|
|
|
|
_control = _display displayCtrl 1251;
|
|
_config = configFile >> "RscDisplayInventory" >> "controls" >> "BackgroundSlotSecondaryMagazine";
|
|
_control ctrlSetPosition [getNumber (_config >> "x"), getNumber (_config >> "y"), getNumber (_config >> "w"), getNumber (_config >> "h")];
|
|
_control ctrlCommit 0;
|
|
} else {
|
|
private _control = _display displayCtrl 627;
|
|
_control ctrlSetPosition [0, 0, 0, 0];
|
|
_control ctrlCommit 0;
|
|
|
|
_control = _display displayCtrl 1251;
|
|
_control ctrlSetPosition [0, 0, 0, 0];
|
|
_control ctrlCommit 0;
|
|
};
|