mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
0644ad9ca2
* Added workaround functions for turret magazine ammo. * Switched to retrieving turrets dynamically instead of looking them up from an array. * Refactoring only, no functional changes * Repurposed getNeedRearmMagazines as a general purpose rearm info function + more. * The function retrieves all non-full magazines. This code was previously repeated in many different functions, but is now centralized in one. * Empty pylon filling is no longer supported in favor of the upcoming "pylons" ACE-module. Fixed bugs: * Rearm was using broken commands "magazineTurretAmmo" and "setMagazineTurretAmmo". They are now replaced with their corresponding workaround functions. * Pylon rearm was trying to set ammo count on empty pylons. Note: rearmSuccessLocal is not yet fixed! * Rearming no longer switches shell types in cannons/mortars. * Added Tuupertunut to authors. * Rearming no longer switches shell types. 2nd try. Last time it was fixed only if the turret is manned. Now it is fixed even when unmanned. * Updated fnc_rearm to support the earlier repurposing of fnc_getNeedRearmMagazines. * Small fixes and comments. * Renamed fnc_getVehicleMagazines to fnc_getTurretConfigMagazines. The latter describes much better what the function actually does. * Removed redundant checks. * Refactoring. * Fixed spaces in macros. * Renamed fnc_getAllTurrets to fnc_getAllRearmTurrets
51 lines
1.5 KiB
Plaintext
51 lines
1.5 KiB
Plaintext
/*
|
|
* Author: GitHawk
|
|
* Check whether enough supply is left to take the magazine.
|
|
*
|
|
* Arguments:
|
|
* 0: Ammo Truck <OBJECT>
|
|
* 1: Magazine Classname <STRING>
|
|
*
|
|
* Return Value:
|
|
* Enough supply <BOOL>
|
|
*
|
|
* Example:
|
|
* [ammo_truck, "500Rnd_127x99_mag_Tracer_Red"] call ace_rearm_fnc_hasEnoughSupply
|
|
*
|
|
* Public: No
|
|
*/
|
|
#include "script_component.hpp"
|
|
|
|
params ["_truck", "_magazineClass"];
|
|
|
|
// With infinite supply, there is always enough
|
|
if (GVAR(supply) == 0) exitWith {true};
|
|
|
|
|
|
// With limited supply, we need to check supply
|
|
if (GVAR(supply) == 1) exitWith {
|
|
private _supply = [_truck] call FUNC(getSupplyCount);
|
|
([_magazineClass] call FUNC(getCaliber)) params ["_cal", "_idx"];
|
|
|
|
// With caliber based rearming, we only need partial supply
|
|
if (GVAR(level) == 2) exitWith {
|
|
// If REARM_COUNT is bigger than the magazine size, we might get a bigger number than 1
|
|
private _magazinePart = ((REARM_COUNT select _idx) / (getNumber (configFile >> "CfgMagazines" >> _magazineClass >> "count"))) min 1;
|
|
(_cal * _magazinePart <= _supply)
|
|
};
|
|
(_cal <= _supply)
|
|
};
|
|
|
|
|
|
// With magazine specific supply, we need to check stored magazines
|
|
if (GVAR(supply) == 2) exitWith {
|
|
private _magazineSupply = _truck getVariable [QGVAR(magazineSupply), []];
|
|
private _magazinePresent = false;
|
|
{
|
|
_x params ["_magazine", "_rounds"];
|
|
if ((_magazine isEqualTo _magazineClass) && (_rounds > 0)) exitWith {_magazinePresent = true; };
|
|
false
|
|
} count _magazineSupply;
|
|
_magazinePresent
|
|
};
|