mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
46 lines
1.3 KiB
Plaintext
46 lines
1.3 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: PabstMirror
|
|
* Finds next valid index for the device array.
|
|
*
|
|
* Arguments:
|
|
* 0: Offset from currentIndex (use 1 to find next valid after current) or a displayName string (default: 0) <STRING, NUMBER>
|
|
*
|
|
* Return Value:
|
|
* The new index (-1 if no valid) <NUMBER>
|
|
*
|
|
* Example:
|
|
* [] call ace_common_fnc_deviceKeyFindValidIndex
|
|
* ["kestral4500"] call ace_common_fnc_deviceKeyFindValidIndex
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params [["_searchOffsetOrName", 0]];
|
|
|
|
private _validIndex = -1;
|
|
|
|
if (_searchOffsetOrName isEqualType "") then {
|
|
{
|
|
if (_x select 0 == _searchOffsetOrName) exitWith {
|
|
_validIndex = _forEachIndex;
|
|
};
|
|
} forEach GVAR(deviceKeyHandlingArray);
|
|
} else {
|
|
if (count GVAR(deviceKeyHandlingArray) > 0) then {
|
|
private _baseIndex = [GVAR(deviceKeyCurrentIndex) + _searchOffsetOrName, 0] select (GVAR(deviceKeyCurrentIndex) == -1);
|
|
|
|
for "_offset" from _baseIndex to (count GVAR(deviceKeyHandlingArray) - 1 + _baseIndex) do {
|
|
private _realIndex = _offset % (count GVAR(deviceKeyHandlingArray));
|
|
|
|
if ([] call ((GVAR(deviceKeyHandlingArray) select _realIndex) select 2)) exitWith {
|
|
_validIndex = _realIndex;
|
|
};
|
|
};
|
|
};
|
|
};
|
|
|
|
GVAR(deviceKeyCurrentIndex) = _validIndex;
|
|
|
|
GVAR(deviceKeyCurrentIndex)
|