mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
53 lines
1.4 KiB
Plaintext
53 lines
1.4 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: commy2
|
|
* Moves a rallypoint to the players location.
|
|
*
|
|
* Arguments:
|
|
* 0: Unit <OBJECT>
|
|
* 1: Side <SIDE>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [ACE_Player, side ACE_Player] call ace_respawn_fnc_moveRallypoint
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_unit", "_side"];
|
|
|
|
private _rallypoint = [
|
|
objNull,
|
|
missionNamespace getVariable ["ACE_Rallypoint_West", objNull],
|
|
missionNamespace getVariable ["ACE_Rallypoint_East", objNull],
|
|
missionNamespace getVariable ["ACE_Rallypoint_Independent", objNull]
|
|
] select ([west, east, independent] find _side) + 1;
|
|
|
|
TRACE_3("moving rally",_unit,_rallypoint,typeOf _rallypoint);
|
|
|
|
if (isNull _rallypoint) exitWith {};
|
|
|
|
private _position = getPosATL _unit;
|
|
_position = _position findEmptyPosition [0, 2, typeOf _rallypoint];
|
|
|
|
if (_position isEqualTo []) then {_position = getPosATL _unit};
|
|
|
|
_position set [2, 0];
|
|
|
|
[localize LSTRING(Deploy)] call EFUNC(common,displayTextStructured);
|
|
|
|
[{
|
|
params ["_rallypoint", "_unit", "_position"];
|
|
|
|
_rallypoint setPosATL _position;
|
|
_unit reveal _rallypoint;
|
|
|
|
_rallypoint setVariable [QGVAR(markerDate), [dayTime, "HH:MM"] call BIS_fnc_timeToString, true];
|
|
|
|
["ace_rallypointMoved", [_rallypoint, _side, _position]] call CBA_fnc_globalEvent;
|
|
|
|
[localize LSTRING(Deployed)] call EFUNC(common,displayTextStructured);
|
|
}, [_rallypoint, _unit, _position], 5] call CBA_fnc_waitAndExecute;
|