mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
63 lines
1.6 KiB
Plaintext
63 lines
1.6 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: commy2
|
|
* Sets newly placed marker
|
|
* Handles the QGVAR(setMarkerNetwork) event.
|
|
*
|
|
* Arguments:
|
|
* 0: Markername <STRING>
|
|
* 1: Marker Data <ARRAY>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [[],[],dummyLogic] call ace_markers_fnc_setMarkerJIP;
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_marker", "_data"];
|
|
TRACE_2("params",_marker,_data);
|
|
_data params ["_markerClassname", "_colorClassname", "_pos", "_dir"];
|
|
|
|
private _config = configfile >> "CfgMarkers" >> _markerClassname;
|
|
|
|
if (!isClass _config) then {
|
|
WARNING("CfgMarker not found, changed to milDot");
|
|
_config = configFile >> "CfgMarkers" >> "MilDot";
|
|
};
|
|
|
|
_marker setMarkerTypeLocal configName _config;
|
|
|
|
_config = configfile >> "CfgMarkerColors" >> _colorClassname;
|
|
|
|
if (!isClass _config) then {
|
|
WARNING("CfgMarkerColors not found, changed to Default");
|
|
_config = configFile >> "CfgMarkerColors" >> "Default";
|
|
};
|
|
|
|
_marker setMarkerColorLocal configName _config;
|
|
|
|
_marker setMarkerPosLocal _pos;
|
|
_marker setMarkerDirLocal _dir;
|
|
|
|
// save properties on server machine for JIP, marker editing ready
|
|
if (isMultiplayer && {isServer}) then {
|
|
private _allMapMarkers = GETGVAR(allMapMarkers,[]);
|
|
private _allMapMarkersProperties = GETGVAR(allMapMarkersProperties,[]);
|
|
|
|
private _index = _allMapMarkers find _marker;
|
|
|
|
if (_index == -1) then {
|
|
_allMapMarkers pushBack _marker;
|
|
_allMapMarkersProperties pushBack _data;
|
|
} else {
|
|
_allMapMarkers set [_index, _marker];
|
|
_allMapMarkersProperties set [_index, _data];
|
|
};
|
|
|
|
GVAR(allMapMarkers) = _allMapMarkers;
|
|
GVAR(allMapMarkersProperties) = _allMapMarkersProperties;
|
|
};
|