mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
6ca9d59443
* Merge ACEX - first attempt Backwards compatibility with XGVAR set of macros used on all settings and config entries Public API functions not taken into account yet, many other things probably still missed * Resolve issues * Switch to addSetting, backward compatible CfgPatches, missed XGVAR. * Remove unnecessary backwards compat * Convert ACEX Categorised settings to initSettings / Fix Intel items magazine * Apply suggestions from code review Co-authored-by: PabstMirror <pabstmirror@gmail.com> * Remove maintainers from merged ACEX components * Cleanup unused module and faction classes * Sitting - Add more object configs by @Dystopian https://github.com/acemod/ACEX/pull/255 * Translations - Add Japanese by @classicarma https://github.com/acemod/ACEX/pull/259 * Kill Tracker - Add killtracker.inc public include file by @Freddo3000" https://github.com/acemod/ACEX/pull/251 * Add ACEX authors and sort authors file * acex - final tweaks (#8513) * acex - handle old funcs * replace thirst/hunger setvars to acex naming fix macro Revert "fix macro" This reverts commit d807e5e804c43916eaa42d34a89af94c6d9a48ad. Revert "replace thirst/hunger setvars to acex naming" This reverts commit bafc607884932d6e339daedc7c22e25dddbdd868. x Co-authored-by: TyroneMF <TyroneMF@hotmail.com> Co-authored-by: PabstMirror <pabstmirror@gmail.com>
50 lines
1.2 KiB
Plaintext
50 lines
1.2 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: Kingsley
|
|
* Adds the child actions.
|
|
*
|
|
* Arguments:
|
|
* 0: Player <OBJECT>
|
|
*
|
|
* Return Value:
|
|
* Actions <ARRAY>
|
|
*
|
|
* Example:
|
|
* [player] call ace_fortify_fnc_addActions
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_player"];
|
|
|
|
private _side = side group _player;
|
|
private _objects = missionNamespace getVariable [format [QGVAR(Objects_%1), _side], []];
|
|
private _actions = [];
|
|
private _infiniteBudget = ([side group _player] call FUNC(getBudget)) == -1;
|
|
|
|
{
|
|
_x params ["_classname", "_cost"];
|
|
|
|
private _displayName = getText (configFile >> "CfgVehicles" >> _classname >> "displayName");
|
|
|
|
private _action = [
|
|
_classname,
|
|
if (_infiniteBudget) then { _displayName } else { format ["$%1 - %2", _cost, _displayName] },
|
|
"",
|
|
LINKFUNC(deployObject),
|
|
{
|
|
params ["", "_player", "_args"];
|
|
|
|
private _cost = _args call FUNC(getCost);
|
|
private _budget = [side group _player] call FUNC(getBudget);
|
|
_budget == -1 || {_budget >= _cost}
|
|
},
|
|
{},
|
|
[_side, _classname]
|
|
] call EFUNC(interact_menu,createAction);
|
|
|
|
_actions pushBack [_action, [], _player];
|
|
} forEach _objects;
|
|
|
|
_actions
|