mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
0644ad9ca2
* Added workaround functions for turret magazine ammo. * Switched to retrieving turrets dynamically instead of looking them up from an array. * Refactoring only, no functional changes * Repurposed getNeedRearmMagazines as a general purpose rearm info function + more. * The function retrieves all non-full magazines. This code was previously repeated in many different functions, but is now centralized in one. * Empty pylon filling is no longer supported in favor of the upcoming "pylons" ACE-module. Fixed bugs: * Rearm was using broken commands "magazineTurretAmmo" and "setMagazineTurretAmmo". They are now replaced with their corresponding workaround functions. * Pylon rearm was trying to set ammo count on empty pylons. Note: rearmSuccessLocal is not yet fixed! * Rearming no longer switches shell types in cannons/mortars. * Added Tuupertunut to authors. * Rearming no longer switches shell types. 2nd try. Last time it was fixed only if the turret is manned. Now it is fixed even when unmanned. * Updated fnc_rearm to support the earlier repurposing of fnc_getNeedRearmMagazines. * Small fixes and comments. * Renamed fnc_getVehicleMagazines to fnc_getTurretConfigMagazines. The latter describes much better what the function actually does. * Removed redundant checks. * Refactoring. * Fixed spaces in macros. * Renamed fnc_getAllTurrets to fnc_getAllRearmTurrets
51 lines
1.2 KiB
Plaintext
51 lines
1.2 KiB
Plaintext
/*
|
|
* Author: GitHawk
|
|
* Get the caliber of the ammo in a magazine and return its parameters.
|
|
*
|
|
* Arguments:
|
|
* 0: Magazine Classname <STRING>
|
|
*
|
|
* Return Value:
|
|
* 0: Caliber information <ARRAY>
|
|
* 0: Rounded caliber <NUMBER>
|
|
* 1: Caliber index <NUMBER>
|
|
*
|
|
* Example:
|
|
* ["500Rnd_127x99_mag_Tracer_Red"] call ace_rearm_fnc_getCaliber
|
|
*
|
|
* Public: No
|
|
*/
|
|
#include "script_component.hpp"
|
|
|
|
params [
|
|
["_magazineClass", ""]
|
|
];
|
|
|
|
if (_magazineClass isEqualTo "") exitWith {[8, 2]};
|
|
|
|
private _ammo = getText (configFile >> "CfgMagazines" >> _magazineClass >> "ammo");
|
|
private _tmpCal = getNumber (configFile >> "CfgAmmo" >> _ammo >> "ace_caliber");
|
|
private _cal = 8;
|
|
if (_tmpCal > 0) then {
|
|
_cal = _tmpCal;
|
|
} else {
|
|
_tmpCal = getNumber (configFile >> "CfgAmmo" >> _ammo >> QGVAR(caliber));
|
|
if (_tmpCal > 0) then {
|
|
_cal = _tmpCal;
|
|
} else {
|
|
diag_log format ["[ACE] ERROR: Undefined Ammo [%1 : %2]", _ammo, inheritsFrom (configFile >> "CfgAmmo" >> _ammo)];
|
|
if (_ammo isKindOf "BulletBase") then {
|
|
_cal = 8;
|
|
} else {
|
|
_cal = 100;
|
|
};
|
|
};
|
|
};
|
|
_cal = round _cal;
|
|
private _idx = REARM_CALIBERS find _cal;
|
|
if (_idx == -1 ) then {
|
|
_idx = 2;
|
|
};
|
|
|
|
[_cal, _idx]
|