mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
b1d5bbe450
* Initial Commit
* Got rid of unneeded translation values
* Updated Strings
* "Fixed" issue where when you deploy the tripid and weapon on slope it freaked out.
* Fixed locality issues. Added timers to relavent functions.
* Added weights to all magazines/tripod. Weights to weapons coming soon when I transfer them to the launcher slot
* Fixed bug regarding localized strings. Created new tripod model
* Added timers for deploying/picking up the tripod. Changed ammo-box model from custom to one already in ARMA. Changed gun-bag model for a more generic one. Created a texture for the tripod and gunbag
* Removed ability to disassemble weapons via the addAction. Added ACE Action to get in due to a memory point issue. Changed from a static deploy/dismount time to one based in the weapon configs
* Created forward-compatability. Made it so I can define a base plate for any weapon if I ever want to expand from the generic M3 Tripod.
* Fixed bug where tripod wouldn't deploy with the correct times. Fixed bug where if you moved the tripod into the ground it would go flying.
* Added mortar compatability. Will probably shift whole mortar ammo loading to CSW one day
* Added icons to each relavent item
* Added README, possibly fixed bug where if you are in a weapon others cant load/unload ammo. Changed distance you can interact with weapons
* Added checks for when deploying the gun as well as unloading ammo to prevent duplication/deletion of items.
* Added documentation
* Added order to doc
* Explained why things are the way they are
* Remove temp files
* Removed redundant files
* Converted tabs->spaces. Added newlines at end of all files. Changed broken line in fnc_tripodDeploy.sqf.
* 100% newlines at end of file
* Added newlines to files that didnt get the change. Fixed README. Changed from GVAR(cswOptions) to GVAR(options). Changed from tabs to spaces in wiki
* Fixed issue with UAV assembling with enableWeaponDisassembling. Fixed bug where game would crash if you disassembled static weapon with more than 1 magazine
* Tabs->Spaces
* Added CSW options to base StaticWeapon class to allow for easier additions. Switched default mortar away from CSW system due to incompatabilities
* Lazy Evaluations and macros to describe how things work.
* Added newlines to script_component. Fix no-texture issue on tripod. "Fix" 20mm HE saying 40mm HE. Add custom icons to all weapons. Move "Check Ammo" to CSW menu
* abc
* Revert "abc"
This reverts commit bcb4214bd9.
* Update to current commit
* Revert changes to fortify.md
* Updated UI Icon to Crew Served Ammo branch UI
* Added Pabst's CrewServedAmmo to handle ammo loading/unloading instead of my solution
* Fixed bug where currentWeaponTurret returned a blank string when a player hasent entered hte weapon to select the current weapon
* Re-added ammo loading time
* Tabs->Spaces
* Newline at end of files
* Removed replaced functions
* Remove redundant strings. Move ammo handling to appropiate section
* Tabs->Spaces
* Update wiki
* Updated to fix crash with default weapons and disable CSW ability on default static weapons
* Added editor attributes to enable/disable CSW at edit time
* Change how ammo is removed from the CSW. Uses math instead of iteration
* Fix bug where assembled weapon did not get rid of default actions
* Added support for multiple types of ammo in one CSW
* Add tracer magazines for .50 cal
* Fix bug where you could load ammo even if the gun couldnt take any more
* Disable debug and enable compile cache
* Changed weapon deploy/pickup time. Removed custom Titan missiles. Using ACE Dragging now. Added progress bar check for pickupTripod. Updated documentation
* Removed check if CSW is full to unload ammo
* Fix bug where items would spawn underneath other items on wepaon dismount
* Change some things
* Configure base statics, improve returnAmmo
* Add mortar baseplate
* Remove explicit inheritance
* Fix bug where unloading ammo would duplicate it if you had room in your person.
* Tab->Space
* Player couldnt pickup tripod due to legacy code
* Fix GMG_01_base_F inheritce
* Port of ACE 2 tripod + ACE 2 CSW Bag
* Move ACE 2 Data to APL folder
* Adjust weights to make them more accurate to how ARMA uses it and the real life equivalents
* Fix bug where error was thrown on esc from picking up tripod. Tripod rotated 180
* Fix bug where if you called ace_common_claim the weapon could be set to be disassembled even though it may not be wanted via CSW
* Added ability to toggle ammo handling when weaponAssembly is disabled.
* Add Proxy Weapons for all Vanilla static weapons. These serve as a way to allow for realistic ammo reload times without having to modify base classes if you want feautres turned off. Adjusted reload and mount times to be more "realistic"
* Fix Shadow RPT Spam
* Update wiki
* Change order of setDir and setPos
* Change all setDir/setPos orientations. Remove redundant check. Ensure that weapon locked state reflects it with the "getIn" command. Add a way to pass in a specific classname for the weapon assemble type. Add a callback function onDisassemble if user wants to set the state of the new tripod using the old weapon as a reference
* Actually check for the carryWeaponClassname in the deployWeapon check
* Ai Compatiblity
* Add stringtable entries
* Formatting fixes
* Stringtables for settings, fix setMagazineTurretAmmo
* inherit ammo for mags, reorder stringtable
displays correct ammo and descriptionShort
* don't require ace_javelin
* Tweaks, cleanup, localzation, ace_reload changes
change weapon tag to [CSW]
tweak localization strings
minor cleanup
simplify some ace_reload funcs
* delete moved dev func
* Hopefully fix issue where to-be deleted tripod intersects with newly created weapon and vice versa. Remove PBOPREFIX newline
* cleanup/proxyWeapon/mk6 compat
92 lines
4.2 KiB
Plaintext
92 lines
4.2 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: TCVM
|
|
* Dismounts the weapon from the tripod and drops its backpack beside
|
|
*
|
|
* Arguments:
|
|
* 0: Static Weapon <OBJECT>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [weapon] call ace_csw_fnc_assemble_pickupWeapon
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
[{
|
|
params ["_staticWeapon", "_player"];
|
|
TRACE_2("assemble_pickupWeapon",_staticWeapon,_player);
|
|
|
|
private _onDisassembleFunc = getText(configFile >> "CfgVehicles" >> (typeOf _staticWeapon) >> QUOTE(ADDON) >> "disassembleFunc");
|
|
private _carryWeaponClassname = getText(configFile >> "CfgVehicles" >> (typeOf _staticWeapon) >> QUOTE(ADDON) >> "disassembleWeapon");
|
|
private _turretClassname = getText(configFile >> "CfgVehicles" >> (typeOf _staticWeapon) >> QUOTE(ADDON) >> "disassembleTurret");
|
|
private _pickupTime = getNumber(configFile >> "CfgWeapons" >> _carryWeaponClassname >> QUOTE(ADDON) >> "pickupTime");
|
|
TRACE_4("",typeOf _staticWeapon,_carryWeaponClassname,_turretClassname,_pickupTime);
|
|
if (!isClass (configFile >> "CfgWeapons" >> _carryWeaponClassname)) exitWith {ERROR_1("bad weapon classname [%1]",_carryWeaponClassname);};
|
|
if (!isClass (configFile >> "CfgVehicles" >> _turretClassname)) exitWith {ERROR_1("bad turret classname [%1]",_turretClassname);};
|
|
|
|
private _onFinish = {
|
|
params ["_args"];
|
|
_args params ["_staticWeapon", "_player", "_carryWeaponClassname", "_turretClassname", "_onDisassembleFunc"];
|
|
TRACE_4("disassemble finish",_staticWeapon,_player,_carryWeaponClassname,_turretClassname);
|
|
|
|
private _weaponPos = getPosATL _staticWeapon;
|
|
_weaponPos set [2, (_weaponPos select 2) + 0.1];
|
|
private _weaponDir = getDir _staticWeapon;
|
|
|
|
LOG("remove ammo");
|
|
{
|
|
_x params ["_xMag", "", "_xAmmo"];
|
|
|
|
private _carryMag = GVAR(vehicleMagCache) getVariable _xMag;
|
|
if (isNil "_carryMag") then {
|
|
private _groups = "getNumber (_x >> _xMag) == 1" configClasses (configFile >> QGVAR(groups));
|
|
_carryMag = configName (_groups param [0, configNull]);
|
|
GVAR(vehicleMagCache) setVariable [_xMag, _carryMag];
|
|
TRACE_2("setting cache",_xMag,_carryMag);
|
|
};
|
|
if ((_xAmmo > 0) && {_carryMag != ""}) then {
|
|
TRACE_2("Removing ammo",_xMag,_carryMag);
|
|
[_player, _carryMag, _xAmmo] call FUNC(reload_handleReturnAmmo);
|
|
};
|
|
} forEach (magazinesAllTurrets _staticWeapon);
|
|
|
|
private _cswTripod = createVehicle [_turretClassname, [0, 0, 0], [], 0, "NONE"];
|
|
[_cswTripod, _staticWeapon] call (missionNamespace getVariable _onDisassembleFunc);
|
|
|
|
LOG("delete weapon");
|
|
deleteVehicle _staticWeapon;
|
|
|
|
// Delay a frame so weapon has a chance to be deleted
|
|
[{
|
|
params ["_player", "_cswTripod", "_weaponDir", "_weaponPos", "_carryWeaponClassname"];
|
|
_cswTripod setDir _weaponDir;
|
|
_cswTripod setPosATL _weaponPos;
|
|
_cswTripod setVelocity [0, 0, -0.05];
|
|
_cswTripod setVectorUp (surfaceNormal _weaponPos);
|
|
|
|
if ((alive _player) && {(secondaryWeapon _player) == ""}) exitWith {
|
|
_player addWeapon _carryWeaponClassname;
|
|
};
|
|
private _weaponRelPos = _cswTripod getRelPos RELATIVE_DIRECTION(90);
|
|
private _weaponHolder = createVehicle ["groundWeaponHolder", [0, 0, 0], [], 0, "NONE"];
|
|
_weaponHolder setDir random [0, 180, 360];
|
|
_weaponHolder setPosATL [_weaponRelPos select 0, _weaponRelPos select 1, _weaponPos select 2];
|
|
_weaponHolder addWeaponCargoGlobal [_carryWeaponClassname, 1];
|
|
}, [_player, _cswTripod, _weaponDir, _weaponPos, _carryWeaponClassname]] call CBA_fnc_execNextFrame;
|
|
|
|
LOG("end");
|
|
};
|
|
|
|
private _condition = {
|
|
params ["_args"];
|
|
_args params ["_staticWeapon"];
|
|
((crew _staticWeapon) isEqualTo []) && (alive _staticWeapon)
|
|
};
|
|
|
|
[TIME_PROGRESSBAR(_pickupTime), [_staticWeapon, _player, _carryWeaponClassname, _turretClassname, _onDisassembleFunc], _onFinish, {}, localize LSTRING(DisassembleCSW_progressBar), _condition] call EFUNC(common,progressBar);
|
|
}, _this] call CBA_fnc_execNextFrame;
|
|
|