mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
bca8b01860
* Add search to teleport players UI * Change group side icons to look better * Improve teleport UI and add stringtable entries * Add Assign Repair Vehicle module * Add Assign Repair Facility module * Add Assign Engineer module * Add Full Heal module * Add Suicide Bomber module * Make heal module work without ace_medical * Add suicide bomber module translations * Improve attribute cargo to use displayName * Improve set engineer ui * ACE_Curator for repair modules + author array * Add angle param to getModuleDestination * Prevent multiple suicide bomber modules on same target * Heal module: support BI scripted revive system * Requested changes
62 lines
1.5 KiB
Plaintext
62 lines
1.5 KiB
Plaintext
/*
|
|
* Author: alganthe
|
|
* Module calling the garrison function.
|
|
*
|
|
* Arguments:
|
|
* 0: Module logic <OBJECT>
|
|
* 1: Position of the module <POSITION>
|
|
* 2: Radius of the task <NUMBER>
|
|
* 3: Filling mode of the garrison function <NUMBER>
|
|
* 4: Enable or not top down filling <BOOL>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [LOGIC, [2203.64, 2281.47, 1], 20, 2, true] call ace_zeus_fnc_moduleGarrison
|
|
*
|
|
* Public: No
|
|
*/
|
|
#include "script_component.hpp"
|
|
|
|
params ["_logic", "_pos", "_radius" ,"_mode" , "_topDownMode", "_teleport"];
|
|
|
|
private _unit = (attachedTo _logic);
|
|
private _building = nearestBuilding (getPosASL _unit);
|
|
|
|
// Handles errors
|
|
scopeName "Main";
|
|
private _fnc_errorAndClose = {
|
|
params ["_msg"];
|
|
deleteVehicle _logic;
|
|
[_msg] call FUNC(showMessage);
|
|
breakOut "Main";
|
|
};
|
|
|
|
switch (false) do {
|
|
case !(isNull _unit): {
|
|
[LSTRING(NothingSelected)] call _fnc_errorAndClose;
|
|
};
|
|
case (_unit isKindOf "CAManBase"): {
|
|
[LSTRING(OnlyInfantry)] call _fnc_errorAndClose;
|
|
};
|
|
case (alive _unit): {
|
|
[LSTRING(OnlyAlive)] call _fnc_errorAndClose;
|
|
};
|
|
case (_unit distance _building < 500): {
|
|
[LSTRING(BuildingTooFar)] call _fnc_errorAndClose;
|
|
};
|
|
};
|
|
|
|
private _units = units _unit;
|
|
// Make sure all units are disembarked
|
|
{
|
|
if (vehicle _x != _x) then {
|
|
moveOut _x;
|
|
};
|
|
} forEach _units;
|
|
|
|
[_pos, ["Building"], _units, _radius, _mode, _topDownMode, _teleport] call EFUNC(ai,garrison);
|
|
|
|
deleteVehicle _logic;
|