mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
b489750d5b
* Optimizations with private, params, and isEqualType * Fixed tab being used instead of space * Fixed tabs inserted by notepad++ * More usage of new private syntax and params - changed a few checks for an array being empty to `_arr isEqualTo []` rather than `count _arr == 0` - added more uses of `private` on the same line as the variable is declared - added more uses of params to assign variables passed as parameters - removed unnecessary parentheses - removed several unnecessary variable declarations with private array syntax * clean up and formatting
47 lines
1.3 KiB
Plaintext
47 lines
1.3 KiB
Plaintext
/*
|
|
* Author: Garth 'L-H' de Wet
|
|
* Performs the dial tones and detonation of explosive.
|
|
*
|
|
* Arguments:
|
|
* 0: Unit to do dialing <OBJECT>
|
|
* 1: Index <NUMBER>
|
|
* 2: Dialing points <ARRAY>
|
|
* 3: IED code <STRING>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [FUNC(dialingPhone), 0.25, [_unit,4,_arr,_code]] call CALLSTACK(CBA_fnc_addPerFrameHandler);
|
|
*
|
|
* Public: No
|
|
*/
|
|
#include "script_component.hpp"
|
|
|
|
params ["_args", "_pfID"];
|
|
_args params ["_unit", "_i", "_arr", "_code"];
|
|
|
|
if ((_i mod 4) == 0) then {
|
|
playSound3D [QUOTE(PATHTO_R(Data\Audio\DialTone.wss)), objNull, false, (_unit modelToWorldVisual [0,0.2,2]), 15,1,2.5];
|
|
};
|
|
ctrlSetText [1400,format["Calling%1",_arr select (_i - 4)]];
|
|
|
|
private _explosive = [_code] call FUNC(getSpeedDialExplosive);
|
|
|
|
if (_i >= (count _arr + 2)) then {
|
|
[_pfID] call CALLSTACK(CBA_fnc_removePerFrameHandler);
|
|
if ((count _explosive) > 0) then {
|
|
[_unit, -1, [_explosive select 0, _explosive select 2]] call FUNC(detonateExplosive);
|
|
};
|
|
_unit setVariable [QGVAR(Dialing), false, true];
|
|
if (_unit == ace_player) then {
|
|
ctrlSetText [1400,"Call Ended!"];
|
|
};
|
|
};
|
|
if (_i == (count _arr)) then {
|
|
if ((count _explosive) > 0) then {
|
|
playSound3D [QUOTE(PATHTO_R(Data\Audio\Cellphone_Ring.wss)),objNull, false, getPosASL (_explosive select 0),3.16228,1,75];
|
|
};
|
|
};
|
|
_args set [1, _i + 1];
|