mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
51 lines
1.1 KiB
Plaintext
51 lines
1.1 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: rocko
|
|
* Fixes animation issues that may get you stuck
|
|
*
|
|
* Arguments:
|
|
* None
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [] call ace_common_fnc_headBugFix
|
|
*
|
|
* Public: Yes
|
|
*
|
|
* Note: Has to be spawned not called
|
|
*/
|
|
|
|
private _unit = ACE_player;
|
|
private _anim = animationState _unit;
|
|
|
|
[QGVAR(headbugFixUsed), [profileName, _anim]] call CBA_fnc_serverEvent;
|
|
[QGVAR(headbugFixUsed), [profileName, _anim]] call CBA_fnc_localEvent;
|
|
|
|
if (_unit != vehicle _unit || {!([_unit, objNull, ["isNotSitting"]] call FUNC(canInteractWith))}) exitWith {false};
|
|
|
|
private _pos = getPosATL _unit;
|
|
private _dir = getDir _unit;
|
|
|
|
titleCut ["", "BLACK"];
|
|
[_unit, "headBugFix"] call FUNC(hideUnit);
|
|
|
|
// create invisible headbug fix vehicle
|
|
private _dummy = createVehicle ["ACE_Headbug_Fix", _pos, [], 0, "NONE"];
|
|
_dummy setDir _dir;
|
|
_unit moveInAny _dummy;
|
|
sleep 0.1; // @todo
|
|
|
|
unassignVehicle _unit;
|
|
_unit action ["Eject", vehicle _unit];
|
|
_unit setDir _dir;
|
|
_unit setPosATL _pos;
|
|
sleep 1.0;
|
|
|
|
deleteVehicle _dummy;
|
|
|
|
[_unit, "headBugFix"] call FUNC(unhideUnit);
|
|
titleCut ["", "PLAIN"];
|
|
true
|