mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
104 lines
3.5 KiB
Plaintext
104 lines
3.5 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: commy2
|
|
* Helper function for updating the 2d and 3d scope controls
|
|
* Called from a dummy map controls onDraw.
|
|
*
|
|
* Arguments:
|
|
* 0: Display (RscInGameUI for a weapon) <DISPLAY>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [ACE_RscWeapon_Arco's Display] call ace_optics_fnc_onDrawScope2D
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
disableSerialization;
|
|
|
|
params ["_display"];
|
|
|
|
// @todo, all weapon types
|
|
private _optic = (primaryWeaponItems ACE_player) select 2;
|
|
private _isPIP = (getText (configFile >> "CfgWeapons" >> _optic >> "ItemInfo" >> "modelOptics")) == QPATHTOF(models\ace_optics_pip.p3d);
|
|
|
|
if (_isPIP) then {
|
|
GVAR(pipLastFrame) = diag_frameno;
|
|
if (isNull GVAR(camera)) then {
|
|
if ((({_x != GVAR(camera)} count allMissionObjects "camera") > 0) || {!isNull curatorCamera}) exitWith {
|
|
TRACE_1("waiting for feature camera to end",GVAR(camera));
|
|
};
|
|
|
|
// PiP technique by BadBenson
|
|
GVAR(camera) = "camera" camCreate positionCameraToWorld [0, 0, 0];
|
|
GVAR(camera) camSetFov 0.7;
|
|
GVAR(camera) camSetTarget ACE_player;
|
|
GVAR(camera) camCommit 1;
|
|
|
|
QGVAR(rendertarget0) setPiPEffect [0];
|
|
GVAR(camera) cameraEffect ["INTERNAL", "BACK", QGVAR(rendertarget0)];
|
|
|
|
TRACE_2("created new pip camera",GVAR(camera),isNull GVAR(camera));
|
|
|
|
// Start a waitUntil to handle destruction after GVAR(pipLastFrame) is no longer updated
|
|
[{
|
|
(abs (diag_frameno - GVAR(pipLastFrame))) > 1
|
|
}, {
|
|
GVAR(camera) cameraEffect ["TERMINATE", "BACK"];
|
|
camDestroy GVAR(camera);
|
|
TRACE_2("destroyed pip camera",GVAR(camera),isNull GVAR(camera));
|
|
}, []] call CBA_fnc_waitUntilAndExecute;
|
|
};
|
|
};
|
|
|
|
//If we are not zoomed into the actual scope (not collimator)
|
|
if (!ctrlShown (_display displayCtrl 154)) exitWith {
|
|
(_display displayCtrl 1713001) ctrlShow false;
|
|
(_display displayCtrl 1713002) ctrlShow false;
|
|
(_display displayCtrl 1713005) ctrlShow false;
|
|
(_display displayCtrl 1713006) ctrlShow false;
|
|
(_display displayCtrl 1713010) ctrlShow false;
|
|
(_display displayCtrl 1713011) ctrlShow false;
|
|
};
|
|
|
|
if (_isPIP) then {
|
|
GVAR(camera) setPosATL positionCameraToWorld [0, 0, 0.4];
|
|
GVAR(camera) camPrepareTarget positionCameraToWorld [0, 0, 50];
|
|
GVAR(camera) camCommitPrepared 0;
|
|
|
|
// @todo, check if that needs to be done at all
|
|
if (cameraView == "GUNNER") then {
|
|
GVAR(camera) camsetFOV 0.7;
|
|
GVAR(camera) camcommit 0;
|
|
} else {
|
|
GVAR(camera) camsetFOV 0.01;
|
|
GVAR(camera) camcommit 0;
|
|
};
|
|
};
|
|
|
|
// Calculate lighting
|
|
private _dayOpacity = call EFUNC(common,ambientBrightness);
|
|
private _nightOpacity = [1, 0] select (_dayOpacity == 1);
|
|
|
|
// Apply lighting and make layers visible
|
|
(_display displayCtrl 1713001) ctrlSetTextColor [1, 1, 1, 1];
|
|
(_display displayCtrl 1713002) ctrlSetTextColor [1, 1, 1, [0, 1] select (_dayOpacity < 0.5)];
|
|
(_display displayCtrl 1713005) ctrlSetTextColor [1, 1, 1, _dayOpacity];
|
|
(_display displayCtrl 1713006) ctrlSetTextColor [1, 1, 1, _nightOpacity];
|
|
|
|
/*
|
|
(_display displayCtrl 1713001) ctrlCommit 0;
|
|
(_display displayCtrl 1713002) ctrlCommit 0;
|
|
(_display displayCtrl 1713005) ctrlCommit 0;
|
|
(_display displayCtrl 1713006) ctrlCommit 0;
|
|
*/
|
|
|
|
(_display displayCtrl 1713001) ctrlShow true;
|
|
(_display displayCtrl 1713002) ctrlShow true;
|
|
(_display displayCtrl 1713005) ctrlShow true;
|
|
(_display displayCtrl 1713006) ctrlShow true;
|
|
(_display displayCtrl 1713010) ctrlShow _isPIP;
|
|
(_display displayCtrl 1713011) ctrlShow _isPIP;
|