mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
dbe372cb48
* Code cleanup * Moved keybinds to initKeybinds.sqf * Update addons/dragging/initKeybinds.sqf Co-authored-by: Grim <69561145+LinkIsGrim@users.noreply.github.com> * Update addons/dragging/functions/fnc_carryObject.sqf Co-authored-by: Grim <69561145+LinkIsGrim@users.noreply.github.com> * Update addons/dragging/functions/fnc_getWeight.sqf Co-authored-by: Grim <69561145+LinkIsGrim@users.noreply.github.com> * Rephrasing and adjustments for dragging --------- Co-authored-by: Grim <69561145+LinkIsGrim@users.noreply.github.com>
43 lines
1.3 KiB
Plaintext
43 lines
1.3 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: commy2, Dystopian
|
|
* Checks if unit can drag the object. Doesn't check weight.
|
|
*
|
|
* Arguments:
|
|
* 0: Unit that should do the dragging <OBJECT>
|
|
* 1: Object to drag <OBJECT>
|
|
*
|
|
* Return Value:
|
|
* Can the unit drag the object? <BOOL>
|
|
*
|
|
* Example:
|
|
* [player, cursorTarget] call ace_dragging_fnc_canDrag
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_unit", "_target"];
|
|
|
|
if !(alive _target && {_target getVariable [QGVAR(canDrag), false]} && {isNull objectParent _target}) exitWith {false};
|
|
|
|
if !([_unit, _target, ["isNotSwimming"]] call EFUNC(common,canInteractWith)) exitWith {false};
|
|
|
|
// Static weapons need to be empty for dragging (ignore UAV AI)
|
|
if (_target isKindOf "StaticWeapon") exitWith {
|
|
(crew _target) findIf {getText (configOf _x >> "simulation") != "UAVPilot"} == -1
|
|
};
|
|
|
|
// Units need to be unconscious or limping; Units also need to not be in ragdoll, as that causes desync issues
|
|
if (_target isKindOf "CAManBase") exitWith {
|
|
!(alive _target != isAwake _target) &&
|
|
{lifeState _target == "INCAPACITATED" ||
|
|
{_target getHitPointDamage "HitLegs" >= 0.5}}
|
|
};
|
|
|
|
// Check max items for WeaponHolders
|
|
if (["WeaponHolder", "WeaponHolderSimulated"] findIf {_target isKindOf _x} != -1) exitWith {
|
|
(count (weaponCargo _target + magazineCargo _target + itemCargo _target)) <= MAX_DRAGGED_ITEMS
|
|
};
|
|
|
|
true // return
|