ACE3/addons/weaponselect/functions/fnc_setNextGrenadeMuzzle.sqf

/*
 * Author: CAA-Picard
 *
 * Select the next grenade muzzle to throw.
 *
 * Argument:
 * muzzle name
 *
 * Return value:
 * None
 *
 */
#include "script_component.hpp"

private ["_unit", "_muzzle"];

_unit = _this select 0;
_muzzle = _this select 1;

private ["_uniformMags", "_vestMags", "_backPackMags"];

_uniformMags = getMagazineCargo uniformContainer _unit;
_vestMags = getMagazineCargo vestContainer _unit;
_backPackMags = getMagazineCargo backpackContainer _unit;

private ["_uniformMagsToRemove", "_vestMagsToRemove", "_backPackMagsToRemove"];

_uniformMagsToRemove = [];
_vestMagsToRemove = [];
_backPackMagsToRemove = [];

private ["_firstMagazine", "_throwMuzzleNames"];

_firstMagazine = "";
_throwMuzzleNames = getArray (configfile >> "CfgWeapons" >> "Throw" >> "muzzles");

// Collect which magazines to remove
{
    private "_muzzleMagazines";
    _muzzleMagazines = getArray (configFile >> "CfgWeapons" >> "Throw" >> _x >> "magazines" );

    if (_x != _muzzle) then {

        {
            private "_index";
            _index = (_uniformMags select 0) find _x;
            if (_index > -1) then {
                _uniformMagsToRemove = _uniformMagsToRemove + [[_x, (_uniformMags select 1) select _index]];
            };

            _index = (_vestMags select 0) find _x;
            if (_index > -1) then {
                _vestMagsToRemove = _vestMagsToRemove + [[_x, (_vestMags select 1) select _index]];
            };

            _index = (_backpackMags select 0) find _x;
            if (_index > -1) then {
                _backpackMagsToRemove = _backpackMagsToRemove + [[_x, (_backpackMags select 1) select _index]];
            };
        } forEach _muzzleMagazines;

    } else {

        {
            private "_index";
            _index = (_uniformMags select 0) find _x;
            if (_index > -1) then {
                _firstMagazine = _x;
            };

            _index = (_vestMags select 0) find _x;
            if (_index > -1) then {
                _firstMagazine = _x;
            };

            _index = (_backpackMags select 0) find _x;
            if (_index > -1) then {
                _firstMagazine = _x;
            };
        } forEach _muzzleMagazines;

    };
} forEach _throwMuzzleNames;

// Remove all magazines except those we are switching to --> this breaks the selector
{
    for [{_i = 0}, {_i < (_x select 1)}, {_i = _i + 1}] do {
        _unit removeItem (_x select 0);
    };
} forEach _uniformMagsToRemove;

{
    for [{_i = 0}, {_i < (_x select 1)}, {_i = _i + 1}] do {
        _unit removeItem (_x select 0);
    };
} forEach _vestMagsToRemove;

{
    for [{_i = 0}, {_i < (_x select 1)}, {_i = _i + 1}] do {
        _unit removeItem (_x select 0);
    };
} forEach _backPackMagsToRemove;

// Readd magazines
{
    for [{_i = 0}, {_i < (_x select 1)}, {_i = _i + 1}] do {
        _unit addItemToUniform (_x select 0); 
    };
} forEach _uniformMagsToRemove;

{
    for [{_i = 0}, {_i < (_x select 1)}, {_i = _i + 1}] do {
        _unit addItemToVest (_x select 0); 
    };
} forEach _vestMagsToRemove;

{
    for [{_i = 0}, {_i < (_x select 1)}, {_i = _i + 1}] do {
        _unit addItemToBackpack (_x select 0); 
    };
} forEach _backPackMagsToRemove;