mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
50 lines
1.4 KiB
Plaintext
50 lines
1.4 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: commy2, Glowbal
|
|
* Display a structured text with image.
|
|
*
|
|
* Arguments:
|
|
* 0: Text <ANY>
|
|
* 1: Image <STRING>
|
|
* 2: Image color <ARRAY> (default: [1, 1, 1])
|
|
* 3: Target Unit. Will only display if target is the player controlled object <OBJECT> (default: ACE_player)
|
|
* 4: Size <NUMBER> (default: 2)
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* ["text", "image", [1, 1, 1], ACE_player, 2] call ace_common_fnc_displayTextPicture
|
|
* ["text", "image", nil, nil, 3] call ace_common_fnc_displayTextPicture
|
|
*
|
|
* Public: Yes
|
|
*/
|
|
|
|
params [["_text", ""], ["_image", "", [""]], ["_imageColor", [1,1,1], [[]]], ["_target", ACE_player, [objNull]], ["_size", 2, [0]]];
|
|
|
|
if (_target != ACE_player) exitWith {};
|
|
|
|
if (typeName _text != "TEXT") then {
|
|
if (_text isEqualType []) then {
|
|
if (count _text > 0) then {
|
|
{
|
|
if (_x isEqualType "" && {isLocalized _x}) then {
|
|
_text set [_forEachIndex, localize _x];
|
|
};
|
|
} forEach _text;
|
|
|
|
_text = format _text;
|
|
};
|
|
};
|
|
|
|
if (_text isEqualType "" && {isLocalized _text}) then {
|
|
_text = localize _text;
|
|
};
|
|
|
|
_text = parseText format ["<t align='center'>%1</t>", _text];
|
|
};
|
|
|
|
_text = composeText [parseText format ["<img size='2' align='center' color='%2' image='%1'/>", _image, _imageColor call BIS_fnc_colorRGBtoHTML], lineBreak, _text];
|
|
|
|
[_text, _size] call FUNC(displayTextStructured);
|