mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
37 lines
1.2 KiB
Plaintext
37 lines
1.2 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: TheDrill, PabstMirror
|
|
* Recieve an finger event, adds to the array (or updates if already present) and starts PFEH if not already running
|
|
*
|
|
* Arguments:
|
|
* 0: Source Unit (can be self) <OBJECT>
|
|
* 1: Position being pointed at (ASL) <ARRAY>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [bob, [1,2,3]] call ace_finger_fnc_incomingFinger;
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_sourceUnit", "_fingerPosPrecise", "_distance"];
|
|
|
|
// Add some random float to location if it's not our own finger:
|
|
private _fingerPos = if (_sourceUnit == ACE_player) then {
|
|
_fingerPosPrecise
|
|
} else {
|
|
_fingerPosPrecise vectorAdd ([random (2 * FP_RANDOMIZATION_X) - FP_RANDOMIZATION_X, random (2 * FP_RANDOMIZATION_X) - FP_RANDOMIZATION_X, random (2 * FP_RANDOMIZATION_Y) - FP_RANDOMIZATION_Y] vectorMultiply _distance)
|
|
};
|
|
|
|
TRACE_3("incoming finger:", _sourceUnit, _fingerPosPrecise, _fingerPos);
|
|
|
|
private _data = [diag_tickTime, _fingerPos, ([_sourceUnit, false, true] call EFUNC(common,getName))];
|
|
[GVAR(fingersHash), _sourceUnit, _data] call CBA_fnc_hashSet;
|
|
|
|
if (GVAR(pfeh_id) == -1) then {
|
|
GVAR(pfeh_id) = [DFUNC(perFrameEH), 0, []] call CBA_fnc_addPerFrameHandler;
|
|
TRACE_1("Started PFEH", GVAR(pfeh_id));
|
|
};
|