mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
48 lines
1.1 KiB
Plaintext
48 lines
1.1 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: Dystopian
|
|
* Checks if unit can pull target body out of vehicle.
|
|
*
|
|
* Arguments:
|
|
* 1: Body <OBJECT>
|
|
* 2: Unit <OBJECT>
|
|
*
|
|
* Return Value:
|
|
* Able to pull out target body <BOOL>
|
|
*
|
|
* Example:
|
|
* [crew cursorObject select 0, player] call ace_interaction_fnc_canPullOutBody
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_body", "_unit"];
|
|
|
|
private _vehicle = objectParent _body;
|
|
|
|
if (
|
|
!isNull objectParent _unit
|
|
|| {alive _body}
|
|
|| {isNull _vehicle}
|
|
|| {1 < locked _vehicle}
|
|
|| {
|
|
0 < {alive _x} count crew _vehicle // alive is in vehicle
|
|
// group is used here for situations when side player == ENEMY
|
|
&& {0.6 > side group _unit getFriend side group _vehicle} // player is enemy
|
|
}
|
|
) exitWith {false};
|
|
|
|
((fullCrew [_vehicle, ""] select {_body == _x select 0}) select 0) params ["", "", "_cargoIndex", "_turretPath"];
|
|
|
|
private _locked = if (!(_turretPath isEqualTo [])) then {
|
|
_vehicle lockedTurret _turretPath;
|
|
} else {
|
|
if (_cargoIndex > -1) then {
|
|
_vehicle lockedCargo _cargoIndex;
|
|
} else {
|
|
lockedDriver _vehicle;
|
|
};
|
|
};
|
|
|
|
!_locked
|