mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
63 lines
2.5 KiB
Plaintext
63 lines
2.5 KiB
Plaintext
#include "\a3\ui_f\hpp\defineResinclDesign.inc"
|
|
#include "script_component.hpp"
|
|
/*
|
|
* Author: PabstMirror
|
|
* Loads the version info HTML box from main menu
|
|
*
|
|
* Arguments:
|
|
* 0: Display (from onMouseMoving) <DISPLAY>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* onMouseMovingEvent execVM "script_loadMainMenuBox.sqf";
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_display"];
|
|
private _controlsGroup = _display displayCtrl IDC_MAIN_INFO;
|
|
|
|
//Need to load from profileNamespace because ace_settings might not be init if world = empty
|
|
if (profileNamespace getVariable [QGVAR(showNewsOnMainMenu), true]) then {
|
|
_controlsGroup ctrlShow true;
|
|
|
|
private _fnc_onSetFocus = {
|
|
params ["_control"];
|
|
private _controlsGroup = ctrlParentControlsGroup _control;
|
|
|
|
(_controlsGroup controlsGroupCtrl IDC_MAIN_INFO_BACKGROUND) ctrlSetTextColor [1,1,1,1];
|
|
(_controlsGroup controlsGroupCtrl IDC_MAIN_INFO_BACKGROUND_ICON) ctrlSetTextColor [1,1,1,1];
|
|
(_controlsGroup controlsGroupCtrl IDC_MAIN_INFO_ICON) ctrlSetTextColor [0,0,0,1];
|
|
};
|
|
|
|
private _fnc_onKillFocus = {
|
|
params ["_control"];
|
|
private _controlsGroup = ctrlParentControlsGroup _control;
|
|
|
|
(_controlsGroup controlsGroupCtrl IDC_MAIN_INFO_BACKGROUND) ctrlSetTextColor [0,0,0,0.75];
|
|
(_controlsGroup controlsGroupCtrl IDC_MAIN_INFO_BACKGROUND_ICON) ctrlSetTextColor [0,0,0,0.75];
|
|
(_controlsGroup controlsGroupCtrl IDC_MAIN_INFO_ICON) ctrlSetTextColor [1,1,1,0.5];
|
|
};
|
|
|
|
(_controlsGroup controlsGroupCtrl IDC_MAIN_INFO_BUTTON) ctrlAddEventHandler ["MouseEnter", _fnc_onSetFocus];
|
|
(_controlsGroup controlsGroupCtrl IDC_MAIN_INFO_BUTTON) ctrlAddEventHandler ["SetFocus", _fnc_onSetFocus];
|
|
(_controlsGroup controlsGroupCtrl IDC_MAIN_INFO_BUTTON) ctrlAddEventHandler ["MouseExit", _fnc_onKillFocus];
|
|
(_controlsGroup controlsGroupCtrl IDC_MAIN_INFO_BUTTON) ctrlAddEventHandler ["KillFocus", _fnc_onKillFocus];
|
|
|
|
private _versionStr = getText (configFile >> "CfgPatches" >> "ace_main" >> "versionStr") splitString ".";
|
|
_versionStr resize 3; // MAJOR, MINOR, PATCH
|
|
_versionStr = _versionStr joinString ".";
|
|
|
|
(_display displayCtrl IDC_MAIN_INFO_CURRENT_VERSION_INFO) ctrlSetText format ["Version: %1", _versionStr];
|
|
(_display displayCtrl IDC_MAIN_INFO_NEWEST_VERSION_INFO) htmlLoad "https://ace3mod.com/version.html";
|
|
} else {
|
|
_controlsGroup ctrlShow false;
|
|
};
|
|
|
|
/*
|
|
Note: switch version.html to simpler format and right align
|
|
<h1 align="right">Latest: {{site.ace.version.major}}.{{site.ace.version.minor}}.{{site.ace.version.patch}}</h1>
|
|
*/
|