mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
74 lines
2.8 KiB
Plaintext
74 lines
2.8 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: PabstMirror, mharis001
|
|
* Dynamically adds "Defuse" actions to nearby mines when interact_menu is opened.
|
|
* Called by the "ace_interactMenuOpened" event.
|
|
*
|
|
* Arguments:
|
|
* Interact Menu Type (0 - World, 1 - Self) <NUMBER>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [0] call ace_explosives_fnc_interactEH
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_interactionType"];
|
|
TRACE_1("Explosives interactEH",_interactionType);
|
|
|
|
// Ignore self-interaction menu or mounted vehicle interaction
|
|
// For performance reasons only add PFH if player has a defusal kit
|
|
// If player somehow gets a defusal kit during keyDown, they will just have to reopen menu
|
|
if (
|
|
_interactionType != 0
|
|
|| {vehicle ACE_player != ACE_player}
|
|
|| {!("ACE_DefusalKit" in ([ACE_player, false, true, true, true, false] call CBA_fnc_uniqueUnitItems))}
|
|
) exitWith {};
|
|
|
|
[{
|
|
BEGIN_COUNTER(interactEH);
|
|
params ["_args", "_pfhID"];
|
|
_args params ["_setPosition", "_addedHelpers", "_minesHelped"];
|
|
|
|
if (!EGVAR(interact_menu,keyDown)) then {
|
|
TRACE_1("Cleaning defuse helpers",count _addedHelpers);
|
|
{deleteVehicle _x} forEach _addedHelpers;
|
|
[_pfhID] call CBA_fnc_removePerFrameHandler;
|
|
} else {
|
|
// Prevent Rare Error when ending mission with interact key down:
|
|
private _player = ACE_player;
|
|
if (isNull _player) exitWith {};
|
|
private _playerPos = getPosASL _player;
|
|
|
|
// Rescan if player has moved more than 5 meters from last position
|
|
if (_playerPos distanceSqr _setPosition > 25) then {
|
|
private _cfgAmmo = configFile >> "CfgAmmo";
|
|
{
|
|
if (_x distanceSqr _player < 225 && {!(_x in _minesHelped)} && {!(getModelInfo _x select 0 isEqualTo "empty.p3d")}) then {
|
|
private _config = _cfgAmmo >> typeOf _x;
|
|
private _size = getNumber (_config >> QGVAR(size));
|
|
private _defuseClass = ["ACE_DefuseObject", "ACE_DefuseObject_Large"] select (_size == 1);
|
|
private _defusePos = getArray (_config >> QGVAR(defuseObjectPosition));
|
|
if (_defusePos isEqualTo []) then {
|
|
_defusePos = [0, 0, 0];
|
|
};
|
|
|
|
TRACE_4("Creating defuse helper",_x,typeOf _x,_defuseClass,_defusePos);
|
|
private _helper = _defuseClass createVehicleLocal [0, 0, 0];
|
|
|
|
_helper attachTo [_x, _defusePos];
|
|
_helper setVariable [QGVAR(Explosive), _x];
|
|
_addedHelpers pushBack _helper;
|
|
_minesHelped pushBack _x;
|
|
};
|
|
} forEach allMines;
|
|
|
|
_args set [0, _playerPos];
|
|
};
|
|
};
|
|
END_COUNTER(interactEH);
|
|
}, 0.5, [getPosASL ACE_player vectorAdd [-100, 0, 0], [], []]] call CBA_fnc_addPerFrameHandler;
|