mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
85c5fbabe9
* Fix incorrect function input for spectator hiding * Remove locations tab from spectator - Doesn't add much value, adds complexity and the implementation is half baked. Would rather add back in at a later date (if at all) with a better implementation. - I have an idea to replace the locations tab with a meta tab so users can toggle things like projectile drawing via the UI and are not forced to use a hotkey. Might also be a good place to display the extended controls.
60 lines
1.6 KiB
Plaintext
60 lines
1.6 KiB
Plaintext
/*
|
|
* Author: AACO, SilentSpike
|
|
* Function used to set the camera focus
|
|
*
|
|
* Arguments:
|
|
* 0: New focus <OBJECT>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [player] call ace_spectator_fnc_setFocus
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
#include "script_component.hpp"
|
|
|
|
params [["_newFocus", objNull, [objNull,true]]];
|
|
|
|
// If boolean provided then first find a focus
|
|
if (_newFocus isEqualType true) then {
|
|
private _testFocus = ([] call FUNC(getTargetEntities)) select 0;
|
|
|
|
if (isNil "_testFocus") then {
|
|
if (MODE_FREE in GVAR(availableModes)) then {
|
|
WARNING("No available entities to focus on. Switching to free cam.");
|
|
[MODE_FREE] call FUNC(cam_setCameraMode);
|
|
_newFocus = objNull;
|
|
} else {
|
|
// Default to player if necessary
|
|
WARNING("No available entities to focus on. Using player.");
|
|
_newFocus = player;
|
|
};
|
|
} else {
|
|
_newFocus = _testFocus;
|
|
};
|
|
};
|
|
|
|
if (_newFocus != GVAR(camTarget) && { !(isNull _newFocus && { isNull GVAR(camTarget) }) }) then {
|
|
GVAR(camTarget) = _newFocus;
|
|
|
|
if (isNull _newFocus) then {
|
|
if (GVAR(camMode) == MODE_FREE) then {
|
|
[] call FUNC(cam_resetTarget);
|
|
} else {
|
|
[MODE_FREE] call FUNC(cam_setCameraMode);
|
|
};
|
|
} else {
|
|
[GVAR(camMode)] call FUNC(cam_setCameraMode);
|
|
};
|
|
|
|
// Only update display if it exists, this function is independent of it
|
|
if !(isNull SPEC_DISPLAY) then {
|
|
[] call FUNC(ui_updateListFocus);
|
|
[] call FUNC(ui_updateWidget);
|
|
[] call FUNC(ui_updateHelp);
|
|
};
|
|
};
|